Сбор общих степеней терминов

Question

Как собрать общие полномочия, появляющиеся в следующей функции, с помощью MATHEMATICA, так что если я введу

(4 m^6)/((m - n)^2 (m + n)^4 (2m+n)^4) 

тогда вывод должен отображаться как

((2 m^3)/((m - n) (m + n)^2 (2m+n)^2))^2

Изменить: В общем, если есть много членов с разными степенями как в числителе, так и в знаменателе, то требуется НОД всех степеней членов как в числителе, так и в знаменателе. Например, если у нас есть следующие

(a1^(n1)a2^(n2)a3^(n3)a4^(n4)...a^(nn))/(b1^(m1)b2^(m2)b3^(m3)b4^(m4)...bm^(mm))

То, что можно было бы принять за общую силу, - это

GCD(n1,n2,...,nn,m1,m2,m3....mm)

Answer 1

expr = (4 m^6)/((m - n)^2 (m + n)^4 (2 m + n)^4);

Запрошенная форма автоматически упростится до исходного выражения.

((2 m^3)/((m - n) (m + n)^2 (2 m + n)^2))^2

(* (4 m^6)/((m - n)^2 (m + n)^4 (2 m + n)^4) *&)

Чтобы сохранить запрошенную форму, вам необходимо предотвратить автоматическое упрощение

expr2 = Module[{$a}, Inactive[Power][ ($a /. Solve[expr == $a^2, $a][[-1]]), 2]]

expr2 // Activate

(* (4 m^6)/((m - n)^2 (m + n)^4 (2 m + n)^4) *)

РЕДАКТИРОВАТЬ:

expr = (a1^3 a2^6 a3^9 a4^6 a5^6)/(b1^3 b2^12 b3^15 b4^9 b5^6);

gcd = GCD @@ Cases[expr, x_^p_. :> p, 1]

(* 3 *)

Inactive[Power][(expr /. x_^p_ :> x^(p/gcd)), gcd]

(% // Activate) === expr

(* True *)

РЕДАКТИРОВАТЬ 2:

format[expr_] := Module[{coef, gcd},
  coef = expr /. {a_Integer r_ :> a, r_ :> 1};
  gcd = GCD @@
    Cases[expr/coef, (a : _Integer : 1) x_^p_. :> p, 1];
  Inactive[Power][
   (expr/(coef^(1/gcd)) /. x_^p_ :> x^(p/gcd)), gcd]]

format[(4 m^6)/((m - n)^2 (m + n)^4 (2 m + n)^4)]

format[(a1^3 a2^6 a3^9 a4^6 a5^6)/(b1^3 b2^12 b3^15 b4^9 b5^6)]