Benutzerdefinierte Objektanzeige im Datensatz mithilfe von MakeBoxen
Der folgende Code definiert ein paar "Objekte" im Sinne von Mathematica unter Verwendung einer Konvention, die aus sogenannten Q-Funktionen zum Erstellen von Typen und zur Datenvalidierung, MakeBoxeszum Formatieren, Associationfür Daten sowie SubValuesfür Eigenschaften und Methoden besteht. (Es ist eher eine Konvention als ein Rahmen und eine, die ich oft benutze, weil sie nicht pingelig ist und das symbolische Paradigma von Mathematica umfasst.)
Vor kurzem bin ich jedoch auf Anzeigeprobleme meiner benutzerdefinierten Formate gestoßen Dataset. Immer wenn ich ein Objekt wie SubObjectunten habe, wird es gut angezeigt, aber wenn ich ein Objekt wie Objectunten habe, das selbst eine Liste von SubObject's enthalten kann , wird die Anzeige sogar einer Liste solcher ObjectObjekte ...angezeigt, und dies scheint insbesondere nur bei zu passieren Ein ObjectObjekt enthält eine Liste mit mehr als einem SubObjectObjekt.
Vielen Dank im Voraus für alle Erkenntnisse oder Korrekturen.
Um dies zu testen, kopieren Sie einfach den folgenden Code und führen Sie die nachfolgenden Tests aus, um die seltsamen DatasetAnzeigeprobleme zu beheben. Hier ist mein Code zum Definieren der Objekte:
(*Utility q-function defining allowed rule pattern.*)
ClearAll[validRuleQ];
validRuleQ[(Rule | RuleDelayed)[_String, _]] := True;
validRuleQ[__] := False;
(*SubObject Data Q-Function*)
ClearAll[SubObjectDataQ];
SubObjectDataQ[
Association["Name" -> _String,
"Date" -> _?DateObjectQ, ___?validRuleQ]] := True;
SubObjectDataQ[__] := False;
(*SubObject Q-Function*)
ClearAll[SubObjectQ];
SubObjectQ[SubObject[_?SubObjectDataQ]] := True;
SubObjectQ[__] := False;
(*SubObject*)
ClearAll[SubObject];
(*SubObject Format*)
SubObject /:
MakeBoxes[obj : SubObject[_?SubObjectDataQ], form : StandardForm] :=
FrameBox[
RowBox[{StyleBox[obj["Name"], Bold], " ",
StyleBox["(subobject)", Bold, Gray]}], RoundingRadius -> 5,
Background -> LightBlue];
(*SubObject Constructor*)
SubObject[name_String, date_?DateObjectQ, rules___?validRuleQ] :=
SubObject[Association["Name" -> name, "Date" -> date, rules]];
(*SubObject Properties*)
SubObject[assoc_?SubObjectDataQ]["Association"] := assoc;
SubObject[assoc_?SubObjectDataQ]["Properties"] := Keys[assoc];
SubObject[assoc_?SubObjectDataQ][key_String] := Lookup[assoc, key];
(*Object Data Q-Function*)
ClearAll[ObjectDataQ];
ObjectDataQ[
Association["Name" -> _String, "Date" -> _?DateObjectQ,
"Objects" -> {___?SubObjectQ}, ___?validRuleQ]] := True;
ObjectDataQ[__] := False;
(*Object Q-Function*)
ClearAll[ObjectQ];
ObjectQ[Object[_?ObjectDataQ]] := True;
ObjectQ[__] := False;
(*Object*)
ClearAll[Object];
(*Object Format*)
Object /:
MakeBoxes[obj : Object[_?ObjectDataQ], form : StandardForm] :=
FrameBox[RowBox[{StyleBox[obj["Name"], Bold], " ",
StyleBox["(object)", Bold, Gray]}], RoundingRadius -> 5,
Background -> LightBlue];
(*Object Constructor*)
Object[name_String, date_?DateObjectQ, objects : {___?SubObjectQ},
rules___?validRuleQ] :=
Object[Association["Name" -> name, "Date" -> date,
"Objects" -> objects, rules]];
(*Object Properties*)
Object[assoc_?ObjectDataQ]["Association"] := assoc;
Object[assoc_?ObjectDataQ]["Properties"] := Keys[assoc];
Object[assoc_?ObjectDataQ][key_String] := Lookup[assoc, key];
Hier ist der Code zum Testen der Objektdefinitionen und zum Anzeigen der Ausgabe in a Dataset.
Erstellen Sie zunächst einige SubObjectObjekte und ihre Listenvariable mit diesem Code:
(*Create some SubObject objects and then put them in a list for later.*)
so1=SubObject["SubObject1",DateObject[]];
so2=SubObject["SubObject2",DateObject[]];
so3=SubObject["SubObject3",DateObject[]];
sobjs={so1,so2,so3}
Dies sollte folgendermaßen angezeigt werden:
Erstellen Sie nun die ObjectObjekte und ihre Liste mit folgendem Code:
(*Create some Object objects and then put them in a list for later.*)
o1=Object["Object1",DateObject[],sobjs[[1;;1]]];
o2=Object["Object2",DateObject[],sobjs[[1;;2]]];
o3=Object["Object3",DateObject[],sobjs[[1;;3]]];
objs={o1,o2,o3}
Dies sollte folgendermaßen angezeigt werden:
Zeigen Sie nun einfach das Datasetfür die SubObjectObjektliste an:
(*Display SubObject Dataset*)
Dataset[sobjs]
Welche Anzeigen wie erwartet so:
Problem:
Und schließlich besteht das unerwartete Problem darin, dass ...anstelle eines ObjectObjekts alle ObjectObjekte angezeigt werden, die mehr als eines SubObjectin einer Liste enthalten, in unserem Fall die Variablen o2und o3. Hier ist der problematische Code:
(*Problematic code for display of Object in Dataset*)
Dataset[objs]
Welches wird angezeigt als
Wie behebe ich das, damit die ObjectObjekte Datasetkorrekt angezeigt werden?
(Hinweis: Ich habe versucht, HoldAll als Attribut für die Symbole der Konstruktorfunktionen zu verwenden, aber dies ist keine wünschenswerte Lösung, da es dann nicht bequem ist, die Objekte als Eingabevariablen für die Konstruktoren zu skripten, z. B. eine Liste von SubObjects in die Der Konstruktor für Objectwird vor dem Einfügen in die Assoziationsdaten nicht ausgewertet.)
Antworten
Das Problem kommt von TypeSystem`NestedGrid`PackagePrivate`smallQ, mit dem entschieden wird, ob ein Element vollständig angezeigt oder mit folgenden Elementen entfernt werden soll …:
TypeSystem`NestedGrid`PackagePrivate`smallQ[e_] :=
Or[SameQ[TypeSystem`PackageScope`$ElisionEnabled, False],
TypeSystem`AtomicDataQ[e],
And[Length@e <= TypeSystem`PackageScope`$ElisionLengthLimit, ByteCount@e <= TypeSystem`PackageScope`$ElisionByteLimit,
LeafCount@e <= TypeSystem`PackageScope`$ElisionLeafLimit
]
];
TypeSystem`AtomicDataQ[x_] := Or[And[AtomQ[x], ! AssociationQ[x]],
MemberQ[TypeSystem`$AtomicHeads, Head @ x],
System`Private`ValidQ[x]
];
Wie Sie sehen können, sind das zweite und dritte Objekt nicht klein:
TypeSystem`NestedGrid`PackagePrivate`smallQ /@ objs
(* {True, False, False} *)
Die Definition smallQund AtomicDataQauch eine gute Lösung für das Problem zeigen: Fügen Sie einfach Objectauf TypeSystem`$AtomicHeadsdem Datensatz Rendering zu behandeln sagt Object[...]Ausdrücke ähnlich DateObjectetc:
AppendTo[TypeSystem`$AtomicHeads, Object];
TypeSystem`NestedGrid`PackagePrivate`smallQ /@ objs
(* {True, True, True} *)
Dataset@objs