SAS - Biểu đồ hình tròn

Biểu đồ hình tròn là biểu diễn các giá trị dưới dạng các lát của hình tròn với các màu khác nhau. Các lát được dán nhãn và các số tương ứng với mỗi lát cũng được thể hiện trong biểu đồ.

Trong SAS, biểu đồ hình tròn được tạo bằng cách sử dụng PROC TEMPLATE lấy các tham số để kiểm soát tỷ lệ phần trăm, nhãn, màu sắc, tiêu đề, v.v.

Cú pháp

Cú pháp cơ bản để tạo biểu đồ tròn trong SAS là:

PROC TEMPLATE;
   DEFINE STATGRAPH pie;
      BEGINGRAPH;
         LAYOUT REGION;
            PIECHART CATEGORY = variable /
            DATALABELLOCATION = OUTSIDE
            CATEGORYDIRECTION = CLOCKWISE
            START = 180 NAME = 'pie';
            DISCRETELEGEND 'pie' /
            TITLE = ' ';
         ENDLAYOUT;
      ENDGRAPH;
   END;
RUN;

Sau đây là mô tả các tham số được sử dụng:

• variable là giá trị mà chúng tôi tạo biểu đồ hình tròn.

Biểu đồ hình tròn đơn giản

Trong biểu đồ hình tròn này, chúng tôi lấy một biến duy nhất tạo thành tập dữ liệu. Biểu đồ hình tròn được tạo với giá trị của các lát thể hiện phần nhỏ của số đếm của biến đối với tổng giá trị của biến.

Thí dụ

Trong ví dụ dưới đây, mỗi lát cắt đại diện cho một phần của loại ô tô trong tổng số ô tô.

PROC SQL;
create table CARS1 as
SELECT make, model, type, invoice, horsepower, length, weight
 FROM 
SASHELP.CARS
WHERE make in ('Audi','BMW')
;
RUN;

PROC TEMPLATE;
   DEFINE STATGRAPH pie;
      BEGINGRAPH;
         LAYOUT REGION;
            PIECHART CATEGORY = type /
            DATALABELLOCATION = OUTSIDE
            CATEGORYDIRECTION = CLOCKWISE
            START = 180 NAME = 'pie';
            DISCRETELEGEND 'pie' /
            TITLE = 'Car Types';
         ENDLAYOUT;
      ENDGRAPH;
   END;
RUN;
PROC SGRENDER DATA = cars1
            TEMPLATE = pie;
RUN;

Khi chúng tôi thực thi đoạn mã trên, chúng tôi nhận được kết quả sau:

Biểu đồ hình tròn có nhãn dữ liệu

Trong biểu đồ hình tròn này, chúng tôi đại diện cho cả giá trị phân số cũng như giá trị phần trăm cho mỗi lát. Chúng tôi cũng thay đổi vị trí của nhãn bên trong biểu đồ. Kiểu hiển thị của biểu đồ được sửa đổi bằng cách sử dụng tùy chọn DATASKIN. Nó sử dụng một trong những kiểu có sẵn, có sẵn trong môi trường SAS.

Thí dụ

PROC TEMPLATE;
   DEFINE STATGRAPH pie;
      BEGINGRAPH;
         LAYOUT REGION;
            PIECHART CATEGORY = type /
            DATALABELLOCATION = INSIDE
            DATALABELCONTENT = ALL
            CATEGORYDIRECTION = CLOCKWISE
            DATASKIN = SHEEN 
            START = 180 NAME = 'pie';
            DISCRETELEGEND 'pie' /
            TITLE = 'Car Types';
         ENDLAYOUT;
      ENDGRAPH;
   END;
RUN;
PROC SGRENDER DATA = cars1
            TEMPLATE = pie;
RUN;

Khi chúng tôi thực thi đoạn mã trên, chúng tôi nhận được kết quả sau:

Biểu đồ hình tròn được nhóm

Trong biểu đồ hình tròn này, giá trị của biến được trình bày trong biểu đồ được nhóm lại với một biến khác của cùng một tập dữ liệu. Mỗi nhóm trở thành một vòng tròn và biểu đồ có bao nhiêu vòng tròn đồng tâm bằng số lượng nhóm có sẵn.

Thí dụ

Trong ví dụ dưới đây, chúng tôi nhóm biểu đồ theo biến có tên "Make". Vì có sẵn hai giá trị ("Audi" và "BMW"), vì vậy chúng tôi nhận được hai vòng tròn đồng tâm, mỗi vòng tròn đại diện cho các lát của loại ô tô theo cách riêng của nó.

PROC TEMPLATE;
   DEFINE STATGRAPH pie;
      BEGINGRAPH;
         LAYOUT REGION;
            PIECHART CATEGORY = type / Group = make
            DATALABELLOCATION = INSIDE
            DATALABELCONTENT = ALL
            CATEGORYDIRECTION = CLOCKWISE
            DATASKIN = SHEEN 
            START = 180 NAME = 'pie';
            DISCRETELEGEND 'pie' /
            TITLE = 'Car Types';
         ENDLAYOUT;
      ENDGRAPH;
   END;
RUN;
PROC SGRENDER DATA = cars1
            TEMPLATE = pie;
RUN;

Khi chúng tôi thực thi đoạn mã trên, chúng tôi nhận được kết quả sau: