アセンブリ-システムコール

システムコールは、ユーザースペースとカーネルスペースの間のインターフェイスのAPIです。すでにシステムコールを使用しています。sys_writeおよびsys_exit、それぞれ画面への書き込みおよびプログラムの終了。

Linuxシステムコール

アセンブリプログラムでLinuxシステムコールを利用できます。プログラムでLinuxシステムコールを使用するには、次の手順を実行する必要があります-

システムコール番号をEAXレジスタに入れます。
システムコールの引数をレジスタEBX、ECXなどに格納します。
関連する割り込みを呼び出します（80h）。
結果は通常、EAXレジスタに返されます。

使用されるシステムコールの引数を格納する6つのレジスタがあります。これらは、EBX、ECX、EDX、ESI、EDI、およびEBPです。これらのレジスタは、EBXレジスタから始まる連続した引数を取ります。6つを超える引数がある場合、最初の引数のメモリ位置はEBXレジスタに格納されます。

次のコードスニペットは、システムコールsys_exit −の使用法を示しています。

mov	eax,1		; system call number (sys_exit)
int	0x80		; call kernel

次のコードスニペットは、システムコールsys_write −の使用法を示しています。

mov	edx,4		; message length
mov	ecx,msg		; message to write
mov	ebx,1		; file descriptor (stdout)
mov	eax,4		; system call number (sys_write)
int	0x80		; call kernel

すべてのシステムコールは、それらの番号（int 80hを呼び出す前にEAXに入力する値）とともに/usr/include/asm/unistd.hにリストされています。

次の表は、このチュートリアルで使用されるシステムコールの一部を示しています-

％eax	名前	％ebx	％ecx	％edx	％esx	％edi
1	sys_exit	int	-	-	-	-
2	sys_fork	struct pt_regs	-	-	-	-
3	sys_read	unsigned int	char *	size_t	-	-
4	sys_write	unsigned int	const char *	size_t	-	-
5	sys_open	const char *	int	int	-	-
6	sys_close	unsigned int	-	-	-	-

例

次の例では、キーボードから数値を読み取り、画面に表示します-

section .data                           ;Data segment
   userMsg db 'Please enter a number: ' ;Ask the user to enter a number
   lenUserMsg equ $-userMsg             ;The length of the message
   dispMsg db 'You have entered: '
   lenDispMsg equ $-dispMsg                 

section .bss           ;Uninitialized data
   num resb 5
	
section .text          ;Code Segment
   global _start
	
_start:                ;User prompt
   mov eax, 4
   mov ebx, 1
   mov ecx, userMsg
   mov edx, lenUserMsg
   int 80h

   ;Read and store the user input
   mov eax, 3
   mov ebx, 2
   mov ecx, num  
   mov edx, 5          ;5 bytes (numeric, 1 for sign) of that information
   int 80h
	
   ;Output the message 'The entered number is: '
   mov eax, 4
   mov ebx, 1
   mov ecx, dispMsg
   mov edx, lenDispMsg
   int 80h  

   ;Output the number entered
   mov eax, 4
   mov ebx, 1
   mov ecx, num
   mov edx, 5
   int 80h  
    
   ; Exit code
   mov eax, 1
   mov ebx, 0
   int 80h

上記のコードをコンパイルして実行すると、次の結果が得られます。

Please enter a number:
1234  
You have entered:1234