`PlotLabel` para plotagens em uma` Tabela`

Question

Eu tenho um Tablecontendo dois gráficos, dados por

Table[
 Plot[{Re[f[n]] /. j -> 3, Im[f[n]] /. j -> 3}, {n, 0, 15}, 
  GridLines -> Automatic, PlotRange -> All, PlotLegends -> {"Real", "Imaginary"}, 
  PlotLabel -> f[n]], 
{f, {Sum[Sinc[Pi*(#1 - i*j)], {i, 1, Floor[#1]}] & , 
   (-1 + E^(2*I*Pi*#1))/(j*(-1 + E^((2*I*Pi*#1)/j))) & }}
]

Como você pode ver, o Mathematica reescreveu o primeiro PlotLabel(ou seja, Sum[Sinc[Pi*(#1 - i*j)], {i, 1, Floor[#1]}] &) em uma expressão que considera mais útil ou natural. Eu não quero fazer isso. Eu quero que o PlotLabelpara esse enredo fique assim:

ou seja, como se estivesse escrito PlotLabel -> "expr". Mas o outro rótulo já é como eu quero.

Eu experimentei usar, StringFormmas não ajuda. Como eu faço isso? Ou isso não é possível?

Answer 1

Table[Plot[{Re[ReleaseHold@f] /. j -> 3,  Im[ReleaseHold@f] /. j -> 3}, {n, 0, 15}, 
  GridLines -> Automatic, 
  PlotRange -> All, ImageSize -> 350, 
  PlotLegends -> {"Real", "Imaginary"}, 
  PlotLabel ->  f], 
{f, {HoldForm@Sum[Sinc[Pi*(n - i*j)], {i, 1, Floor[n]}], 
   HoldForm[(-1 + E^(2*I*Pi*n))/(j*(-1 + E^((2*I*Pi*n)/j)))]}}]

Você pode substituir HoldForme ReleaseHoldpor Defere First, respectivamente, para obter o mesmo resultado.

Como Bob Hanlon sugeriu nos comentários, nas versões 12.0+ você pode usar ReImPloto seguinte:

 Table[ReImPlot[ReleaseHold[f] /. j -> 3, {n, 0, 15}, 
    GridLines -> Automatic, PlotRange -> All, ImageSize -> 350, 
    PlotLegends -> "ReIm", 
    ReImLabels -> {"Real", "Imaginary"}, 
    ReImStyle -> {ColorData[97][1], {ColorData[97][2], Dashing[{}]}},
    PlotLabel -> f], 
  {f, {HoldForm@Sum[Sinc[Pi*(n - i*j)], {i, 1, Floor[n]}], 
      HoldForm[(-1 + E^(2*I*Pi*n))/(j*(-1 + E^((2*I*Pi*n)/j)))]}}]