Первые элементы в подсписках

Question

Дано

t1 = {{{1, 2, 3, 4}, {5, 6, {15, 16}, 7}}, {11, 12, 13, 14}};

Я пытаюсь получить Firstэлементы из подсписок, которые дали бы

{1,5,15,11}

Как использовать First, Takeили #1от этой проблемы?

Answer 1

Если сохранение «порядка» извлеченных элементов имеет значение, вы можете использовать

ClearAll[fa, fb]

fa = Cases[ReplaceRepeated[{a : Except[_List], b__} :> {{a}, b}]@#, {x_} :>  x, All] &;
fb = Cases[MapAll[# /. {a : Except[_List], b__} :> {{a}, b} &, #], {x_} :> x, All] &;

Примеры:

t1 = {{{1, 2, 3, 4}, {5, 6, {15, 16}, 7}}, {11, 12, 13, 14}}; 
t2 = {{a, 2, 3, 4}, {b, 6, {c, 8, {{d, 8, 9}, {e, 3, 3, 2}}, {f, 5, 7}}}};(*from cvgmt's answer*)
t3 = {{{1, 2, 3, 4}, {5, 6, {15, {16, {17, {18}}}}, 7}}, {11, 12, 13, 14}};

fa /@ {t1, t2, t3}

  {{1, 5, 15, 11}, 
   {a, b, c, d, e, f},
   {1, 5, 15, 16, 17, 18, 11}}

fb /@ {t1, t2, t3}

  {{1, 5, 15, 11}, 
   {a, b, c, d, e, f},
   {1, 5, 15, 16, 17, 18, 11}}

Answer 2

Если целые числа считаются первыми элементами:

Cases[t1, List[a_Integer, ___] :> a, All]
(* {1, 15, 5, 11} *)

Answer 3

Cases[First /@ Cases[t1, _List, Infinity], Except[_List]]

{1, 15, 5, 11}

Answer 4

Другой способ подходит для всего списка.

t2 = {{a, 2, 3, 4}, {b, 
    6, {c, 8, {{d, 8, 9}, {e, 3, 3, 2}}, {f, 5, 7}}}};
Cases [t2, {x_ /; ListQ[x] == False, ___}, {0, Infinity}]
First /@ %

Два выхода:

{{a, 2, 3, 4}, {d, 8, 9}, {e, 3, 3, 2}, {f, 5, 7}, {c, 
  8, {{d, 8, 9}, {e, 3, 3, 2}}, {f, 5, 7}}, {b, 
  6, {c, 8, {{d, 8, 9}, {e, 3, 3, 2}}, {f, 5, 7}}}}

{a, d, e, f, c, b}