Arduino - आर्द्रता संवेदक

इस अनुभाग में, हम सीखेंगे कि विभिन्न सेंसरों के साथ हमारे Arduino बोर्ड को कैसे इंटरफ़ेस करें। हम निम्नलिखित सेंसर पर चर्चा करेंगे -

• आर्द्रता सेंसर (DHT22)
• तापमान संवेदक (LM35)
• पानी डिटेक्टर सेंसर (सरल पानी ट्रिगर)
• पीर सेंसर
• अतिध्वनि संवेदक
• GPS

आर्द्रता सेंसर (DHT22)

DHT-22 (जिसे AM2302 भी कहा जाता है) एक डिजिटल-आउटपुट, सापेक्षिक आर्द्रता और तापमान संवेदक है। यह आस-पास की हवा को मापने के लिए एक कैपेसिटिव ह्यूमिडिटी सेंसर और एक थर्मिस्टर का उपयोग करता है, और डेटा पिन पर एक डिजिटल सिग्नल भेजता है।

इस उदाहरण में, आप सीखेंगे कि Arduino UNO के साथ इस सेंसर का उपयोग कैसे करें। कमरे के तापमान और आर्द्रता को सीरियल मॉनिटर पर मुद्रित किया जाएगा।

DHT-22 सेंसर

कनेक्शन सरल हैं। 3-5V शक्ति के लिए बाईं ओर पहला पिन, डेटा इनपुट पिन के लिए दूसरा पिन और जमीन पर दाईं-सबसे पिन।

तकनीकी जानकारी

• Power - 3-5 वी

• Max Current - 2.5mA

• Humidity - 0-100%, 2-5% सटीकता

• Temperature - 40 से 80 ° C, C 0.5 ° C सटीकता

अवयव आवश्यक

आपको निम्नलिखित घटकों की आवश्यकता होगी -

• 1 × ब्रेडबोर्ड
• 1 × Arduino Uno R3
• 1 × DHT22
• 1 × 10K ओम रोकनेवाला

प्रक्रिया

सर्किट आरेख का पालन करें और ब्रेडबोर्ड पर घटकों को हुक करें जैसा कि नीचे की छवि में दिखाया गया है।

स्केच

अपने कंप्यूटर पर Arduino IDE सॉफ्टवेयर खोलें। Arduino भाषा में कोडिंग आपके सर्किट को नियंत्रित करेगा। New पर क्लिक करके एक नया स्केच फाइल खोलें।

Arduino कोड

// Example testing sketch for various DHT humidity/temperature sensors

#include "DHT.h"
#define DHTPIN 2 // what digital pin we're connected to
// Uncomment whatever type you're using!
//#define DHTTYPE DHT11 // DHT 11
#define DHTTYPE DHT22 // DHT 22 (AM2302), AM2321
//#define DHTTYPE DHT21 // DHT 21 (AM2301)
// Connect pin 1 (on the left) of the sensor to +5V
// NOTE: If using a board with 3.3V logic like an Arduino Due connect pin 1
// to 3.3V instead of 5V!
// Connect pin 2 of the sensor to whatever your DHTPIN is
// Connect pin 4 (on the right) of the sensor to GROUND
// Connect a 10K resistor from pin 2 (data) to pin 1 (power) of the sensor
// Initialize DHT sensor.
// Note that older versions of this library took an optional third parameter to
// tweak the timings for faster processors. This parameter is no longer needed
// as the current DHT reading algorithm adjusts itself to work on faster procs.
DHT dht(DHTPIN, DHTTYPE);

void setup() {
   Serial.begin(9600);
   Serial.println("DHTxx test!");
   dht.begin();
}

void loop() {
   delay(2000); // Wait a few seconds between measurements
   float h = dht.readHumidity();
   // Reading temperature or humidity takes about 250 milliseconds!
   float t = dht.readTemperature();
   // Read temperature as Celsius (the default)
   float f = dht.readTemperature(true);
   // Read temperature as Fahrenheit (isFahrenheit = true)
   // Check if any reads failed and exit early (to try again).
   if (isnan(h) || isnan(t) || isnan(f)) {
      Serial.println("Failed to read from DHT sensor!");
      return;
   }
   
   // Compute heat index in Fahrenheit (the default)
   float hif = dht.computeHeatIndex(f, h);
   // Compute heat index in Celsius (isFahreheit = false)
   float hic = dht.computeHeatIndex(t, h, false);
   Serial.print ("Humidity: ");
   Serial.print (h);
   Serial.print (" %\t");
   Serial.print ("Temperature: ");
   Serial.print (t);
   Serial.print (" *C ");
   Serial.print (f);
   Serial.print (" *F\t");
   Serial.print ("Heat index: ");
   Serial.print (hic);
   Serial.print (" *C ");
   Serial.print (hif);
   Serial.println (" *F");
}

नोट करने के लिए कोड

DHT22 सेंसर में चार टर्मिनल (V _cc , DATA, NC, GND) हैं, जो बोर्ड से जुड़े हैं -

• Arduino पिन नंबर 2 को DATA पिन
• अरुडिनो बोर्ड के 5 वोल्ट का वी _सीसी पिन
• Arduino बोर्ड की जमीन पर GND पिन
• हमें DATA और V _cc पिन के बीच 10k ओम रेसिस्टर (पुल अप रेज़र) को कनेक्ट करना होगा

एक बार हार्डवेयर कनेक्शन हो जाने के बाद, आपको पहले वर्णित के अनुसार अपनी Arduino लाइब्रेरी फ़ाइल में DHT22 लाइब्रेरी को जोड़ना होगा।

परिणाम

आप सीरियल पोर्ट मॉनिटर पर तापमान और आर्द्रता का प्रदर्शन देखेंगे जो हर 2 सेकंड में अपडेट किया जाता है।