Plot3D não funciona com uma função de 2 variáveis

Question

Estou tentando plotar uma função de 2 variáveis ​​que também possui alguns parâmetros. Eu o defini como:

f[x_,y_][pars_] := ...

onde parsestá o conjunto de parâmetros. No entanto, não consigo plotar a função. Tentei usar:

Plot3D[f[x,y], ...]

e

Plot3D[f[x,y][pars], ...]

mas nenhum dos dois funciona. O colchete preto aparece à direita e o programa está em execução, mas não há saída. Como posso resolver isso?

Aqui está o link para o bloco de notas: https://drive.google.com/file/d/1NdrBwRJ7BWaguXHxmt2bnJdkHhg5IIb4/view?usp=sharing

Answer 1

Antes de culpar, Plot3Dolhe para a função que você está alimentando. Se eu corro B[-a, -a][pars]no seu notebook, ele não retorna em tempo hábil. Olhando para a definição de Bvocê tem

B[x_, y_][pars_] := ...

mas observe que parsnão aparece no lado direito dessa expressão. Então, quando você chamar Bele não se acostumar, e as variáveis reais Nm, Nn, etc, permanecem indefinidos ao chamar B.

Em vez disso, faça algo como

B[x_, y_][pars_] := With[
    {Nm = Lookup[pars, Nm], Nn = Lookup[pars, Nn], <the rest of your variables>},
    <your big expression>
]

Como parsé uma lista de regras, ela é usada Lookuppara obter os valores numéricos reais e, em seguida, Withpara fazer a substituição.

Depois disso, posso verificar se avalia

In[44]:= B[-a, -a][pars]

Out[44]= 119996.

e faz isso muito rapidamente.

Answer 2

Clear["Global`*"]

Subscript[B, 0] = 120000;  (* in G*)

Subscript[Φ, 0] = 
 2.0679*10^-7*10^16 // Rationalize;    (* in G A^2 *)

a = Sqrt[(2*Subscript[Φ, 0])/(Sqrt[3]*Subscript[B, 0])]; 
  K[m_, n_] = Sqrt[(2*Pi^2*Subscript[B, 0])/
           (Sqrt[3]*Subscript[Φ, 0])]*{(-Sqrt[3])*n, 
    2*m - n}; 
ξ0 = Sqrt[
    Subscript[Φ, 0]/(2*Pi*Hc2)] /. {Hc2 -> 350000}; 
pars = {ξ -> ξ0, λ -> 2700, Nn -> 2, Nm -> 2}; 

B[x_, y_][{ξ_?NumericQ, λ_?NumericQ, Nn_Integer, Nm_Integer}] := 
   Subscript[B, 0] + Subscript[B, 0]*
       Sum[If[m == 0 && n == 0, 0, 
     If[K[n, m] . K[n, m]*ξ^2 < 0.05, 0, 
       Exp[(-ξ^2)*(K[m, n] . K[m, n]/2)]/
                 (1 + λ^2*K[m, n] . K[m, n])]*
      Cos[K[m, n] . {x, y}]], 
         {m, -Nm, Nm}, {n, -Nn, Nm}]

Plot3D[ 
 B[x, y][{ξ, λ, Nn, Nm} /. pars],
 {x, -a, a}, {y, -a, a},
 AxesLabel -> Automatic,
 PlotPoints -> 50]

DensityPlot[ 
 B[x, y][{ξ, λ, Nn, Nm} /. pars],
 {x, -a, a}, {y, -a, a},
 FrameLabel -> Automatic,
 PlotPoints -> 100,
 PlotLegends -> Automatic]

Bmax = B[0, 0] [{ξ, λ, Nn, Nm} /. pars] // N

120011.

Bmin = N[B[a/2, a/(2*Sqrt[3])][{ξ, λ, Nn, Nm} /. pars]]

119995.