Arduino - датчик влажности

В этом разделе мы узнаем, как подключить нашу плату Arduino к различным датчикам. Мы обсудим следующие датчики -

• Датчик влажности (DHT22)
• Датчик температуры (LM35)
• Датчик детектора воды (Simple Water Trigger)
• ПИР-ДАТЧИК
• УЛЬТРАЗВУКОВЫЙ ДАТЧИК
• GPS

Датчик влажности (DHT22)

DHT-22 (также называемый AM2302) представляет собой датчик относительной влажности и температуры с цифровым выходом. Он использует емкостной датчик влажности и термистор для измерения окружающего воздуха и отправляет цифровой сигнал на вывод данных.

В этом примере вы узнаете, как использовать этот датчик с Arduino UNO. Комнатная температура и влажность будут распечатаны на серийном мониторе.

Датчик DHT-22

Подключения просты. Первый вывод слева для питания 3-5 В, второй вывод для ввода данных и самый правый вывод для заземления.

Технические детали

• Power - 3-5В

• Max Current - 2,5 мА

• Humidity - 0-100%, точность 2-5%

• Temperature - от 40 до 80 ° C, точность ± 0,5 ° C

Необходимые компоненты

Вам понадобятся следующие компоненты -

• 1 × Макетная плата
• 1 × Arduino Uno R3
• 1 × DHT22
• Резистор 1 × 10 кОм

Процедура

Следуя принципиальной схеме, подключите компоненты на макетной плате, как показано на рисунке ниже.

Эскиз

Откройте на своем компьютере программу Arduino IDE. Кодирование на языке Arduino будет управлять вашей схемой. Откройте новый файл эскиза, нажав кнопку «Создать».

Код Arduino

// Example testing sketch for various DHT humidity/temperature sensors

#include "DHT.h"
#define DHTPIN 2 // what digital pin we're connected to
// Uncomment whatever type you're using!
//#define DHTTYPE DHT11 // DHT 11
#define DHTTYPE DHT22 // DHT 22 (AM2302), AM2321
//#define DHTTYPE DHT21 // DHT 21 (AM2301)
// Connect pin 1 (on the left) of the sensor to +5V
// NOTE: If using a board with 3.3V logic like an Arduino Due connect pin 1
// to 3.3V instead of 5V!
// Connect pin 2 of the sensor to whatever your DHTPIN is
// Connect pin 4 (on the right) of the sensor to GROUND
// Connect a 10K resistor from pin 2 (data) to pin 1 (power) of the sensor
// Initialize DHT sensor.
// Note that older versions of this library took an optional third parameter to
// tweak the timings for faster processors. This parameter is no longer needed
// as the current DHT reading algorithm adjusts itself to work on faster procs.
DHT dht(DHTPIN, DHTTYPE);

void setup() {
   Serial.begin(9600);
   Serial.println("DHTxx test!");
   dht.begin();
}

void loop() {
   delay(2000); // Wait a few seconds between measurements
   float h = dht.readHumidity();
   // Reading temperature or humidity takes about 250 milliseconds!
   float t = dht.readTemperature();
   // Read temperature as Celsius (the default)
   float f = dht.readTemperature(true);
   // Read temperature as Fahrenheit (isFahrenheit = true)
   // Check if any reads failed and exit early (to try again).
   if (isnan(h) || isnan(t) || isnan(f)) {
      Serial.println("Failed to read from DHT sensor!");
      return;
   }
   
   // Compute heat index in Fahrenheit (the default)
   float hif = dht.computeHeatIndex(f, h);
   // Compute heat index in Celsius (isFahreheit = false)
   float hic = dht.computeHeatIndex(t, h, false);
   Serial.print ("Humidity: ");
   Serial.print (h);
   Serial.print (" %\t");
   Serial.print ("Temperature: ");
   Serial.print (t);
   Serial.print (" *C ");
   Serial.print (f);
   Serial.print (" *F\t");
   Serial.print ("Heat index: ");
   Serial.print (hic);
   Serial.print (" *C ");
   Serial.print (hif);
   Serial.println (" *F");
}

Код для примечания

Датчик DHT22 имеет четыре контакта (V _cc , DATA, NC, GND), которые подключаются к плате следующим образом:

• Вывод DATA на вывод Arduino номер 2
• _Вывод V _cc на 5 В на плате Arduino
• Вывод GND на землю платы Arduino
• Нам нужно подключить резистор 10 кОм (подтягивающий резистор) между DATA и выводом V _cc.

После подключения оборудования вам необходимо добавить библиотеку DHT22 в файл библиотеки Arduino, как описано ранее.

Результат

Вы увидите дисплей температуры и влажности на мониторе последовательного порта, который обновляется каждые 2 секунды.