Combinando vários índices
Tenho um grande conjunto de dados em que preciso comparar várias amostras em diferentes testes e em condições variadas. Estou procurando uma maneira de emparelhar e analisá-los facilmente. Como exemplo, digamos que eu tenha as Amostras (S) a, b e c, que passam pelos testes (T) 1 e 2, nas condições (C) x, y e z, que geram os resultados (R) R1 e R2.
S T C R1 R2
a 1 x 2.9
a 1 y 2.6
a 1 z 8.7
a 2 x 9.4 0.372
a 2 y 8.1 0.208
a 2 z 7.6 0.154
b 1 x 7.5
b 1 y 7.3
b 1 z 1.7
b 2 x 3.9 0.213
b 2 y 7.9 0.435
b 2 z 2.5 0.294
c 1 x 6.2
c 1 y 1.8
c 1 z 6.3
c 2 x 1.5 0.246
c 2 y 6.0 0.496
c 2 z 1.7 0.167
Os testes têm saídas diferentes e preciso aplicar funções específicas dependendo do teste. Tal como:
Test1[a,b] = R1a/R1b
Test2[a,b] = R1a/R2a - R1b/R2b
Os testes devem ser aplicados apenas a amostras com condições de correspondência, mas cada amostra deve ser emparelhada. Portanto, o resultado seria:
S1 S2 T C R
a b 1 x 2.9/7.5
a c 1 x 2.9/6.2
a b 2 x 9.4/0.372-3.9/0.213
a c 2 x 9.4/0.372-1.5/0.246
a b 1 y 2.6/7.3
...
Eu tenho tentado acertar por um tempo e acabo me confundindo. Alguém tem uma solução ou sugestões? Se você deseja um formato facilmente copiável do exemplo:
{{S, T, C, R1, R2}, {a, 1, x, 2.9}, {a, 1, y, 2.6}, {a, 1, z, 8.7},
{a, 2, x, 9.4, 0.372}, {a, 2, y, 8.1, 0.208}, {a, 2, z, 7.6, 0.154},
{b, 1, x, 7.5}, {b, 1, y, 7.3}, {b, 1, z, 1.7}, {b, 2, x, 3.9, 0.213},
{b, 2, y, 7.9, 0.435}, {b, 2, z, 2.5, 0.294}, {c, 1, x, 6.2}, {c, 1, y, 1.8},
{c, 1, z, 6.3}, {c, 2, x, 1.5, 0.246}, {c, 2, y, 6., 0.496}, {c, 2, z, 1.7, 0.167}}
Respostas
Não tenho certeza se entendi corretamente quais resultados devem ser recombinados, mas este código faz o seguinte: primeiro, os dados são coletados por condição, depois por teste, em seguida, subconjuntos de comprimento 2 são gerados e na etapa final o cálculo numérico dos resultados é aplicado:
test1[{{a_,1,c_,R1a_},{b_,1,c_,R1b_}}]:={a,b,1,c,R1a/R1b}
test2[{{a_,2,c_,R1a_,R2a_},{b_,2,c_,R1b_,R2b_}}]:={a,b,2,c,R1a/R2a-R1b/R2b}
{{S,T,C,R1,R2},{a,1,x,2.9},{a,1,y,2.6},{a,1,z,8.7},{a,2,x,9.4,0.372},{a,2,y,8.1,0.208},{a,2,z,7.6,0.154},{b,1,x,7.5},{b,1,y,7.3},{b,1,z,1.7},{b,2,x,3.9,0.213},{b,2,y,7.9,0.435},{b,2,z,2.5,0.294},{c,1,x,6.2},{c,1,y,1.8},{c,1,z,6.3},{c,2,x,1.5,0.246},{c,2,y,6.,0.496},{c,2,z,1.7,0.167}};
GatherBy[%,#[[3]]&][[2;;]];
Flatten[GatherBy[#,{x}\[Function]x[[2]]]&/@%,1];
Flatten[Subsets[#,{2}]&/@%,1];
If[#[[1,2]]===1,test1[#],test2[#]]&/@%;
%//TableForm
o que resulta em
a b 1 x 0.386667
a c 1 x 0.467742
b c 1 x 1.20968
a b 2 x 6.95896
a c 2 x 19.1713
b c 2 x 12.2123
a b 1 y 0.356164
a c 1 y 1.44444
b c 1 y 4.05556
a b 2 y 20.7814
a c 2 y 26.8455
b c 2 y 6.06415
a b 1 z 5.11765
a c 1 z 1.38095
b c 1 z 0.269841
a b 2 z 40.8472
a c 2 z 39.171
b c 2 z -1.67624
Este não é o resultado esperado por OP, pois contém todos os subconjuntos possíveis para um determinado teste e condição (por exemplo, a terceira entrada b, c teste 1 sob a condição x). Se houver um critério mais envolvido para a combinação de resultados, a etapa que gera os subconjuntos no código acima precisa ser substituída / refinada. Usar em Subsequencesvez de Subsetsconsidera apenas tuplas ordenadas que podem ser a solução que OP está procurando:
a b 1 x 0.386667
b c 1 x 1.20968
a b 2 x 6.95896
b c 2 x 12.2123
a b 1 y 0.356164
b c 1 y 4.05556
a b 2 y 20.7814
b c 2 y 6.06415
a b 1 z 5.11765
b c 1 z 0.269841
a b 2 z 40.8472
b c 2 z -1.67624
data = {{"S", "T", "C", "R1", "R2"}, {a, 1, x, 2.9}, {a, 1, y,
2.6}, {a, 1, z, 8.7}, {a, 2, x, 9.4, 0.372}, {a, 2, y, 8.1,
0.208}, {a, 2, z, 7.6, 0.154}, {b, 1, x, 7.5}, {b, 1, y, 7.3}, {b,
1, z, 1.7}, {b, 2, x, 3.9, 0.213}, {b, 2, y, 7.9, 0.435}, {b, 2,
z, 2.5, 0.294}, {c, 1, x, 6.2}, {c, 1, y, 1.8}, {c, 1, z,
6.3}, {c, 2, x, 1.5, 0.246}, {c, 2, y, 6., 0.496}, {c, 2, z, 1.7,
0.167}};
Grid[data, Dividers -> All, Background -> {None, 1 -> LightBlue},
Alignment -> {{Center, Center, Center, ".", "."}, Center}]
t1 = {#[[1]], #2[[1]], #[[2]], #[[3]], #[[4]]/#2[[4]]} &;
t2 = {#[[1]], #2[[1]], #[[2]], #[[3]], #[[4]]/#[[5]] - #2[[4]]/#2[[5]]} &;
proc = If[#[[1, 2]] === 1, t1 @@ #, t2 @@ #] &;
GroupBydados por {test, condition}(colunas 2 e 3) e processar 2 subconjuntos usando proc:
data2 = Join @@ Values @ GroupBy[Rest @ data, #[[{2, 3}]] &,
Map[proc] @ Subsets[#, {2}] &];
Grid[Prepend[{"S1", "S2", "T", "C", "R"}]@data2,
Dividers -> All, Background -> {None, 1 -> LightBlue},
Alignment -> {{Center, Center, Center, Center, "."}, Center}]
Como alternativa, podemos usar GatherBy:
data2 == Join @@ Map[Map[proc] @ Subsets[#, {2}]&] @ GatherBy[Rest@data, #[[{2, 3}]]&]
True