Graph3D - substitua os vértices por MoleculePlot3D

Question

Como podemos substituir os vértices em um grafo de 3 dimensões por Graphics3Dobjetos individuais?

No meu caso concreto quero visualizar uma rede química e substituir os vértices por suas respectivas MoleculePlot3Drepresentações. Como um teaser, esse é o gráfico 3D atual com o qual estou trabalhando. Você provavelmente pode imaginar a aplicação final :)

Usei as ideias deste post para configurar as coordenadas.

As esferas vermelhas devem ser substituídas por gráficos de moléculas de 3 dimensões.

Considere este exemplo mínimo:

Graph3D[{"CO" \[DirectedEdge] "C", "CO" \[DirectedEdge] "O"}]

Configurando as MoleculePlot3Dinstâncias correspondentes:

vert = AssociationThread[
  {"CO", "C", "O"} -> {
   MoleculePlot3D[Molecule[{Atom["[C]"], Atom["[O]"]}, {Bond[{1, 2}, "Double"]}]], 
   MoleculePlot3D[Molecule[{Atom["[C]"]}]], 
   MoleculePlot3D[Molecule[{Atom["[O]"]}]]}]

No entanto, tenho dificuldades para substituir os vértices no Graph3Darquivo programaticamente. Consegui modificar o Gráfico 2D:

Graph[{
    Annotation["CO", VertexShapeFunction -> (Inset[vert["CO"], #1, Center, 2*#3] &), VertexSize -> 0.2],
    Annotation["C",  VertexShapeFunction -> (Inset[vert["C"], #1, Center, 2*#3] &),  VertexSize -> 0.2],   
    Annotation["O",  VertexShapeFunction -> (Inset[vert["O"], #1, Center, 2*#3] &),  VertexSize -> 0.2]}, 
    {"CO" \[DirectedEdge] "C", "CO" \[DirectedEdge] "O"}]

Como posso fazer isso no Graph3D? No caso completo estarei trabalhando com as seguintes moléculas:

{"C", "C+", "CH", "CH+", "CN", "CO", "CS", "CS+", "H", "H2", "HCO+", 
 "HCS+", "He", "N", "O", "OH", "S", "SO", "CH2+", "CO+", "O+", "OCS+", 
 "S+", "SO+", "CH2", "CN+", "H2O", "HCN", "HS", "H3O+", "HS+", "CH3+", 
 "HNC", "H3CO+", "CH4", "N+", "N2", "H+", "OH+", "OCS", "H2O+", "H2+", 
 "H2S+", "H3+", "He+", "O2", "SO2"}

Portanto, moléculas relativamente pequenas sem a necessidade de fazer escalas extremas nos MoleculePlots.

Answer 1

Esta resposta evita Insetcompletamente e captura as primitivas gráficas de dentro da expressão de um sistema MoleculePlot3De, portanto, é um pouco frágil porque pode quebrar em uma versão futura que reestrutura a saída de MoleculePlot3D.

A inspeção mostra que Graphics3D retornado por MoleculePlot3D sempre contém um GraphicsComplexcom todos os átomos e ligações. Então, podemos usar isso GraphicsComplexe envolvê-lo GeometricTransformationpara fazer a função de forma do vértice

molVertex[mol_][coords_, vertex_, scale_] := Module[
    {graphic = MoleculePlot3D @ mol, gc},
    gc = Cases[graphic, _GraphicsComplex, Infinity];
    GeometricTransformation[
        gc, 
        TranslationTransform[coords] @* ScalingTransform[scale]
    ]
]

Aqui está um exemplo,

SeedRandom @ 42;
g = RandomGraph @ {5, 8};
mols = Map[
    Molecule,
    {"CCCC(C)(C)OCC", "SC1CCCC1", "O=P(O)(O)CCO", "CCCC", "F[Ti](Cl)(Cl)Cl"}
];
Graph3D[
    Annotation[#,
        VertexShapeFunction -> molVertex[mols[[#]]],
        VertexSize -> 0.2
    ]& /@ VertexList[g],
    EdgeList @ g
]