Fortran-동적 배열

ㅏ dynamic array 크기는 컴파일 시간에 알려지지 않았지만 실행 시간에 알려지는 배열입니다.

동적 배열은 속성으로 선언됩니다. allocatable.

예를 들면

real, dimension (:,:), allocatable :: darray

배열의 순위, 즉 차원을 언급해야하지만 이러한 배열에 메모리를 할당하려면 다음을 사용합니다. allocate 함수.

allocate ( darray(s1,s2) )

배열을 사용한 후 프로그램에서 생성 된 메모리는 deallocate 함수

deallocate (darray)

예

다음 예는 위에서 설명한 개념을 보여줍니다.

program dynamic_array 
implicit none 

   !rank is 2, but size not known   
   real, dimension (:,:), allocatable :: darray    
   integer :: s1, s2     
   integer :: i, j     
   
   print*, "Enter the size of the array:"     
   read*, s1, s2      
   
   ! allocate memory      
   allocate ( darray(s1,s2) )      
   
   do i = 1, s1           
      do j = 1, s2                
         darray(i,j) = i*j               
         print*, "darray(",i,",",j,") = ", darray(i,j)           
      end do      
   end do      
   
   deallocate (darray)  
end program dynamic_array

위의 코드가 컴파일되고 실행되면 다음과 같은 결과가 생성됩니다.

Enter the size of the array: 3,4
darray( 1 , 1 ) = 1.00000000    
darray( 1 , 2 ) = 2.00000000    
darray( 1 , 3 ) = 3.00000000    
darray( 1 , 4 ) = 4.00000000    
darray( 2 , 1 ) = 2.00000000    
darray( 2 , 2 ) = 4.00000000    
darray( 2 , 3 ) = 6.00000000    
darray( 2 , 4 ) = 8.00000000    
darray( 3 , 1 ) = 3.00000000    
darray( 3 , 2 ) = 6.00000000    
darray( 3 , 3 ) = 9.00000000    
darray( 3 , 4 ) = 12.0000000

데이터 진술의 사용

그만큼 data 문은 둘 이상의 배열을 초기화하거나 배열 섹션 초기화에 사용할 수 있습니다.

데이터 문의 구문은-

data variable / list / ...

예

다음 예제는 개념을 보여줍니다-

program dataStatement
implicit none

   integer :: a(5), b(3,3), c(10),i, j
   data a /7,8,9,10,11/ 
   
   data b(1,:) /1,1,1/ 
   data b(2,:)/2,2,2/ 
   data b(3,:)/3,3,3/ 
   data (c(i),i = 1,10,2) /4,5,6,7,8/ 
   data (c(i),i = 2,10,2)/5*2/
   
   Print *, 'The A array:'
   do j = 1, 5                
      print*, a(j)           
   end do 
   
   Print *, 'The B array:'
   do i = lbound(b,1), ubound(b,1)
      write(*,*) (b(i,j), j = lbound(b,2), ubound(b,2))
   end do

   Print *, 'The C array:' 
   do j = 1, 10                
      print*, c(j)           
   end do      
   
end program dataStatement

위의 코드가 컴파일되고 실행되면 다음과 같은 결과가 생성됩니다.

The A array:
           7
           8
           9
          10
          11
 The B array:
           1           1           1
           2           2           2
           3           3           3
 The C array:
           4
           2
           5
           2
           6
           2
           7
           2
           8
           2

Where 문 사용

그만큼 where문을 사용하면 일부 논리적 조건의 결과에 따라 표현식에서 배열의 일부 요소를 사용할 수 있습니다. 주어진 조건이 참인 경우 요소에서 표현식을 실행할 수 있습니다.

예

다음 예제는 개념을 보여줍니다-

program whereStatement
implicit none

   integer :: a(3,5), i , j
   
   do i = 1,3
      do j = 1, 5                
         a(i,j) = j-i          
      end do 
   end do
   
   Print *, 'The A array:'
   
   do i = lbound(a,1), ubound(a,1)
      write(*,*) (a(i,j), j = lbound(a,2), ubound(a,2))
   end do
   
   where( a<0 ) 
      a = 1 
   elsewhere
      a = 5
   end where
  
   Print *, 'The A array:'
   do i = lbound(a,1), ubound(a,1)
      write(*,*) (a(i,j), j = lbound(a,2), ubound(a,2))
   end do   
   
end program whereStatement

위의 코드가 컴파일되고 실행되면 다음과 같은 결과가 생성됩니다.

The A array:
           0           1           2           3           4
          -1           0           1           2           3
          -2          -1           0           1           2
 The A array:
           5           5           5           5           5
           1           5           5           5           5
           1           1           5           5           5