Sem som - como posso desfazer 'sc delete AudioEndpointBuilder'?

Question

Há pouco mais de uma semana cometi o terrível erro de executar sc delete AudioEndpointBuilderna linha de comando do Windows. As consequências foram verdadeiramente desastrosas.
Não tenho mais som no meu computador! Como posso desfazer esse comando aparentemente perigoso?

Uma tentativa ingênua de simplesmente correr sc create AudioEndpointBuilder não resolveu o problema.

Answer 1

Você tem poucas opções.

1. Você pode baixar e descompactar o seguinte cmdarquivo em:
   
   

Para executar o arquivo, clique com o botão direito e escolha Run as administrator. O conteúdo é o seguinte:

@Echo off
:: ---------------------------------------------------------------------------------------
:: http://schulze.000webhostapp.com/win10//sc-create-AudiosrvEndpointBuilder.cmd
:: ---------------------------------------------------------------------------------------
:: Unless you substantially alter this code - or merely use small snippets of it - please
:: be sure to leave the following 20 lines intact:
 Echo.
 Echo  DISCLAIMER - Read https://stackoverflow.com/legal/terms-of-service/public#warranties !
 Echo  Credit - https://superuser.com/users/1102737/henke
 Echo  If this cmd file has been helpful to you, the best way to thank me
 Echo  is to upvote both the question and this answer - if you are allowed to.
 Echo     Link to answer - https://superuser.com/questions/1585391#1585392
 Echo  (c) Copyright Henrik D Schulze 2020-09-14 - http://schulze.000webhostapp.com/
 Echo     This answer to 'No sound - how can I undo sc delete AudioEndpointBuilder?'
 Echo  is licensed under [CC BY 4.0](https://creativecommons.org/licenses/by/4.0/)
 Echo.
 Echo  = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =
 Echo  =  If you do NOT want to run this file, hit CTRL + C, then Y, then ENTER !  =
 Echo  = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =
 Echo.
 Echo  If you WANT to run this file, you need to right-click it and 'Run as administrator'.
 Echo.
:: ---------------------------------------------------------------------------------------
pause

:: Save a backup of the existing registry keys for AudioEndpointBuilder:
%SystemRoot%\System32\reg.exe export^
 HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder^
 %SystemRoot%\OLD!-backupOfAudioEndpointBuilder.reg
:: Delete the existing registry keys for AudioEndpointBuilder:
reg.exe delete HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /f
:: Create the registry keys for AudioEndpointBuilder:
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v Description /d^
 @^%%SystemRoot^%%\System32\AudioEndpointBuilder.dll,-205 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v DisplayName /d^
 @^%%SystemRoot^%%\System32\AudioEndpointBuilder.dll,-204 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v ErrorControl /t^
 REG_DWORD /d 1 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v FailureActions /t^
 REG_BINARY /d "80510100000000000000000003000000140000000100000060ea000001000000c0d401000000000000000000" /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v Group /d^
 AudioGroup /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v ImagePath /t^
 REG_EXPAND_SZ /d "%%SystemRoot%%\System32\svchost.exe -k LocalSystemNetworkRestricted -p" /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v ObjectName /d^
 LocalSystem /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v RequiredPrivileges /t^
 REG_MULTI_SZ /d SeChangeNotifyPrivilege /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v^
 ServiceSidType /t REG_DWORD /d 1 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v^
 Start /t REG_DWORD /d 2 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v^
 Type /t REG_DWORD /d 32 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder\Parameters /v^
 ServiceDll /t REG_EXPAND_SZ /d ^%%SystemRoot^%%\System32\AudioEndpointBuilder.dll /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder\Parameters /v^
 ServiceDllUnloadOnStop /t REG_DWORD /d 1 /f

:: Save a backup of the existing registry keys for Audiosrv:
%SystemRoot%\System32\reg.exe export^
 HKLM\SYSTEM\CurrentControlSet\services\Audiosrv %SystemRoot%\OLD!-backupOfAudiosrv.reg
:: Delete the existing registry keys for Audiosrv:
reg.exe delete HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /f
:: Create the registry keys for Audiosrv:
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v DependOnService /t^
 REG_MULTI_SZ /d "AudioEndpointBuilder\0RpcSs" /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v Description /d^
 @^%%SystemRoot^%%\System32\audiosrv.dll,-201 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v DisplayName /d^
 @^%%SystemRoot^%%\System32\audiosrv.dll,-200 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v ErrorControl /t^
 REG_DWORD /d 1 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v FailureActions /t^
 REG_BINARY /d "80510100000000000000000003000000140000000100000060ea000001000000c0d401000100000020bf0200" /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v Group /d^
 AudioGroup /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v ImagePath /t^
 REG_EXPAND_SZ /d "%%SystemRoot%%\System32\svchost.exe -k LocalServiceNetworkRestricted -p" /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v ObjectName /d^
 "NT AUTHORITY\LocalService" /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v RequiredPrivileges /t^
 REG_MULTI_SZ /d "SeChangeNotifyPrivilege\0SeImpersonatePrivilege\0SeIncreaseWorkingSetPrivilege" /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v^
 ServiceSidType /t REG_DWORD /d 1 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v^
 Start /t REG_DWORD /d 2 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v^
 Type /t REG_DWORD /d 16 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv\Parameters /v^
 ServiceDll /t REG_EXPAND_SZ /d ^%%SystemRoot^%%\System32\Audiosrv.dll /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv\Parameters /v^
 ServiceDllUnloadOnStop /t REG_DWORD /d 1 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv\Security /v Security /t REG_BINARY /d^
 "01000480c0000000cc00000000000000140000000200ac000600000000001400fd01020001010000000000051200000000001800ff010f0001020000000000052000000020020000000014008d010200010100000000000504000000000014008d010200010100000000000506000000000018008d000200010200000000000f0200000001000000000038008d000200010a00000000000f0300000000040000abace86417c3b0f1abc5110bd73b6dc89d8a33d21867214545351283ff23a71d010100000000000512000000010100000000000512000000" /f

:: Create the services:
sc create AudioEndpointBuilder binPath=^
 ^%%SystemRoot^%%"\system32\svchost.exe -k LocalSystemNetworkRestricted" type= share start= auto
sc create Audiosrv binPath=^
 ^%%SystemRoot^%%"\system32\svchost.exe -k LocalServiceNetworkRestricted" type= share start= auto

:Description
 Echo  Please note!
 Echo  - - - - - -
 Echo  '%0' created the AudioEndpointBuilder Audiosrv services
 Echo  in the registry and in services.msc.
 Echo.
 Echo   = = = = = = = = = = = = = = = = = =
 Echo   =  PLEASE RESTART YOUR COMPUTER!  =   I hope your Audio works now. (It should!)
 Echo   = = = = = = = = = = = = = = = = = =
 Echo.
pause
:: ---------------------------------------------------------------------------------------
 Echo.

Se o script acima não restaurar o som em seu computador, pode haver problemas com o arquivo AudioEndpointBuilder.dlle / ou com audiosrv.dll. Esses dois arquivos geralmente estão localizados em C:\Windows\System32\. Eles podem estar faltando ou ter a (s) versão (ões) incorreta (s) em comparação com sua compilação atual do Windows 10. No entanto, a menos que você tenha mexido com esses arquivos, este não é muito provável que seja o problema.
Outra razão pela qual a execução do script não recupera o som pode ser problemas com os drivers de som. Também considero esta uma causa improvável. Em Device Manager procurar Sound, video and game controllers. A maneira mais fácil de instalar os drivers mais recentes disponíveis é permitir que o Windows Update faça isso por você.

1. Você pode tentar atualizar para uma versão posterior do Windows 10. Isso é semelhante em efeito a fazer uma instalação limpa do Windows 10. No meu laptop com uma unidade de disco rígido, isso levou cerca de sete horas. Links sugeridos:
   https://www.askvg.com/windows-10-feature-update-available-for-download-and-upgrade/
   https://support.microsoft.com/en-us/help/4028685/windows -10-get-the-update
   Ou apenas faça uma pesquisa online, por exemplo, por "Windows 10" "Update & Security" "Update Assistant".

2. Faça uma instalação limpa do Windows 10. Ao fazer isso, você perderá todos os softwares instalados em seu computador, portanto, isso deve ser considerado apenas como último recurso.