Primeiros elementos em sublistas

Question

Dado

t1 = {{{1, 2, 3, 4}, {5, 6, {15, 16}, 7}}, {11, 12, 13, 14}};

Tento obter Firstelementos de sublistas que produziriam

{1,5,15,11}

Como usar First, Takeou #1para este problema?

Answer 1

Se preservar a "ordem" dos elementos extraídos for importante, você pode usar

ClearAll[fa, fb]

fa = Cases[ReplaceRepeated[{a : Except[_List], b__} :> {{a}, b}]@#, {x_} :>  x, All] &;
fb = Cases[MapAll[# /. {a : Except[_List], b__} :> {{a}, b} &, #], {x_} :> x, All] &;

Exemplos:

t1 = {{{1, 2, 3, 4}, {5, 6, {15, 16}, 7}}, {11, 12, 13, 14}}; 
t2 = {{a, 2, 3, 4}, {b, 6, {c, 8, {{d, 8, 9}, {e, 3, 3, 2}}, {f, 5, 7}}}};(*from cvgmt's answer*)
t3 = {{{1, 2, 3, 4}, {5, 6, {15, {16, {17, {18}}}}, 7}}, {11, 12, 13, 14}};

fa /@ {t1, t2, t3}

  {{1, 5, 15, 11}, 
   {a, b, c, d, e, f},
   {1, 5, 15, 16, 17, 18, 11}}

fb /@ {t1, t2, t3}

  {{1, 5, 15, 11}, 
   {a, b, c, d, e, f},
   {1, 5, 15, 16, 17, 18, 11}}

Answer 2

Se inteiros são o que conta como primeiros elementos:

Cases[t1, List[a_Integer, ___] :> a, All]
(* {1, 15, 5, 11} *)

Answer 3

Cases[First /@ Cases[t1, _List, Infinity], Except[_List]]

{1, 15, 5, 11}

Answer 4

Outra forma adequada para toda a lista.

t2 = {{a, 2, 3, 4}, {b, 
    6, {c, 8, {{d, 8, 9}, {e, 3, 3, 2}}, {f, 5, 7}}}};
Cases [t2, {x_ /; ListQ[x] == False, ___}, {0, Infinity}]
First /@ %

As duas saídas são

{{a, 2, 3, 4}, {d, 8, 9}, {e, 3, 3, 2}, {f, 5, 7}, {c, 
  8, {{d, 8, 9}, {e, 3, 3, 2}}, {f, 5, 7}}, {b, 
  6, {c, 8, {{d, 8, 9}, {e, 3, 3, 2}}, {f, 5, 7}}}}

{a, d, e, f, c, b}