Проблемы с Plotlegend

Question

Я делаю трехмерный график функции En1 и приписываю его цвет функции sz1 ниже, которая содержит значения от -1 до 1.

En1[δ_, g1_, g2_, k_] := 1/2(-I g1 + I g2 -Sqrt[-(g1 + g2 - 2 k + I δ) (g1 + g2 + 2 k + Iδ)] + δ)

vec1[δ_, g1_, g2_,k_] := {{-((I g1 + I g2 + Sqrt[-(g1 + g2 - 2 k + I δ) (g1 + g2 + 2 k + I δ)] - δ)/1), 2 k}}

vec1d[δ_, g1_, g2_,k_] := {{(I g1 + I g2 - Sqrt[-(g1 + g2 - 2 k - I δ) (g1 + g2 + 2 k - I δ)] + δ)/1, 2 k}}

σz = PauliMatrix[3];
σ0 = IdentityMatrix[2];

sz1[δ_, g1_, g2_, k_] := Flatten[vec1d[δ, g1, g2, k]. σz . Transpose[vec1[δ, g1, g2, k]]][[1]]/Flatten[vec1d[δ, g1, g2, k].Transpose[vec1[δ, g1, g2, k]]][[1]]

g1 = 1;  g2 = 1;

Plot3D[
  {Re[En1[δ, g1, g2, k]]}, 
  {δ, -2, 2}, {k, 0, 2},
  ColorFunction -> Function[{δ, k, z}, ColorData["TemperatureMap"][sz1[δ, g1, g2, k]]], 
  ColorFunctionScaling -> False, 
  PlotLegends -> BarLegend[{ColorData["TemperatureMap"], {-1, 1}}], 
  BoxRatios -> {1, 1, 1}
]

Как мы видим, цвет соответствует функции sz1. Однако есть проблема с моей легендой, поскольку градиент цвета кажется нелинейным. Есть ли способ сделать так, чтобы цвет легенды изменялся линейно от -1 до 1?

Если мы построим график, sz1мы увидим, что это странно по отношению к$\delta$ при фиксированном k, т. е.

Plot3D[{sz1[δ, g1, g2, k]}, {δ, -2, 2}, {k, 0, 2}, AxesLabel -> {"δ", "k"}]

Однако цвет трехмерного графика Re[En1]не является чем-то необычным по отношению к цвету. Вы видите для этого какую-нибудь причину?

Answer 1

Вы можете явно изменить масштаб функции цвета в легенде:

BarLegend[{ColorData["TemperatureMap"][Rescale[#, {-1, 1}]] &, {-1, 1}}]

Без этого, похоже, легенда использует диапазон по умолчанию от 0 до 1 для функции цвета. Таким образом, значения ниже нуля обрезаются до цвета, соответствующего нулю.

Чтобы ответить на ваш измененный вопрос, вы также можете изменить масштаб функции цвета на графике:

ColorFunction -> Function[{\[Delta], k, z},
   ColorData["TemperatureMap"][Rescale[sz1[\[Delta], g1, g2, k], {-1, 1}]]
] 

Установка ViewPoint -> Top для более четкого отображения изменения цвета дает:

ps, в вашем определении En1 есть опечатка: в последнем множителе, я думаю, вы намереваетесь оставить пробел между I и delta.