Groupby com soma em Julia Dataframe

Question

Estou tentando fazer um groupby + sum em um Julia Dataframe com valores Int e String

Por exemplo, df:

│ Row │ A      │ B      │ C     │ D      │
│     │ String │ String │ Int64 │ String │
├─────┼────────┼────────┼───────┼────────┤
│ 1   │ x1     │ a      │ 12    │ green  │
│ 2   │ x2     │ a      │ 7     │ blue   │
│ 3   │ x1     │ b      │ 5     │ red    │
│ 4   │ x2     │ a      │ 4     │ blue   │
│ 5   │ x1     │ b      │ 9     │ yellow │

Para fazer isso em Python, o comando pode ser:

df_group = df.groupby(['A', 'B']).sum().reset_index()

Vou obter o seguinte resultado de saída com os rótulos das colunas iniciais:

    A  B   C
0  x1  a  12
1  x1  b  14
2  x2  a  11

Eu gostaria de fazer a mesma coisa em Julia. Tentei desta forma, sem sucesso:

df_group = aggregate(df, ["A", "B"], sum)

MethodError: nenhum método corresponde a + (:: String, :: String)

Tem ideia de como fazer isso na Julia?

Answer 1

Tente (na verdade, em vez de colunas sem string, provavelmente você quer colunas numéricas):

numcols = names(df, findall(x -> eltype(x) <: Number, eachcol(df)))
combine(groupby(df, ["A", "B"]), numcols .=> sum .=> numcols)

e se você quiser permitir missingvalores (e ignorá-los ao fazer uma soma), então:

numcols = names(df, findall(x -> eltype(x) <: Union{Missing,Number}, eachcol(df)))
combine(groupby(df, ["A", "B"]), numcols .=> sum∘skipmissing .=> numcols)

Answer 2

Julia DataFrames suporta a lógica dividir-aplicar-combinar , semelhante ao pandas, então a agregação parece

using DataFrames

df = DataFrame(:A => ["x1", "x2", "x1", "x2", "x1"], 
               :B => ["a", "a", "b", "a", "b"],
               :C => [12, 7, 5, 4, 9],
               :D => ["green", "blue", "red", "blue", "yellow"])

gdf = groupby(df, [:A, :B])
combine(gdf, :C => sum)

com o resultado

julia> combine(gdf, :C => sum)
3×3 DataFrame
│ Row │ A      │ B      │ C_sum │
│     │ String │ String │ Int64 │
├─────┼────────┼────────┼───────┤
│ 1   │ x1     │ a      │ 12    │
│ 2   │ x2     │ a      │ 11    │
│ 3   │ x1     │ b      │ 14    │

Você pode pular a criação de gdfcom a ajuda de Pipe.jl ou Underscores.jl

using Underscores

@_ groupby(df, [:A, :B]) |> combine(__, :C => sum)

Você pode dar nome à nova coluna com a seguinte sintaxe

julia> @_ groupby(df, [:A, :B]) |> combine(__, :C => sum => :C)
3×3 DataFrame
│ Row │ A      │ B      │ C     │
│     │ String │ String │ Int64 │
├─────┼────────┼────────┼───────┤
│ 1   │ x1     │ a      │ 12    │
│ 2   │ x2     │ a      │ 11    │
│ 3   │ x1     │ b      │ 14    │