SAS - gráficos de pizza

Um gráfico de pizza é uma representação de valores como fatias de um círculo com cores diferentes. As fatias são rotuladas e os números correspondentes a cada fatia também são representados no gráfico.

No SAS, o gráfico de pizza é criado usando PROC TEMPLATE que leva parâmetros para controlar a porcentagem, rótulos, cor, título etc.

Sintaxe

A sintaxe básica para criar um gráfico de pizza no SAS é -

PROC TEMPLATE;
   DEFINE STATGRAPH pie;
      BEGINGRAPH;
         LAYOUT REGION;
            PIECHART CATEGORY = variable /
            DATALABELLOCATION = OUTSIDE
            CATEGORYDIRECTION = CLOCKWISE
            START = 180 NAME = 'pie';
            DISCRETELEGEND 'pie' /
            TITLE = ' ';
         ENDLAYOUT;
      ENDGRAPH;
   END;
RUN;

A seguir está a descrição dos parâmetros usados ​​-

• variable é o valor para o qual criamos o gráfico de pizza.

Gráfico de pizza simples

Neste gráfico de pizza, consideramos uma única variável do conjunto de dados. O gráfico de pizza é criado com o valor das fatias que representam a fração da contagem da variável em relação ao valor total da variável.

Exemplo

No exemplo a seguir, cada fatia representa a fração do tipo de carro do número total de carros.

PROC SQL;
create table CARS1 as
SELECT make, model, type, invoice, horsepower, length, weight
 FROM 
SASHELP.CARS
WHERE make in ('Audi','BMW')
;
RUN;

PROC TEMPLATE;
   DEFINE STATGRAPH pie;
      BEGINGRAPH;
         LAYOUT REGION;
            PIECHART CATEGORY = type /
            DATALABELLOCATION = OUTSIDE
            CATEGORYDIRECTION = CLOCKWISE
            START = 180 NAME = 'pie';
            DISCRETELEGEND 'pie' /
            TITLE = 'Car Types';
         ENDLAYOUT;
      ENDGRAPH;
   END;
RUN;
PROC SGRENDER DATA = cars1
            TEMPLATE = pie;
RUN;

Quando executamos o código acima, obtemos a seguinte saída -

Gráfico de pizza com rótulos de dados

Neste gráfico de pizza, representamos tanto o valor fracionário quanto o valor percentual de cada fatia. Também alteramos a localização do rótulo para estar dentro do gráfico. O estilo de aparência do gráfico é modificado usando a opção DATASKIN. Ele usa um dos estilos embutidos, disponíveis no ambiente SAS.

Exemplo

PROC TEMPLATE;
   DEFINE STATGRAPH pie;
      BEGINGRAPH;
         LAYOUT REGION;
            PIECHART CATEGORY = type /
            DATALABELLOCATION = INSIDE
            DATALABELCONTENT = ALL
            CATEGORYDIRECTION = CLOCKWISE
            DATASKIN = SHEEN 
            START = 180 NAME = 'pie';
            DISCRETELEGEND 'pie' /
            TITLE = 'Car Types';
         ENDLAYOUT;
      ENDGRAPH;
   END;
RUN;
PROC SGRENDER DATA = cars1
            TEMPLATE = pie;
RUN;

Quando executamos o código acima, obtemos a seguinte saída -

Grouped Pie Chart

Neste gráfico de pizza, o valor da variável apresentada no gráfico é agrupado em relação a outra variável do mesmo conjunto de dados. Cada grupo se torna um círculo e o gráfico tem tantos círculos concêntricos quanto o número de grupos disponíveis.

Exemplo

No exemplo abaixo, agrupamos o gráfico em relação à variável chamada "Marca". Como existem dois valores disponíveis ("Audi" e "BMW"), obtemos dois círculos concêntricos, cada um representando fatias de tipos de carros de sua própria marca.

PROC TEMPLATE;
   DEFINE STATGRAPH pie;
      BEGINGRAPH;
         LAYOUT REGION;
            PIECHART CATEGORY = type / Group = make
            DATALABELLOCATION = INSIDE
            DATALABELCONTENT = ALL
            CATEGORYDIRECTION = CLOCKWISE
            DATASKIN = SHEEN 
            START = 180 NAME = 'pie';
            DISCRETELEGEND 'pie' /
            TITLE = 'Car Types';
         ENDLAYOUT;
      ENDGRAPH;
   END;
RUN;
PROC SGRENDER DATA = cars1
            TEMPLATE = pie;
RUN;

Quando executamos o código acima, obtemos a seguinte saída -