Arduino - Feuchtigkeitssensor

In diesem Abschnitt erfahren Sie, wie Sie unser Arduino-Board mit verschiedenen Sensoren verbinden. Wir werden die folgenden Sensoren diskutieren -

• Feuchtigkeitssensor (DHT22)
• Temperatursensor (LM35)
• Wasserdetektorsensor (einfacher Wasserauslöser)
• PIR SENSOR
• ULTRASCHALLSENSOR
• GPS

Feuchtigkeitssensor (DHT22)

Der DHT-22 (auch als AM2302 bezeichnet) ist ein Sensor für Digitalausgang, relative Luftfeuchtigkeit und Temperatur. Es verwendet einen kapazitiven Feuchtigkeitssensor und einen Thermistor, um die Umgebungsluft zu messen, und sendet ein digitales Signal an den Datenstift.

In diesem Beispiel erfahren Sie, wie Sie diesen Sensor mit Arduino UNO verwenden. Die Raumtemperatur und Luftfeuchtigkeit werden auf dem seriellen Monitor gedruckt.

Der DHT-22 Sensor

Die Verbindungen sind einfach. Der erste Pin links ist mit 3-5 V versorgt, der zweite Pin mit dem Dateneingangspin und der Pin ganz rechts mit Masse.

Technische Details

• Power - 3-5V

• Max Current - 2,5 mA

• Humidity - 0-100%, 2-5% Genauigkeit

• Temperature - 40 bis 80 ° C, ± 0,5 ° C Genauigkeit

Erforderliche Komponenten

Sie benötigen folgende Komponenten:

• 1 × Steckbrett
• 1 × Arduino Uno R3
• 1 × DHT22
• 1 × 10K Ohm Widerstand

Verfahren

Befolgen Sie den Schaltplan und schließen Sie die Komponenten wie in der Abbildung unten gezeigt am Steckbrett an.

Skizzieren

Öffnen Sie die Arduino IDE-Software auf Ihrem Computer. Die Codierung in der Arduino-Sprache steuert Ihre Schaltung. Öffnen Sie eine neue Skizzendatei, indem Sie auf Neu klicken.

Arduino Code

// Example testing sketch for various DHT humidity/temperature sensors

#include "DHT.h"
#define DHTPIN 2 // what digital pin we're connected to
// Uncomment whatever type you're using!
//#define DHTTYPE DHT11 // DHT 11
#define DHTTYPE DHT22 // DHT 22 (AM2302), AM2321
//#define DHTTYPE DHT21 // DHT 21 (AM2301)
// Connect pin 1 (on the left) of the sensor to +5V
// NOTE: If using a board with 3.3V logic like an Arduino Due connect pin 1
// to 3.3V instead of 5V!
// Connect pin 2 of the sensor to whatever your DHTPIN is
// Connect pin 4 (on the right) of the sensor to GROUND
// Connect a 10K resistor from pin 2 (data) to pin 1 (power) of the sensor
// Initialize DHT sensor.
// Note that older versions of this library took an optional third parameter to
// tweak the timings for faster processors. This parameter is no longer needed
// as the current DHT reading algorithm adjusts itself to work on faster procs.
DHT dht(DHTPIN, DHTTYPE);

void setup() {
   Serial.begin(9600);
   Serial.println("DHTxx test!");
   dht.begin();
}

void loop() {
   delay(2000); // Wait a few seconds between measurements
   float h = dht.readHumidity();
   // Reading temperature or humidity takes about 250 milliseconds!
   float t = dht.readTemperature();
   // Read temperature as Celsius (the default)
   float f = dht.readTemperature(true);
   // Read temperature as Fahrenheit (isFahrenheit = true)
   // Check if any reads failed and exit early (to try again).
   if (isnan(h) || isnan(t) || isnan(f)) {
      Serial.println("Failed to read from DHT sensor!");
      return;
   }
   
   // Compute heat index in Fahrenheit (the default)
   float hif = dht.computeHeatIndex(f, h);
   // Compute heat index in Celsius (isFahreheit = false)
   float hic = dht.computeHeatIndex(t, h, false);
   Serial.print ("Humidity: ");
   Serial.print (h);
   Serial.print (" %\t");
   Serial.print ("Temperature: ");
   Serial.print (t);
   Serial.print (" *C ");
   Serial.print (f);
   Serial.print (" *F\t");
   Serial.print ("Heat index: ");
   Serial.print (hic);
   Serial.print (" *C ");
   Serial.print (hif);
   Serial.println (" *F");
}

Zu beachtender Code

Der DHT22-Sensor verfügt über vier Anschlüsse (V _cc , DATA, NC, GND), die wie folgt mit der Karte verbunden sind:

• DATA-Pin an Arduino-Pin Nummer 2
• V _cc Pin an 5 Volt Arduino Board
• GND-Pin auf dem Boden der Arduino-Platine
• Wir müssen einen 10k Ohm Widerstand (Pull Up Widerstand) zwischen den DATA und dem V _cc Pin anschließen

Sobald die Hardwareverbindungen hergestellt sind, müssen Sie Ihrer Arduino-Bibliotheksdatei wie zuvor beschrieben eine DHT22-Bibliothek hinzufügen.

Ergebnis

Sie sehen die Temperatur- und Feuchtigkeitsanzeige auf dem Monitor der seriellen Schnittstelle, die alle 2 Sekunden aktualisiert wird.