SAS - Pasta Grafikler

Pasta grafik, farklı renklere sahip bir dairenin dilimleri olarak değerlerin temsilidir. Dilimler etiketlenir ve her bir dilime karşılık gelen sayılar da grafikte gösterilir.

SAS'da pasta grafik kullanılarak oluşturulur PROC TEMPLATE yüzdeyi, etiketleri, rengi, başlığı vb. kontrol etmek için parametreleri alır.

Sözdizimi

SAS'da pasta grafik oluşturmak için temel sözdizimi şudur:

PROC TEMPLATE;
   DEFINE STATGRAPH pie;
      BEGINGRAPH;
         LAYOUT REGION;
            PIECHART CATEGORY = variable /
            DATALABELLOCATION = OUTSIDE
            CATEGORYDIRECTION = CLOCKWISE
            START = 180 NAME = 'pie';
            DISCRETELEGEND 'pie' /
            TITLE = ' ';
         ENDLAYOUT;
      ENDGRAPH;
   END;
RUN;

Aşağıda kullanılan parametrelerin açıklaması verilmiştir -

• variable pasta grafiği oluşturduğumuz değerdir.

Basit Pasta Grafiği

Bu pasta grafiğinde, veri kümesinden tek bir değişken alıyoruz. Pasta grafik, değişkenin toplam değerine göre değişkenin sayısının kesirini temsil eden dilimlerin değeriyle oluşturulur.

Misal

Aşağıdaki örnekte her bir dilim, otomobil tipinin toplam araba sayısından oranını temsil etmektedir.

PROC SQL;
create table CARS1 as
SELECT make, model, type, invoice, horsepower, length, weight
 FROM 
SASHELP.CARS
WHERE make in ('Audi','BMW')
;
RUN;

PROC TEMPLATE;
   DEFINE STATGRAPH pie;
      BEGINGRAPH;
         LAYOUT REGION;
            PIECHART CATEGORY = type /
            DATALABELLOCATION = OUTSIDE
            CATEGORYDIRECTION = CLOCKWISE
            START = 180 NAME = 'pie';
            DISCRETELEGEND 'pie' /
            TITLE = 'Car Types';
         ENDLAYOUT;
      ENDGRAPH;
   END;
RUN;
PROC SGRENDER DATA = cars1
            TEMPLATE = pie;
RUN;

Yukarıdaki kodu çalıştırdığımızda aşağıdaki çıktıyı alıyoruz -

Veri Etiketli Pasta Grafik

Bu pasta grafiğinde, her bir dilim için hem kesirli değeri hem de yüzde değerini temsil ediyoruz. Ayrıca etiketin konumunu da grafiğin içinde olacak şekilde değiştiriyoruz. Grafiğin görünüm stili, DATASKIN seçeneği kullanılarak değiştirilir. SAS ortamında bulunan dahili stillerden birini kullanır.

Misal

PROC TEMPLATE;
   DEFINE STATGRAPH pie;
      BEGINGRAPH;
         LAYOUT REGION;
            PIECHART CATEGORY = type /
            DATALABELLOCATION = INSIDE
            DATALABELCONTENT = ALL
            CATEGORYDIRECTION = CLOCKWISE
            DATASKIN = SHEEN 
            START = 180 NAME = 'pie';
            DISCRETELEGEND 'pie' /
            TITLE = 'Car Types';
         ENDLAYOUT;
      ENDGRAPH;
   END;
RUN;
PROC SGRENDER DATA = cars1
            TEMPLATE = pie;
RUN;

Yukarıdaki kodu çalıştırdığımızda aşağıdaki çıktıyı alıyoruz -

Gruplanmış Pasta Grafiği

Bu pasta grafiğinde, grafikte sunulan değişkenin değeri, aynı veri setinin başka bir değişkenine göre gruplandırılmıştır. Her grup bir daire haline gelir ve grafikte mevcut grup sayısı kadar eşmerkezli daire bulunur.

Misal

Aşağıdaki örnekte grafiği "Make" adlı değişkene göre gruplandırıyoruz. Kullanılabilir iki değer olduğundan ("Audi" ve "BMW") bu nedenle, her biri kendi markasındaki otomobil türlerinin dilimlerini temsil eden iki eş merkezli daire elde ederiz.

PROC TEMPLATE;
   DEFINE STATGRAPH pie;
      BEGINGRAPH;
         LAYOUT REGION;
            PIECHART CATEGORY = type / Group = make
            DATALABELLOCATION = INSIDE
            DATALABELCONTENT = ALL
            CATEGORYDIRECTION = CLOCKWISE
            DATASKIN = SHEEN 
            START = 180 NAME = 'pie';
            DISCRETELEGEND 'pie' /
            TITLE = 'Car Types';
         ENDLAYOUT;
      ENDGRAPH;
   END;
RUN;
PROC SGRENDER DATA = cars1
            TEMPLATE = pie;
RUN;

Yukarıdaki kodu çalıştırdığımızda aşağıdaki çıktıyı alıyoruz -