Euphoria - Urutan

Urutan diwakili oleh daftar objek dalam tanda kurung kurawal {}, dipisahkan dengan koma. Suatu urutan dapat berisi atom dan urutan lainnya. Misalnya -

{2, 3, 5, 7, 11, 13, 17, 19}
{1, 2, {3, 3, 3}, 4, {5, {6}}}
{{"Zara", "Ayan"}, 52389, 97.25}
{} -- the 0-element sequence

Satu elemen dari suatu urutan dapat dipilih dengan memberikan nomor elemen dalam tanda kurung siku. Nomor elemen dimulai dari 1.

Misalnya, jika x berisi {5, 7.2, 9, 0.5, 13} maka x [2] adalah 7.2.

Misalkan x [2] berisi {11,22,33}, Sekarang jika Anda meminta x [2] Anda mendapatkan {11,22,33} dan jika Anda meminta x [2] [3], Anda mendapatkan atom 33 .

Contoh

#!/home/euphoria-4.0b2/bin/eui

sequence x
x = {1, 2, 3, 4}

for a = 1 to length(x) do
   printf(1, "value of x[%d] = %d\n", {a, x[a]})
end for

Di sini, length () adalah fungsi bawaan yang mengembalikan panjang urutan. Contoh di atas menghasilkan hasil sebagai berikut -

value of x[1] = 1
value of x[2] = 2
value of x[3] = 3
value of x[4] = 4

String karakter

Sebuah string karakter hanyalah a sequencekarakter. Ini dapat dimasukkan dengan salah satu dari dua cara -

(a) Using Double Quotes −

"ABCDEFG"

(b) Using Raw String Notation −

-- Using back-quotes
`ABCDEFG`

or

-- Using three double-quotes
"""ABCDEFG"""

Anda dapat mencoba contoh berikut untuk memahami konsep -

#!/home/euphoria-4.0b2/bin/eui

sequence x
x = "ABCD"

for a = 1 to length(x) do
   printf(1, "value of x[%d] = %s\n", {a, x[a]})
end for

Ini menghasilkan hasil sebagai berikut -

value of x[1] = A
value of x[2] = B
value of x[3] = C
value of x[4] = D

String Array

Array string dapat diimplementasikan menggunakan Sequences sebagai berikut -

#!/home/euphoria-4.0b2/bin/eui

sequence x = {"Hello", "World", "Euphoria", "", "Last One"}

for a = 1 to length(x) do
   printf(1, "value of x[%d] = %s\n", {a, x[a]})
end for

Ini menghasilkan hasil sebagai berikut -

value of x[1] = Hello
value of x[2] = World
value of x[3] = Euphoria
value of x[4] =
value of x[5] = Last One

Struktur Euforia

Sebuah struktur dapat diimplementasikan menggunakan Urutan sebagai berikut -

#!/home/euphoria-4.0b2/bin/eui

sequence employee = {
   {"John","Smith"},
      45000,
      27,
      185.5
}
printf(1, "First Name = %s, Last Name = %s\n", {employee[1][1],employee[1][2]} )

Ini menghasilkan hasil sebagai berikut -

First Name = John, Last Name = Smith

Ada berbagai operasi yang dapat dilakukan secara langsung pada urutan. Mari kita lihat secara detail -

Operasi Kemih

Saat diterapkan ke urutan, operator unary sebenarnya diterapkan ke setiap elemen dalam urutan untuk menghasilkan urutan hasil dengan panjang yang sama.

#!/home/euphoria-4.0b2/bin/eui

sequence x
x = -{1, 2, 3, 4}

for a = 1 to length(x) do
   printf(1, "value of x[%d] = %d\n", {a, x[a]})
end for

Ini menghasilkan hasil sebagai berikut -

value of x[1] = -1
value of x[2] = -2
value of x[3] = -3
value of x[4] = -4

Operasi Aritmatika

Hampir semua operasi aritmatika dapat dilakukan pada urutan sebagai berikut -

#!/home/euphoria-4.0b2/bin/eui

sequence x, y, a, b, c
x = {1, 2, 3}
y = {10, 20, 30}

a = x + y
puts(1, "Value of a = {")

for i = 1 to length(a) do
   printf(1, "%d,", a[i])
end for
puts(1, "}\n")

b = x - y
puts(1, "Value of b = {")
for i = 1 to length(a) do
   printf(1, "%d,", b[i])
end for
puts(1, "}\n")

c = x * 3
puts(1, "Value of c = {")

for i = 1 to length(c) do
   printf(1, "%d,", c[i])
end for
puts(1, "}\n")

Ini menghasilkan hasil sebagai berikut -

Value of a = {11,22,33,}
Value of b = {-9,-18,-27,}
Value of c = {3,6,9,}

Opsi Baris Perintah

Seorang pengguna dapat memberikan opsi baris perintah ke skrip Euphoria dan dapat diakses sebagai urutan menggunakan command_line() berfungsi sebagai berikut -

#!/home/euphoria-4.0b2/bin/eui

sequence x

x = command_line()

printf(1, "Interpeter Name: %s\n", {x[1]} )
printf(1, "Script Name: %s\n", {x[2]} )
printf(1, "First Argument: %s\n", {x[3]})
printf(1, "Second Argument: %s\n", {x[4]})

Sini printf()adalah fungsi bawaan Euphoria. Sekarang jika Anda menjalankan skrip ini sebagai berikut -

$eui test.ex "one" "two"

Ini menghasilkan hasil sebagai berikut -

Interpeter Name: /home/euphoria-4.0b2/bin/eui
Script Name: test.ex
First Argument: one
Second Argument: two