SAS-ブランドアルトマン分析

Bland-Altman分析は、同じパラメーターを測定するように設計された2つの方法間の一致または不一致の程度を検証するプロセスです。メソッド間の高い相関関係は、データ分析で十分なサンプルが選択されたことを示しています。SASでは、変数値の平均、上限、下限を計算することにより、ブランド-アルトマンプロットを作成します。次に、PROC SGPLOTを使用して、ブランド-アルトマンプロットを作成します。

構文

SASでPROCSGPLOTを適用するための基本的な構文は次のとおりです。

PROC SGPLOT DATA = dataset;
SCATTER X = variable Y = Variable;
REFLINE value;

以下は、使用されるパラメーターの説明です-

Dataset データセットの名前です。
SCATTER ステートメントは、XおよびYの形式で提供された値の散布図グラフを示します。
REFLINE 水平または垂直の参照線を作成します。

例

以下の例では、newとoldという名前の2つのメソッドによって生成された2つの実験の結果を取り上げます。変数の値の差と、同じ観測値の変数の平均を計算します。また、計算の上限と下限に使用される標準偏差値も計算します。

結果は、散布図としてブランド-アルトマンプロットを示しています。

data mydata;
input new old;
datalines;
31 45
27 12
11 37
36 25
14 8
27 15
3 11
62 42
38 35
20 9
35 54
62 67
48 25
77 64
45 53
32 42
16 19
15 27
22 9
8 38
24 16
59 25
;

data diffs ;
set mydata ;
/* calculate the difference */
diff = new-old ;
/* calculate the average */
mean = (new+old)/2 ;
run ;
proc print data = diffs;
run;

proc sql noprint ;
select mean(diff)-2*std(diff),  mean(diff)+2*std(diff)
into   :lower,  :upper 
from diffs ;
quit;

proc sgplot data = diffs ;
scatter x = mean y = diff;
refline 0 &upper &lower / LABEL = ("zero bias line" "95% upper limit" "95%
lower limit");
TITLE 'Bland-Altman Plot';
footnote 'Accurate prediction with 10% homogeneous error'; 
run ;
quit ;

上記のコードを実行すると、次の結果が得られます。

強化されたモデル

上記のプログラムの拡張モデルでは、95％の信頼水準のカーブフィッティングが得られます。

proc sgplot data = diffs ;
reg x = new y = diff/clm clmtransparency = .5;
needle x = new y = diff/baseline = 0;
refline 0 / LABEL = ('No diff line');
TITLE 'Enhanced Bland-Altman Plot';
footnote 'Accurate prediction with 10% homogeneous error'; 
run ;
quit ;

上記のコードを実行すると、次の結果が得られます。