Como listar nomes e valores de campo json?

Question

Por favor me ajude a descobrir o problema. Eu programo em groovy (você pode usar um exemplo em java, parece que está lá). Json chega à entrada, na qual não se sabe quantos campos. Pode haver 5 campos, talvez 10, talvez 50. Minha tarefa é processar este json e retornar os dados de volta usando:

// Names of dataset columns
def names = ["a", "b", "c"];
// types of return values ​​in each column (for any field (column) json is always String)
def types = ["String", "String", "String"];
// formation of the dataset header
reader.outputLinesSetHeaders (names, types);
// Passing the data itself from json
reader.outputLines ([it.a, it.b, it.c])
// Close the dataset
reader.outputLinesEnd ();

Se eu conhecesse o json de entrada, teria definido os nomes dos campos obrigatórios, o número de "String" com antecedência e retornado seus valores referindo-se a um campo json específico. O exemplo abaixo mostra 3 campos json: auto, home, job. Da mesma forma, 3 vezes "String" para cada um dos campos e se referindo a um campo específico para retornar o valor it.auto, it.home, it.job. Mas como posso fazer o mesmo se não conheço o json de entrada?

import groovy.json.JsonSlurper

import ru.itrpro.xm.plugins.groovy.ResultSetReader;

class XM_PARSE_XLS {

    def execute(ResultSetReader reader, String pfile) {



        def jsonSlurper = new JsonSlurper()
        def list = jsonSlurper.parseText(pfile)



        //The names of the columns of the dataset (now set statically to show an example; but in my case I don't know json and can't write it this way in advance)
        def names = ["AUTO", "HOME", "JOB"];
        //return types in each column (for any json, only "String" types)
        def types = ["String", "String", "String"];

        //формирование заголовка датасета
        reader.outputLinesSetHeaders(names,types);


                list.each {
                        //pass the values as a dataset from json (now set statically to show an example; but in my case I don't know json and can't write it this way in advance)
                        reader.outputLines([it?.AUTO, it?.HOME, it?.JOB]);
                }

        //closing dataset
        reader.outputLinesEnd();
        return null;



    }
    static void main(String... args) {
            String pfile =  """
[{"AUTO":"bmw",
  "HOME":"vest",
  "JOB":"bbds"},
  
  {"AUTO":"audi",
  "HOME":"dest",
  "JOB":"aads"},
  
  {"AUTO":"opel",
  "HOME":"lest",
  "JOB":"ffds"}]
"""
            def SSC = new XM_PARSE_XLS()
            def res = SSC.execute(new ResultSetReader(), pfile)

    }

}

Talvez valha a pena coletar todos os nomes de campo do json de entrada em uma lista e especificar uma lista de "String" (qualquer json de entrada tem todos os campos apenas "String") com o mesmo número dos campos? Mas como fazer isso e como devo passar os valores do campo (it. ***)?

Answer 1

Se o JSON de entrada for do tipo Object (pares de valores-chave), ele será analisado em um Map, então você pode usar seus métodos para inspecioná-lo.

import groovy.json.JsonSlurper

String pfile =  """
[{"AUTO":"bmw",
  "HOME":"vest",
  "JOB":1},
  
  {"AUTO":"audi",
  "HOME":"dest",
  "JOB":2},
  
  {"AUTO":"opel",
  "HOME":"lest",
  "JOB":3}]
"""
def jsonSlurper = new JsonSlurper()
def list = jsonSlurper.parseText pfile

List names = list.inject( new HashSet() ){ res, map ->
  res.addAll map.keySet()
  res
}.toList()

// get types based on actual values
def types = list.first().values()*.getClass()*.simpleName

assert '[AUTO, JOB, HOME]' == names.toString()
assert '[String, String, Integer]' == types.toString()

//reader.outputLinesSetHeaders names, types

list.each{ e ->
  //reader.outputLines names.collect{ e[ it ] }
  println names.collect{ e[ it ] }
}

//reader.outputLinesEnd()

As linhas são comentadas para evitar problemas de compilação.

Answer 2

Supondo que você deseja apenas saber as chaves e o tipo do valor, você pode criar uma união de todas as chaves / tipos. Isso pressupõe que o tipo de valor de uma chave é o mesmo para todas as chaves.

import groovy.json.JsonSlurper

def data = new JsonSlurper().parseText("""[{"a": 1, "b": 2, "c": 3, "x": true}, {"a": 4, "b": 5, "c": 6, "d": "Hello"}]""")
def content = data.collectEntries{ 
    it.collectEntries{ 
        [it.key, it.value.class.name] 
    } 
}

println content
// → [a:java.lang.Integer, b:java.lang.Integer, c:java.lang.Integer, x:java.lang.Boolean, d:java.lang.String]