Problema de corte de cubo

Question

Show[Graphics3D[{Cuboid[]}],
ContourPlot3D[{x==1/3,y==1/4,z==1/5},{x,-0.2,1.2},{y,-0.2,1.2},{z,-0.2,1.2}]]

Três planos dividem o cubo unitário em 8 cubos pequenos. Qual é a maneira mais fácil de obter esses 8 cubóides pequenos? Eu tentei a operação booleana regional que
RegionIntersection[Cuboid[], ImplicitRegion[x < 1/3 && y < 1/4 && z < 1/5, {x, y, z}]]dá

BooleanRegion [# 1 && # 2 &, {Cuboid [{0,0,0}], ImplicitRegion [x <1/3 && y <1/4 && z <1/5, {x, y, z}]}]

mas eu quero

Cuboide [{0, 0, 0}, {1/3, 1/4, 1/5}]

O resultado final esperado é

{Cubóide [{1 / 3,1 / 4,1 / 5}, {1,1,1}], Cubóide [{1 / 3,1 / 4,0}, {1,1,1 / 5}] , Cubóide [{1 / 3,0,1 / 5}, {1,1 / 4,1}], Cubóide [{1 / 3,0,0}, {1,1 / 4,1 / 5}] , Cuboide [{0,1 / 4,1 / 5}, {1 / 3,1,1}], Cuboide [{0,1 / 4,0}, {1 / 3,1,1 / 5}] , Cuboide [{0,0,1 / 5}, {1 / 3,1 / 4,1}], Cuboide [{0,0,0}, {1 / 3,1 / 4,1 / 5}] }

Show[Graphics3D[{Cuboid[]}],
ContourPlot3D[{x==1/3,y==1/4,z==1/5,x==3/4,y==5/6,z==6/7},
{x,-0.2,1.2},{y,-0.2,1.2},{z,-0.2,1.2}]]

Se puder ser estendido para o caso de seis aviões, será melhor.

Answer 1

xmesh = {0, 1/3, 2/3, 1};
ymesh = {0, 1/4, 2/4, 3/4, 1};
zmesh = {0, 1/5, 3/5, 4/5, 1};

cuboids =  Cuboid@@@(Transpose /@ Tuples[Partition[#, 2, 1]& /@ {xmesh, ymesh, zmesh}]);

Graphics3D[{Opacity[.3, RandomColor[]], #} & /@ cuboids, Boxed -> False]

Answer 2

Isso pode ser muito mais elegante e conciso usando Outer, mas funciona:

xplanes = {1/3, 2/3};
yplanes = {1/4, 2/4, 3/4};
zplanes = {1/5, 3/5, 4/5};
ends = {0, 1};

myPlanes = Union[ends, #] & /@ {xplanes, yplanes, zplanes};

theCuboidlets=Flatten[Table[
  Cuboid[{myPlanes[[1, i]], 
          myPlanes[[2, j]], 
          myPlanes[[3, k]]}, 
        {myPlanes[[1, i + 1]], 
         myPlanes[[2, j + 1]], 
         myPlanes[[3, k + 1]]}],
  {i, Length[myPlanes[[1]]] - 1},
  {j, Length[myPlanes[[2]]] - 1},
  {k, Length[myPlanes[[3]]] - 1}]];

Graphics3D[theCuboidlets]