Arduino - Cảm biến độ ẩm

Trong phần này, chúng ta sẽ tìm hiểu cách giao diện bảng Arduino của chúng ta với các cảm biến khác nhau. Chúng ta sẽ thảo luận về các cảm biến sau:

Cảm biến độ ẩm (DHT22)
Cảm biến nhiệt độ (LM35)
Cảm biến phát hiện nước (Kích hoạt nước đơn giản)
CẢM BIẾN PIR
THIẾT BỊ CẢM BIẾN SÓNG SIÊU ÂM
GPS

Cảm biến độ ẩm (DHT22)

DHT-22 (còn được đặt tên là AM2302) là cảm biến đầu ra kỹ thuật số, độ ẩm tương đối và nhiệt độ. Nó sử dụng cảm biến độ ẩm điện dung và một điện trở nhiệt để đo không khí xung quanh, và gửi tín hiệu kỹ thuật số trên chân dữ liệu.

Trong ví dụ này, bạn sẽ học cách sử dụng cảm biến này với Arduino UNO. Nhiệt độ và độ ẩm trong phòng sẽ được in ra màn hình nối tiếp.

Cảm biến DHT-22

Các kết nối rất đơn giản. Chân đầu tiên bên trái vào nguồn 3-5V, chân thứ hai vào chân đầu vào dữ liệu và chân ngoài cùng bên phải nối đất.

Chi tiết kỹ thuật

Power - 3-5V
Max Current - 2,5mA
Humidity - 0-100%, độ chính xác 2-5%
Temperature - Độ chính xác từ 40 đến 80 ° C, ± 0,5 ° C

Thành phần bắt buộc

Bạn sẽ cần các thành phần sau:

1 × Breadboard
1 × Arduino Uno R3
1 × DHT22
Điện trở 1 × 10K ohm

Thủ tục

Làm theo sơ đồ mạch và nối các thành phần trên breadboard như trong hình dưới đây.

Phác thảo

Mở phần mềm Arduino IDE trên máy tính của bạn. Mã hóa bằng ngôn ngữ Arduino sẽ điều khiển mạch của bạn. Mở một tệp phác thảo mới bằng cách nhấp vào Mới.

Mã Arduino

// Example testing sketch for various DHT humidity/temperature sensors

#include "DHT.h"
#define DHTPIN 2 // what digital pin we're connected to
// Uncomment whatever type you're using!
//#define DHTTYPE DHT11 // DHT 11
#define DHTTYPE DHT22 // DHT 22 (AM2302), AM2321
//#define DHTTYPE DHT21 // DHT 21 (AM2301)
// Connect pin 1 (on the left) of the sensor to +5V
// NOTE: If using a board with 3.3V logic like an Arduino Due connect pin 1
// to 3.3V instead of 5V!
// Connect pin 2 of the sensor to whatever your DHTPIN is
// Connect pin 4 (on the right) of the sensor to GROUND
// Connect a 10K resistor from pin 2 (data) to pin 1 (power) of the sensor
// Initialize DHT sensor.
// Note that older versions of this library took an optional third parameter to
// tweak the timings for faster processors. This parameter is no longer needed
// as the current DHT reading algorithm adjusts itself to work on faster procs.
DHT dht(DHTPIN, DHTTYPE);

void setup() {
   Serial.begin(9600);
   Serial.println("DHTxx test!");
   dht.begin();
}

void loop() {
   delay(2000); // Wait a few seconds between measurements
   float h = dht.readHumidity();
   // Reading temperature or humidity takes about 250 milliseconds!
   float t = dht.readTemperature();
   // Read temperature as Celsius (the default)
   float f = dht.readTemperature(true);
   // Read temperature as Fahrenheit (isFahrenheit = true)
   // Check if any reads failed and exit early (to try again).
   if (isnan(h) || isnan(t) || isnan(f)) {
      Serial.println("Failed to read from DHT sensor!");
      return;
   }
   
   // Compute heat index in Fahrenheit (the default)
   float hif = dht.computeHeatIndex(f, h);
   // Compute heat index in Celsius (isFahreheit = false)
   float hic = dht.computeHeatIndex(t, h, false);
   Serial.print ("Humidity: ");
   Serial.print (h);
   Serial.print (" %\t");
   Serial.print ("Temperature: ");
   Serial.print (t);
   Serial.print (" *C ");
   Serial.print (f);
   Serial.print (" *F\t");
   Serial.print ("Heat index: ");
   Serial.print (hic);
   Serial.print (" *C ");
   Serial.print (hif);
   Serial.println (" *F");
}

Mã cần lưu ý

Cảm biến DHT22 có bốn đầu cuối (V _cc , DATA, NC, GND), được kết nối với bo mạch như sau:

Chân DATA đến chân Arduino số 2
Chân V _cc đến 5 volt của bảng Arduino
Ghim GND vào mặt đất của bảng Arduino
Chúng ta cần phải kết nối 10k ohm resistor (pull up resistor) giữa DATA và V _cc pin

Sau khi kết nối phần cứng hoàn tất, bạn cần thêm thư viện DHT22 vào tệp thư viện Arduino của mình như đã mô tả trước đó.

Kết quả

Bạn sẽ thấy màn hình hiển thị nhiệt độ và độ ẩm trên màn hình cổng nối tiếp được cập nhật 2 giây một lần.