Pascal - Birimler

Bir Pascal programı, birimler adı verilen modüllerden oluşabilir. Bir birim, değişkenlerden ve tür bildirimlerinden, ifadelerden, prosedürlerden vb. Oluşan bazı kod bloklarından oluşabilir. Pascal'da birçok yerleşik birim vardır ve Pascal, programcıların kullanılacak kendi birimlerini tanımlamasına ve yazmasına izin verir. daha sonra çeşitli programlarda.

Yerleşik Üniteleri Kullanma

Hem yerleşik birimler hem de kullanıcı tanımlı birimler, kullanım cümlesi tarafından bir programa dahil edilir. Varyantlar birimini Pascal - Varyantlar eğitiminde zaten kullandık . Bu eğitimde, kullanıcı tanımlı birimlerin oluşturulması ve dahil edilmesi açıklanmaktadır. Ancak, önce yerleşik bir birimin nasıl ekleneceğini görelim.crt programınızda -

program myprog;
uses crt;

Aşağıdaki örnek, crt birim -

Program Calculate_Area (input, output);
uses crt;
var 
   a, b, c, s, area: real;

begin
   textbackground(white); (* gives a white background *)
   clrscr; (*clears the screen *)
   
   textcolor(green); (* text color is green *)
   gotoxy(30, 4); (* takes the pointer to the 4th line and 30th column) 
   
   writeln('This program calculates area of a triangle:');
   writeln('Area = area = sqrt(s(s-a)(s-b)(s-c))');
   writeln('S stands for semi-perimeter');
   writeln('a, b, c are sides of the triangle');
   writeln('Press any key when you are ready');
   
   readkey;
   clrscr;
   gotoxy(20,3);
   
   write('Enter a: ');
   readln(a);
   gotoxy(20,5);
   
   write('Enter b:');
   readln(b);
   gotoxy(20, 7);
   
   write('Enter c: ');
   readln(c);

   s := (a + b + c)/2.0;
   area := sqrt(s * (s - a)*(s-b)*(s-c));
   gotoxy(20, 9);
   
   writeln('Area: ',area:10:3);
   readkey;
end.

Pascal eğitiminin hemen başında kullandığımız programın aynısı, değişikliğin etkilerini bulmak için onu derleyip çalıştırın.

Bir Pascal Birimi Oluşturma ve Kullanma

Bir birim oluşturmak için, içinde saklamak istediğiniz modülleri veya alt programları yazmanız ve bir dosyaya kaydetmeniz gerekir. .pasuzantı. Bu dosyanın ilk satırı, anahtar kelime birimi ile başlamalı ve ardından birimin adı gelmelidir. Örneğin -

unit calculateArea;

Aşağıda bir Pascal birimi oluşturmanın üç önemli adımı verilmiştir -

• Dosyanın adı ve birimin adı tam olarak aynı olmalıdır. Böylece, calculateArea birimimiz calculateArea.pas adlı bir dosyaya kaydedilecektir .

• Sonraki satır tek bir anahtar kelimeden oluşmalıdır interface. Bu satırdan sonra bu ünitede gelecek olan tüm fonksiyon ve prosedürler için beyanları yazacaksınız.

• İşlev bildirimlerinden hemen sonra kelimeyi yazın implementation, yine bir anahtar kelime. Anahtar kelime uygulamasını içeren satırdan sonra, tüm alt programların tanımını sağlayın.

Aşağıdaki program, calculateArea adlı birimi oluşturur -

unit CalculateArea;
interface

function RectangleArea( length, width: real): real;
function CircleArea(radius: real) : real;
function TriangleArea( side1, side2, side3: real): real;

implementation

function RectangleArea( length, width: real): real;
begin
   RectangleArea := length * width;
end;

function CircleArea(radius: real) : real;
const
   PI = 3.14159;
begin
   CircleArea := PI * radius * radius;
end;

function TriangleArea( side1, side2, side3: real): real;
var
   s, area: real;

begin
   s := (side1 + side2 + side3)/2.0;
   area := sqrt(s * (s - side1)*(s-side2)*(s-side3));
   TriangleArea := area;
end;

end.

Sonra, yukarıda tanımladığımız birimi kullanacak basit bir program yazalım -

program AreaCalculation;
uses CalculateArea,crt;

var
   l, w, r, a, b, c, area: real;

begin
   clrscr;
   l := 5.4;
   w := 4.7;
   area := RectangleArea(l, w);
   writeln('Area of Rectangle 5.4 x 4.7 is: ', area:7:3);

   r:= 7.0;
   area:= CircleArea(r);
   writeln('Area of Circle with radius 7.0 is: ', area:7:3);

   a := 3.0;
   b:= 4.0;
   c:= 5.0;
  
   area:= TriangleArea(a, b, c);
   writeln('Area of Triangle 3.0 by 4.0 by 5.0 is: ', area:7:3);
end.

Yukarıdaki kod derlendiğinde ve yürütüldüğünde, aşağıdaki sonucu verir -

Area of Rectangle 5.4 x 4.7 is: 25.380
Area of Circle with radius 7.0 is: 153.938
Area of Triangle 3.0 by 4.0 by 5.0 is: 6.000