Manipulando uma lista

Question

Eu tenho um conjunto de dados (dados de satélite) - Aqui está o link:

https://drive.google.com/drive/folders/1qBOROSDHSRMykZjWgP7iRMtpQ3gBMceL?usp=sharing

Para ler uma parte específica do conjunto de dados usado:

LISTA = FileNames[]; (* Here you assume you have your files in one specific Directory and list them*)

data1 = Import[
   LISTA[[1]], {"Datasets", "/PRODUCT/methane_mixing_ratio"}];

Verificar a estrutura de dados que se obtém

Dimensions[data1]

{1, 4173, 215}

Quero me livrar de parte do fundo (ou dados NaN) e colocar 0 (zeros)

Newdata1 = Flatten[ReplaceAll[data1, s_ /; s > 5000 -> 0]]

Quando isso é feito, no entanto, a estrutura de dados é "destruída" e se torna apenas uma grande lista de elementos

Dimensions[Newdata1]

{897195}

Existe uma maneira de substituir esses números e manter sua estrutura (1 x 4173 x 214)?

Tentei fazer isso sem usar a opção Flatten, mas não funcionou. Já vi algumas das perguntas aqui e isso pode ser um caso de problema de lista aninhada, mas não tenho certeza de como resolver isso.

Answer 1

Um caso para Clip?

Clip[RandomReal[10000, {3, 4, 5}],{5000,Infinity},{0,Infinity}]

Answer 2

Você também pode usar Threshold, que, para minha surpresa, é mais rápido do que Clip.

SeedRandom[1]
data1 = RandomReal[10000, {1, 4173, 215}];

Substituindo números maiores que 5000 por 0:

t1a = First @ RepeatedTiming[
    res1a = Subtract[data1, Threshold[data1, 5000 + $MachineEpsilon]]];
t2a = First @ RepeatedTiming[res2a = Clip[data1, {0, 5000}, {0, 0}]];
t3a = First @ RepeatedTiming[res3a = data1 UnitStep[Subtract[5000, data1]]];
t4a = First @ RepeatedTiming[res4a = Replace[data1, s_ /; s > 5000 -> 0., All]];
t5a = First @ RepeatedTiming[res5a = ReplaceAll[data1, s_ /; s > 5000 -> 0.]];

res1a == res2a == res3a == res4a == res5a

True

Dimensions @ res1a

 {1, 4173, 215}

Substituindo números menores que 5000 por 0:

t1b = First @ RepeatedTiming[res1b = Threshold[data1, 5000 + $MachineEpsilon]];
t2b = First @ RepeatedTiming[res2b = Clip[data1, {5000, ∞}, {0, ∞}]];
t3b = First @ RepeatedTiming[res3b = data1 UnitStep[Subtract[data1, 5000]]];
t4b = First @ RepeatedTiming[res4b = Replace[data1, s_ /; s < 5000 -> 0., All]];
t5b = First @ RepeatedTiming[res5b = ReplaceAll[data1, s_ /; s < 5000 -> 0.]];

res1b == res2b == res3b == res4b == res5b

True

Dimensions @ res1b

 {1, 4173, 215}

Comparações de tempo

{timingsa, timingsb} = {{t1a, t2a, t3a, t4a, t5a}, {t1b, t2b, t3b, t4b, t5b}};

functionsa = {"Subtract[data1,Threshold[data1,5000+$MachineEpsilon]]", "Clip[data1,{0,5000},{0,0}]", "data1 UnitStep[Subtract[5000,data1]]", "Replace[data1,s_/;s>5000\[Rule]0., All]", "ReplaceAll[data1,s_/;s>5000\[Rule]0.]"}; functionsb = {"Threshold[data1,5000+$MachineEpsilon]", 
   "Clip[data1,{5000, Infinity},{0,Infinity}]", 
   "data1 UnitStep[Subtract[data1,5000]]", 
   "Replace[data1,s_/;s<5000\[Rule]0., All]", 
   "ReplaceAll[data1,s_/;s<5000\[Rule]0.]"};

Grid[Join[{{Item["Replace numbers greater than 5000 with 0", 
     Background -> LightBlue], SpanFromLeft}}, 
  Transpose[{functionsa, timingsa}], 
 {{Item["Replace numbers less than 5000 with 0", 
     Background -> LightBlue], SpanFromLeft}}, 
  Transpose[{functionsb, timingsb}]], 
 Alignment -> {{Left, "."}, Center}, Dividers -> All]