rede de controle do toro

Question

Eu quero fazer uma rede de controle completa de um toro. No entanto, a rede não está fechada. Alguém pode resolver esse problema?

pts6 = Table[{(2 + 1 Cos [s])*Cos [t], (2 + 1 Cos [s])*Sin[t], 1 Sin[s]},
  {s, -Pi, Pi}, {t, -Pi, Pi}];
f = BSplineFunction[pts6, SplineClosed -> {True, True}];
Show[
  Graphics3D[{PointSize[Large], Black, Map[Point, pts6]}],
  Graphics3D[{Gray, Line[pts6], Gray, Line[Transpose[pts6]]}],
  ParametricPlot3D[f[s, t], {s, 0, 1}, {t, 0, 1}, AxesLabel -> Automatic]]

] 1

Answer 1

A solução de Ulrich responde totalmente à pergunta, no entanto, há um problema com a superfície criada por BSpliceFunction. Observe que a superfície não é um toro e há uma quebra no raio interno (há uma sombra nítida que deve ser lisa). Use pts6da solução de Ulrich e fda pergunta.

pts6 = Table[{(2 + Cos[t])*Cos[s], (2 + Cos[t])*Sin[s], Sin[t]}, {s, 
    Subdivide[-Pi, Pi, 6]}, {t, Subdivide[-Pi, Pi, 6]}];
f = BSplineFunction[pts6, SplineClosed -> {True, True}];
g1 = Show[Graphics3D[{PointSize[Large], Black, Map[Point, pts6]}],
  Graphics3D[{Thick, Gray, Line[pts6], Line[Transpose[pts6]]}],
  ParametricPlot3D[f[s, t], {s, 0, 1}, {t, 0, 1}]]

A vista de cima mostra que a malha está espaçada de maneira desigual e a superfície não é um toro. A seção transversal não é circular.

ParametricPlot3D[f[s, t], {s, 0, 1}, {t, 0, 1}, 
  ViewPoint -> {0, 0, \[Infinity]}, 
  PlotLabel -> "non-toroidal surface"]

ParametricPlot3D[f[s, t], {s, 0, 1}, {t, 0, 1},
 RegionFunction -> Function[{x, y, z, u, v}, 0 <= y <= 2],
 BoundaryStyle -> Black, Axes -> True, 
 PlotLabel -> "non-circular cross-section"]

Quando usamos o BSplineFunctioncom a SplineClosedopção, os pontos de controle não devem ser fechados. BSpineFunctioncompleta a superfície conectando os limites. Resolva o problema redefinindo a função spline f2para remover os pontos finais redundantes. O resultado é um toro.

f2 = BSplineFunction[Most[pts6][[All, ;; -2]], SplineClosed -> {True, True}];
ParametricPlot3D[f2[s, t], {s, 0, 1}, {t, 0, 1}, ViewPoint -> {0, 0, \[Infinity]}

Aqui está a visão corrigida dos pontos de controle com o toro, em comparação com o gráfico original.

g2 = Show[Graphics3D[{PointSize[Large], Black, Map[Point, Most@pts6]}],
  Graphics3D[{Thick, Gray, Line[pts6], Line[Transpose[pts6]]}],
  ParametricPlot3D[f2[s, t], {s, 0, 1}, {t, 0, 1}]]

Answer 2

A definição dos pontos de controle está errada. {s,-Pi,Pi}dentro Tablecria uma grade s {_pi,-Pi+1,-Pi+2,...}que não contém o último ponto Pi.

Redefina os pontos de controle para

pts6 = Table[{(2 + 1 Cos[s])*Cos[t], (2 + 1 Cos[s])*Sin[t],1 Sin[s]}, {s, Subdivide[-Pi, Pi, 10]}, {t,Subdivide[-Pi, Pi, 10]}]