`PlotLabel` для участков в` Table`

Question

У меня есть Tableдва сюжета, предоставленные

Table[
 Plot[{Re[f[n]] /. j -> 3, Im[f[n]] /. j -> 3}, {n, 0, 15}, 
  GridLines -> Automatic, PlotRange -> All, PlotLegends -> {"Real", "Imaginary"}, 
  PlotLabel -> f[n]], 
{f, {Sum[Sinc[Pi*(#1 - i*j)], {i, 1, Floor[#1]}] & , 
   (-1 + E^(2*I*Pi*#1))/(j*(-1 + E^((2*I*Pi*#1)/j))) & }}
]

Как видите, Mathematica переписала первое PlotLabel(т. Е. Sum[Sinc[Pi*(#1 - i*j)], {i, 1, Floor[#1]}] &) В выражение, которое считает более полезным или естественным. Я не хочу этого делать. Я хочу, PlotLabelчтобы этот сюжет выглядел так:

т.е. как бы написано PlotLabel -> "expr". Но другой лейбл уже такой, какой я хочу.

Я экспериментировал с использованием, StringFormно это не помогает. Как мне это сделать? Или это невозможно?

Answer 1

Table[Plot[{Re[ReleaseHold@f] /. j -> 3,  Im[ReleaseHold@f] /. j -> 3}, {n, 0, 15}, 
  GridLines -> Automatic, 
  PlotRange -> All, ImageSize -> 350, 
  PlotLegends -> {"Real", "Imaginary"}, 
  PlotLabel ->  f], 
{f, {HoldForm@Sum[Sinc[Pi*(n - i*j)], {i, 1, Floor[n]}], 
   HoldForm[(-1 + E^(2*I*Pi*n))/(j*(-1 + E^((2*I*Pi*n)/j)))]}}]

Вы можете заменить HoldFormи ReleaseHoldна Deferи First, соответственно, чтобы получить тот же результат.

Как предложил Боб Хэнлон в комментариях, в версиях 12.0+ вы можете использовать ReImPlotследующее:

 Table[ReImPlot[ReleaseHold[f] /. j -> 3, {n, 0, 15}, 
    GridLines -> Automatic, PlotRange -> All, ImageSize -> 350, 
    PlotLegends -> "ReIm", 
    ReImLabels -> {"Real", "Imaginary"}, 
    ReImStyle -> {ColorData[97][1], {ColorData[97][2], Dashing[{}]}},
    PlotLabel -> f], 
  {f, {HoldForm@Sum[Sinc[Pi*(n - i*j)], {i, 1, Floor[n]}], 
      HoldForm[(-1 + E^(2*I*Pi*n))/(j*(-1 + E^((2*I*Pi*n)/j)))]}}]