Arduino - Управление кнопкой мыши

Используя библиотеку Mouse, вы можете управлять экранным курсором компьютера с помощью Arduino Leonardo, Micro или Due.

В этом конкретном примере для перемещения курсора на экране используются пять кнопок. Четыре кнопки являются направленными (вверх, вниз, влево, вправо), а одна - для щелчка левой кнопкой мыши. Перемещение курсора из Arduino всегда относительное. Каждый раз при чтении ввода положение курсора обновляется относительно его текущей позиции.

Каждый раз, когда нажимается одна из кнопок направления, Arduino перемещает мышь, сопоставляя ВЫСОКИЙ ввод с диапазоном 5 в соответствующем направлении.

Пятая кнопка предназначена для управления левым щелчком мыши. Когда кнопка будет отпущена, компьютер распознает событие.

Необходимые компоненты

Вам понадобятся следующие компоненты -

• 1 × Макетная плата
• 1 × плата Arduino Leonardo, Micro или Due
• Резистор 5 × 10 кОм
• 5 кнопок мгновенного действия

Процедура

Следуйте принципиальной схеме и подключите компоненты на макетной плате, как показано на рисунке ниже.

Эскиз

Откройте программное обеспечение Arduino IDE на вашем компьютере. Кодирование на языке Arduino будет управлять вашей схемой. Откройте новый файл эскиза, нажав кнопку «Создать».

Для этого примера вам нужно использовать Arduino IDE 1.6.7.

Код Arduino

/*
   Button Mouse Control
   For Leonardo and Due boards only .Controls the mouse from 
   five pushbuttons on an Arduino Leonardo, Micro or Due.
   Hardware:
   * 5 pushbuttons attached to D2, D3, D4, D5, D6
   The mouse movement is always relative. This sketch reads
   four pushbuttons, and uses them to set the movement of the mouse.
   WARNING: When you use the Mouse.move() command, the Arduino takes
   over your mouse! Make sure you have control before you use the mouse commands.
*/

#include "Mouse.h"
// set pin numbers for the five buttons:
const int upButton = 2;
const int downButton = 3;
const int leftButton = 4;
const int rightButton = 5;
const int mouseButton = 6;
int range = 5; // output range of X or Y movement; affects movement speed
int responseDelay = 10; // response delay of the mouse, in ms

void setup() {
   // initialize the buttons' inputs:
   pinMode(upButton, INPUT);
   pinMode(downButton, INPUT);
   pinMode(leftButton, INPUT);
   pinMode(rightButton, INPUT);
   pinMode(mouseButton, INPUT);
   // initialize mouse control:
   Mouse.begin();
}

void loop() {
   // read the buttons:
   int upState = digitalRead(upButton);
   int downState = digitalRead(downButton);
   int rightState = digitalRead(rightButton);
   int leftState = digitalRead(leftButton);
   int clickState = digitalRead(mouseButton);
   // calculate the movement distance based on the button states:
   int xDistance = (leftState - rightState) * range;
   int yDistance = (upState - downState) * range;
   // if X or Y is non-zero, move:
   if ((xDistance != 0) || (yDistance != 0)) {
      Mouse.move(xDistance, yDistance, 0);
   }

   // if the mouse button is pressed:
   if (clickState == HIGH) {
      // if the mouse is not pressed, press it:
      if (!Mouse.isPressed(MOUSE_LEFT)) {
         Mouse.press(MOUSE_LEFT);
      }
   } else {                           // else the mouse button is not pressed:
      // if the mouse is pressed, release it:
      if (Mouse.isPressed(MOUSE_LEFT)) {
         Mouse.release(MOUSE_LEFT);
      }
   }
   // a delay so the mouse does not move too fast:
   delay(responseDelay);
}

Код для примечания

Подключите вашу доску к компьютеру с помощью кабеля micro-USB. Кнопки подключены к цифровым входам от контактов 2 до 6. Убедитесь, что вы используете понижающие резисторы 10 кОм.