Сохранение фазовых факторов в Sqrt

Question

Я пытаюсь построить некоторые голоморфные функции, которые содержат квадратные и более высокие корни. В смысле комплексного анализа функция$f:z\mapsto z^\alpha$ для некоторых $\alpha\in\mathbb C$ имеет фазовый фактор $e^{2\pi i\alpha}$ в $z=0$, что означает, что на небольшом круговом пути вокруг $0$ функция $f$подхватывает этот фактор. Есть ли способ реализовать это в системе Mathematica?

Например,

g[z_] = z^4;
Sqrt[g[Exp[Pi I/2]]]

дает 1 в результате, где я хотел бы, чтобы Mathematica сохранила фазу $g(e^{\pi i/2})=e^{2\pi i}$ а затем вычислить $$\sqrt{g(e^{\pi i/2})}=e^{\pi i}=-1.$$С Sqrtили$(\cdot)^{1/2}$это кажется невозможным, поскольку они выбирают главные квадратные корни. Большое спасибо за вашу помощь!

ИЗМЕНИТЬ Вот пример:

lim = 5; dlim = 20; 
f1[z_] = Sqrt[z^8];
f2[z_] = z^4;
p1 = ParametricPlot[{Re[f1[1 + d I]], Im[f1[1 + d I]]}, {d, -dlim, 
    dlim}, PlotRange -> {{-lim, lim}, {-lim, lim}}];
p2 = ParametricPlot[{Re[f2[ 1 + d I]], Im[f2[1 + d I]]}, {d, -dlim, 
    dlim}, PlotRange -> {{-lim, lim}, {-lim, lim}}];
GraphicsGrid[{{p1, p2}}]

Очевидно, что функции f1и f2не совпадают, как и$\sqrt{x^2}=|x|$ не равно $x$ на $\mathbb R\ni x$. Для моей цели меня скорее интересует разрешение квадратного корня, которое приводит к гладкой функции. Приведенные выше графики выглядят следующим образом:

На левом рисунке видны точки, в которых функция пересекает ветвь квадратного корня. Мне интересно, есть ли способ избежать этого, например, на правом рисунке, без возможности вычислить квадратный корень вручную. Например, если добавить выражение к$z^8$ который содержит похожие фазы, я хотел бы извлечь общую фазу из квадратного корня, чтобы на него не повлияло срезание ветви.

Можно также деформировать указанную выше функцию, чтобы сказать $f(z)=\sqrt{z^8+\varepsilon}$ для некоторых $\varepsilon>0$. Тогда нет возможности извлечь квадратный корень для общего$z$, и невозможно построить деформацию правильного изображения. Я, тем не менее, заинтересован в том, чтобы найти способ сделать это, чтобы правильное изображение постоянно искажалось.

На самом деле меня интересуют квадратные корни из модульных функций EllipticThetaи DedekindEta, которые преобразуются при определенных дробно-линейных преобразованиях с фазами. Тогда вполне определено наличие таких выражений, как$\sqrt{\vartheta_4(z)^8+\varepsilon \vartheta_2(z)^4\vartheta_3(z)^4}$ поскольку оба слагаемых преобразуются с одинаковыми фазами.

Все вышеперечисленные проблемы возникают из-за того, что Mathematica выражает комплексные числа на каждом шаге либо в декартовых координатах, либо игнорирует все по модулю $2\pi$в полярной форме. Было бы неплохо найти способ запретить Mathematica делать это без необходимости переопределять каждую операцию. Большое спасибо!

Answer 1

Это пример общей проблемы аналитического продолжения многозначной функции по непрерывному пути.

В случае алгебраической функции, такой как $w=\sqrt{z^8}$, мы можем записать это как $f(z,w)=w^2-z^8=0$ и в вашем случае позволяя $z(t)=1+it$, написать: $$ \frac{dw}{dt}=-\frac{f_z}{f_w}\frac{dz}{dt}=\frac{4i(1+it)^7}{w} $$ Затем мы решаем (многозначную) IVP: $$ \frac{dw}{dt}=\frac{4i(1+i t)^7}{w};\quad \{w_0\}=\{f(z(t_0),w)=0\} $$ где ДЭ и начальные значения $\{w_0\}$ для $t_0=-5$ настроены как:

tStart = -5;
tEnd = 5;
thez[t_] = 1 + t I;
theDE = w'[t] == ((4 I z^7)/w /. {z -> thez[t],
    w -> w[t]});
wStart = w /. Solve[w^2 == (1 + tStart I)^8, w]

Теперь решите обе IVP и нанесите на график результаты:

colors = {Red, Blue};
plotTable = Table[
   dSol = 
    First[NDSolve[{theDE, w[-5] == wStart[[i]]}, 
      w, {t, tStart, tEnd}]];
   theSol[t_] := Evaluate[Flatten[w[t] /. dSol]];
   ParametricPlot[{Re[theSol[t]], Im[theSol[t]]}, {t, tStart, tEnd}, 
    PlotRange -> {{-5, 5}, {-5, 5}}, PlotStyle -> colors[[i]]],
   {i, 1, 2}];
Show[plotTable]