Arduino - Maustastensteuerung

Mit der Mausbibliothek können Sie den Bildschirmcursor eines Computers mit einem Arduino Leonardo, Micro oder Due steuern.

In diesem Beispiel werden fünf Drucktasten verwendet, um den Bildschirmcursor zu bewegen. Vier der Schaltflächen sind gerichtet (nach oben, unten, links, rechts) und eine für einen linken Mausklick. Die Cursorbewegung von Arduino ist immer relativ. Jedes Mal, wenn eine Eingabe gelesen wird, wird die Position des Cursors relativ zu seiner aktuellen Position aktualisiert.

Immer wenn eine der Richtungstasten gedrückt wird, bewegt Arduino die Maus und ordnet einen HIGH-Eingang einem Bereich von 5 in die entsprechende Richtung zu.

Die fünfte Schaltfläche dient zum Steuern eines Linksklicks mit der Maus. Wenn die Taste losgelassen wird, erkennt der Computer das Ereignis.

Erforderliche Komponenten

Sie benötigen folgende Komponenten:

• 1 × Steckbrett
• 1 × Arduino Leonardo, Micro oder Due Board
• 5 × 10 kOhm Widerstand
• 5 × kurzzeitige Drucktasten

Verfahren

Befolgen Sie den Schaltplan und schließen Sie die Komponenten wie in der Abbildung unten gezeigt am Steckbrett an.

Skizzieren

Öffnen Sie die Arduino IDE-Software auf Ihrem Computer. Die Codierung in der Arduino-Sprache steuert Ihre Schaltung. Öffnen Sie eine neue Skizzendatei, indem Sie auf Neu klicken.

In diesem Beispiel müssen Sie Arduino IDE 1.6.7 verwenden

Arduino Code

/*
   Button Mouse Control
   For Leonardo and Due boards only .Controls the mouse from 
   five pushbuttons on an Arduino Leonardo, Micro or Due.
   Hardware:
   * 5 pushbuttons attached to D2, D3, D4, D5, D6
   The mouse movement is always relative. This sketch reads
   four pushbuttons, and uses them to set the movement of the mouse.
   WARNING: When you use the Mouse.move() command, the Arduino takes
   over your mouse! Make sure you have control before you use the mouse commands.
*/

#include "Mouse.h"
// set pin numbers for the five buttons:
const int upButton = 2;
const int downButton = 3;
const int leftButton = 4;
const int rightButton = 5;
const int mouseButton = 6;
int range = 5; // output range of X or Y movement; affects movement speed
int responseDelay = 10; // response delay of the mouse, in ms

void setup() {
   // initialize the buttons' inputs:
   pinMode(upButton, INPUT);
   pinMode(downButton, INPUT);
   pinMode(leftButton, INPUT);
   pinMode(rightButton, INPUT);
   pinMode(mouseButton, INPUT);
   // initialize mouse control:
   Mouse.begin();
}

void loop() {
   // read the buttons:
   int upState = digitalRead(upButton);
   int downState = digitalRead(downButton);
   int rightState = digitalRead(rightButton);
   int leftState = digitalRead(leftButton);
   int clickState = digitalRead(mouseButton);
   // calculate the movement distance based on the button states:
   int xDistance = (leftState - rightState) * range;
   int yDistance = (upState - downState) * range;
   // if X or Y is non-zero, move:
   if ((xDistance != 0) || (yDistance != 0)) {
      Mouse.move(xDistance, yDistance, 0);
   }

   // if the mouse button is pressed:
   if (clickState == HIGH) {
      // if the mouse is not pressed, press it:
      if (!Mouse.isPressed(MOUSE_LEFT)) {
         Mouse.press(MOUSE_LEFT);
      }
   } else {                           // else the mouse button is not pressed:
      // if the mouse is pressed, release it:
      if (Mouse.isPressed(MOUSE_LEFT)) {
         Mouse.release(MOUSE_LEFT);
      }
   }
   // a delay so the mouse does not move too fast:
   delay(responseDelay);
}

Zu beachtender Code

Schließen Sie Ihr Board mit einem Micro-USB-Kabel an Ihren Computer an. Die Tasten sind mit den digitalen Eingängen von Pin 2 bis 6 verbunden. Stellen Sie sicher, dass Sie 10k Pulldown-Widerstände verwenden.