Dプログラミング-タプル

タプルは、複数の値を1つのオブジェクトとして組み合わせるために使用されます。タプルには一連の要素が含まれています。要素は、タイプ、式、またはエイリアスにすることができます。タプルの数と要素はコンパイル時に固定されており、実行時に変更することはできません。

タプルには、構造体と配列の両方の特性があります。タプル要素は、構造体のようにさまざまなタイプにすることができます。要素には、配列のようなインデックスを使用してアクセスできます。これらは、std.typeconsモジュールのタプルテンプレートによってライブラリ機能として実装されます。タプルは、その操作の一部にstd.typetupleモジュールのTypeTupleを利用します。

tuple（）を使用したタプル

タプルは関数tuple（）で作成できます。タプルのメンバーは、インデックス値によってアクセスされます。以下に例を示します。

例

import std.stdio; 
import std.typecons; 
 
void main() { 
   auto myTuple = tuple(1, "Tuts"); 
   writeln(myTuple); 
   writeln(myTuple[0]); 
   writeln(myTuple[1]); 
}

上記のコードをコンパイルして実行すると、次の結果が得られます。

Tuple!(int, string)(1, "Tuts") 
1 
Tuts

タプルテンプレートを使用したタプル

タプルは、tuple（）関数の代わりに、タプルテンプレートによって直接構築することもできます。各メンバーのタイプと名前は、2つの連続するテンプレートパラメーターとして指定されます。テンプレートを使用して作成すると、プロパティによってメンバーにアクセスできます。

import std.stdio; 
import std.typecons; 

void main() { 
   auto myTuple = Tuple!(int, "id",string, "value")(1, "Tuts"); 
   writeln(myTuple);  
   
   writeln("by index 0 : ", myTuple[0]); 
   writeln("by .id : ", myTuple.id); 
   
   writeln("by index 1 : ", myTuple[1]); 
   writeln("by .value ", myTuple.value); 
}

上記のコードをコンパイルして実行すると、次の結果が得られます。

Tuple!(int, "id", string, "value")(1, "Tuts") 
by index 0 : 1 
by .id : 1 
by index 1 : Tuts 
by .value Tuts

プロパティと関数のパラメータの拡張

タプルのメンバーは、.expandプロパティまたはスライスのいずれかによって展開できます。この展開/スライスされた値は、関数の引数リストとして渡すことができます。以下に例を示します。

例

import std.stdio; 
import std.typecons;
 
void method1(int a, string b, float c, char d) { 
   writeln("method 1 ",a,"\t",b,"\t",c,"\t",d); 
}
 
void method2(int a, float b, char c) { 
   writeln("method 2 ",a,"\t",b,"\t",c); 
}
 
void main() { 
   auto myTuple = tuple(5, "my string", 3.3, 'r'); 
   
   writeln("method1 call 1"); 
   method1(myTuple[]); 
   
   writeln("method1 call 2"); 
   method1(myTuple.expand); 
   
   writeln("method2 call 1"); 
   method2(myTuple[0], myTuple[$-2..$]); 
}

上記のコードをコンパイルして実行すると、次の結果が得られます。

method1 call 1 
method 1 5 my string 3.3 r
method1 call 2 
method 1 5 my string 3.3 r 
method2 call 1 
method 2 5 3.3 r

TypeTuple

TypeTupleは、std.typetupleモジュールで定義されています。値とタイプのコンマ区切りのリスト。TypeTupleを使用した簡単な例を以下に示します。TypeTupleは、引数リスト、テンプレートリスト、および配列リテラルリストを作成するために使用されます。

import std.stdio; 
import std.typecons; 
import std.typetuple; 
 
alias TypeTuple!(int, long) TL;  

void method1(int a, string b, float c, char d) { 
   writeln("method 1 ",a,"\t",b,"\t",c,"\t",d); 
} 

void method2(TL tl) { 
   writeln(tl[0],"\t", tl[1] ); 
} 
 
void main() { 
   auto arguments = TypeTuple!(5, "my string", 3.3,'r');  
   method1(arguments); 
   method2(5, 6L);  
}

上記のコードをコンパイルして実行すると、次の結果が得られます。

method 1 5 my string 3.3 r 
5     6