Como transformar várias colunas em linhas sucessivas no awk

Question

Eu tenho um arquivo A.txt (sep = "\ t", a primeira coluna está vazia):

    Cycle  A1  A2  B1
    1      4   5   2
    2      7   3   4
    3      3   2   5

E eu quero transformar este arquivo em um novo arquivo B.txt (sep = "\ t"):

Well  Cycle  Value
A1     1     4
A1     2     7
A1     3     3
A2     1     5
A2     2     3
A2     3     2
B1     1     2
B1     2     4
B1     3     5

Eu tentei algo com: awk '{for (i = 1; i <= NF; i ++) print $ i}', mas não consegui descobrir. Alguém tem ideia de como fazer isso? obrigado

Answer 1

Não awk, mas usando Miller , dado

$ cat file
    Cycle  A1  A2  B1
    1      4   5   2
    2      7   3   4
    3      3   2   5

então

$ mlr --pprint --ifs tab reshape -i A1,A2,B1 -o Well,Value then sort -f Well then reorder -f Well file
Well Cycle Value
A1   1     4
A1   2     7
A1   3     3
A2   1     5
A2   2     3
A2   3     2
B1   1     2
B1   2     4
B1   3     5

Você pode omitir a sortetapa se não for um requisito.

O reshapecomando Miller também pode aceitar uma expressão regular para seleção de campo, por exemplo.

reshape -r '[A-Z][1-9]' -o Well,Value

Answer 2

Primeiro carregamos o arquivo em um array de array. AoA[colidx, rowidx] Em seguida, no final do bloco de arquivo, reestruturamos esses dados no formato que desejamos.

Nota:

• O separador de campos \t+deve percorrer guias consecutivas e não receber campos vazios.
• a gsub()parte é para remover as n guias finais à esquerda.
• Este código cuidará de tantas colunas e linhas quanto o arquivo tiver. (Se a memória permitir)

awk -F '\t+' '
gsub(/^\t|\t$/, "") {$1=$1} NR==1 {header = "Well" OFS $1 OFS "Value"}
{
  for(i=1; i<=NF; i++) {
    AoA[i, NR] = $(i)
  }
}
END {
  print header
  for(col=2; col<=NF; col++) {
    for(row=2; row<=NR; row++) {
      well  = AoA[col, 1]
      cycle = AoA[1, row]
      value = AoA[col, row]
      print well, cycle, value
    }
  }
}
' OFS='\t' -  | column -t

Resultados:

Well  Cycle  Value
A1    1      4
A1    2      7
A1    3      3
A2    1      5
A2    2      3
A2    3      2
B1    1      2
B1    2      4
B1    3      5

Answer 3

Aqui está uma abordagem (bastante rudimentar) que requer que os cabeçalhos sejam estáticos e conhecidos com antecedência, e que não classifica bem:

$ awk -F'\t' -v OFS="\t" 'BEGIN{print "Well","Cycle","Value"} NR>1{ cycle[NR]=$2;
                            a1[NR]=$3; a2[NR]=$4; 
                            b1[NR]=$5;
                        }
                        END{
                            for(line in cycle){
                                print "A1",cycle[line],a1[line]; 
                                print "A2",cycle[line],a2[line]; 
                                print "B1",cycle[line],b1[line]
                            }
                        }' file 
Well    Cycle   Value
A1  1   4
A2  1   5
B1  1   2
A1  2   7
A2  2   3
B1  2   4
A1  3   3
A2  3   2
B1  3   5

Se você precisa classificar bem, pode usar o ainda mais bruto:

$ awk -F'\t' -vOFS="\t" 'BEGIN{print "Well","Cycle","Value"}
                         NR>1{
                            cycle[NR]=$2; a1[NR]=$3; 
                            a2[NR]=$4; b1[NR]=$5;
                        }
                        END{
                            for(line in cycle){
                                print "A1",cycle[line],a1[line];
                            }
                            for(line in cycle){
                                print "A2",cycle[line],a2[line]; 
                            }
                            for(line in cycle){
                                print "B1",cycle[line],b1[line]
                            }
                        }' file 
Well    Cycle   Value
A1  1   4
A1  2   7
A1  3   3
A2  1   5
A2  2   3
A2  3   2
B1  1   2
B1  2   4
B1  3   5