Arduino - Nem Sensörü

Bu bölümde Arduino kartımızı farklı sensörlerle nasıl arayüzleyeceğimizi öğreneceğiz. Aşağıdaki sensörleri tartışacağız -

• Nem sensörü (DHT22)
• Sıcaklık sensörü (LM35)
• Su dedektörü sensörü (Basit Su Tetikleyici)
• PIR SENSÖRÜ
• ULTRASONİK SENSÖR
• GPS

Nem Sensörü (DHT22)

DHT-22 (AM2302 olarak da adlandırılır) bir dijital çıkış, bağıl nem ve sıcaklık sensörüdür. Çevreleyen havayı ölçmek için kapasitif bir nem sensörü ve bir termistör kullanır ve veri pinine dijital bir sinyal gönderir.

Bu örnekte, bu sensörü Arduino UNO ile nasıl kullanacağınızı öğreneceksiniz. Oda sıcaklığı ve nemi seri monitöre yazdırılacaktır.

DHT-22 Sensörü

Bağlantılar basit. Soldaki ilk pin 3-5V güce, ikinci pin veri giriş pinine ve en sağdaki pin toprağa.

Teknik detaylar

• Power - 3-5V

• Max Current - 2,5 mA

• Humidity -% 0-100,% 2-5 doğruluk

• Temperature - 40 ila 80 ° C, ± 0,5 ° C doğruluk

Gerekli Bileşenler

Aşağıdaki bileşenlere ihtiyacınız olacak -

• 1 × Breadboard
• 1 × Arduino Uno R3
• 1 × DHT22
• 1 × 10K ohm direnç

Prosedür

Devre şemasını takip edin ve aşağıdaki resimde gösterildiği gibi devre tahtasındaki bileşenleri bağlayın.

Eskiz

Bilgisayarınızda Arduino IDE yazılımını açın. Arduino dilinde kodlama devrenizi kontrol edecektir. Yeni'ye tıklayarak yeni bir çizim Dosyası açın.

Arduino Kodu

// Example testing sketch for various DHT humidity/temperature sensors

#include "DHT.h"
#define DHTPIN 2 // what digital pin we're connected to
// Uncomment whatever type you're using!
//#define DHTTYPE DHT11 // DHT 11
#define DHTTYPE DHT22 // DHT 22 (AM2302), AM2321
//#define DHTTYPE DHT21 // DHT 21 (AM2301)
// Connect pin 1 (on the left) of the sensor to +5V
// NOTE: If using a board with 3.3V logic like an Arduino Due connect pin 1
// to 3.3V instead of 5V!
// Connect pin 2 of the sensor to whatever your DHTPIN is
// Connect pin 4 (on the right) of the sensor to GROUND
// Connect a 10K resistor from pin 2 (data) to pin 1 (power) of the sensor
// Initialize DHT sensor.
// Note that older versions of this library took an optional third parameter to
// tweak the timings for faster processors. This parameter is no longer needed
// as the current DHT reading algorithm adjusts itself to work on faster procs.
DHT dht(DHTPIN, DHTTYPE);

void setup() {
   Serial.begin(9600);
   Serial.println("DHTxx test!");
   dht.begin();
}

void loop() {
   delay(2000); // Wait a few seconds between measurements
   float h = dht.readHumidity();
   // Reading temperature or humidity takes about 250 milliseconds!
   float t = dht.readTemperature();
   // Read temperature as Celsius (the default)
   float f = dht.readTemperature(true);
   // Read temperature as Fahrenheit (isFahrenheit = true)
   // Check if any reads failed and exit early (to try again).
   if (isnan(h) || isnan(t) || isnan(f)) {
      Serial.println("Failed to read from DHT sensor!");
      return;
   }
   
   // Compute heat index in Fahrenheit (the default)
   float hif = dht.computeHeatIndex(f, h);
   // Compute heat index in Celsius (isFahreheit = false)
   float hic = dht.computeHeatIndex(t, h, false);
   Serial.print ("Humidity: ");
   Serial.print (h);
   Serial.print (" %\t");
   Serial.print ("Temperature: ");
   Serial.print (t);
   Serial.print (" *C ");
   Serial.print (f);
   Serial.print (" *F\t");
   Serial.print ("Heat index: ");
   Serial.print (hic);
   Serial.print (" *C ");
   Serial.print (hif);
   Serial.println (" *F");
}

Dikkat Edilecek Kod

DHT22 sensörü, panele aşağıdaki şekilde bağlanan dört terminale (V _cc , DATA, NC, GND) sahiptir -

• DATA pinini Arduino pin numarası 2'ye
• 5 volt Arduino kartına V _cc pin
• Arduino kartının zeminine GND pini
• DATA ile V _cc pini arasına 10k ohm direnç (yukarı çekme direnci) bağlamamız gerekir

Donanım bağlantıları yapıldıktan sonra, DHT22 kitaplığını daha önce açıklandığı gibi Arduino kitaplık dosyanıza eklemeniz gerekir.

Sonuç

Her 2 saniyede bir güncellenen seri port monitöründe sıcaklık ve nem göstergesini göreceksiniz.