Como (temporariamente) capturar stdout

Question

Como faço para capturar temporariamente o stdout no Nim?

Eu gostaria de ter um modelo com a seguinte assinatura:

template captureStdout(ident: untyped, body: untyped) = discard

Para que este código ( main.nim) seja executado sem erros:

var msg = "hello"
echo msg & "1"
var s: string
captureStdout(s):
  echo msg & "2"
  msg = "ciao"
echo msg & "3"
assert s == "hello2\n"

e a saída deve ser:

hello1
ciao3

esforços atuais

atualmente consigo capturar o stdout usando um arquivo temporário, mas não consigo liberar para o stdout. Eu faço isso com o seguinte:

template captureStdout*(ident: untyped, body: untyped) =
  discard reopen(stdout, tmpFile, fmWrite)
  body
  ident = readFile(tmpFile)

com isso main.nimé executado sem erro de asserção, mas a saída é apenas

hello1

e em tmpFile vejo:

hello2
ciao3

Answer 1

Quando você chama, reopenvocê reatribui a variável stdouta um Fileque grava em tmpFile.

Para imprimir a saída no sistema STDOUT, você precisa reatribuir a variável stdouta um Fileque grava em seu sistema STDOUT.

Portanto, a resposta difere entre Linux e Windows.

Para Linux, a maneira de fazer isso é usar as funções dup e dup2 C para duplicar o stdoutdescritor de arquivo e usar um arquivo diferente (para que você possa restaurar stdout). Visto que dup e dup2 não estão system/iono Nim, precisaremos ter ligações para unistd.h.

Aqui está um exemplo:

#Create dup handles
proc dup(oldfd: FileHandle): FileHandle {.importc, header: "unistd.h".}
proc dup2(oldfd: FileHandle, newfd: FileHandle): cint {.importc,
    header: "unistd.h".}

# Dummy filename
let tmpFileName = "tmpFile.txt"

template captureStdout*(ident: untyped, body: untyped) =
  var stdout_fileno = stdout.getFileHandle()
  # Duplicate stoud_fileno
  var stdout_dupfd = dup(stdout_fileno)
  echo stdout_dupfd
  # Create a new file
  # You can use append strategy if you'd like
  var tmp_file: File = open(tmpFileName, fmWrite)
  # Get the FileHandle (the file descriptor) of your file
  var tmp_file_fd: FileHandle = tmp_file.getFileHandle()
  # dup2 tmp_file_fd to stdout_fileno -> writing to stdout_fileno now writes to tmp_file
  discard dup2(tmp_file_fd, stdout_fileno)
  #
  body
  # Force flush
  tmp_file.flushFile()
  # Close tmp
  tmp_file.close()
  # Read tmp
  ident = readFile(tmpFileName)
  # Restore stdout
  discard dup2(stdout_dupfd, stdout_fileno)

proc main() =
  var msg = "hello"
  echo msg & "1"
  var s: string

  captureStdout(s):
    echo msg & "2"
    msg = "ciao"

  echo msg & "3"
  echo ">> ", s
  assert s == "hello2\n"

when isMainModule:
  main()
  # Check it works twice
  main()