Bir "Tablo" daki grafikler için "PlotLabel"

Question

Ben var Tabletarafından verilen, iki araziler içeren

Table[
 Plot[{Re[f[n]] /. j -> 3, Im[f[n]] /. j -> 3}, {n, 0, 15}, 
  GridLines -> Automatic, PlotRange -> All, PlotLegends -> {"Real", "Imaginary"}, 
  PlotLabel -> f[n]], 
{f, {Sum[Sinc[Pi*(#1 - i*j)], {i, 1, Floor[#1]}] & , 
   (-1 + E^(2*I*Pi*#1))/(j*(-1 + E^((2*I*Pi*#1)/j))) & }}
]

Gördüğünüz gibi, Mathematica ilkini PlotLabel(yani Sum[Sinc[Pi*(#1 - i*j)], {i, 1, Floor[#1]}] &) daha kullanışlı veya doğal bulduğu bir ifadeye yeniden yazdı . Bunu yapmasını istemiyorum. İstediğim PlotLabelböyle bir görünüm için bu arsa için:

yani, yazılmış gibi PlotLabel -> "expr". Ama diğer etiket zaten benim istediğim gibi.

Kullanmayı denedim StringFormama yardımcı olmuyor. Bunu nasıl yaparım? Yoksa mümkün değil mi?

Answer 1

Table[Plot[{Re[ReleaseHold@f] /. j -> 3,  Im[ReleaseHold@f] /. j -> 3}, {n, 0, 15}, 
  GridLines -> Automatic, 
  PlotRange -> All, ImageSize -> 350, 
  PlotLegends -> {"Real", "Imaginary"}, 
  PlotLabel ->  f], 
{f, {HoldForm@Sum[Sinc[Pi*(n - i*j)], {i, 1, Floor[n]}], 
   HoldForm[(-1 + E^(2*I*Pi*n))/(j*(-1 + E^((2*I*Pi*n)/j)))]}}]

Sen değiştirebilir HoldFormve ReleaseHoldile Deferve Firstaynı sonucu elde etmek için, sırasıyla.

Bob Hanlon'un yorumlarda önerdiği gibi, 12.0+ sürümlerinde ReImPlotaşağıdaki gibi kullanabilirsiniz :

 Table[ReImPlot[ReleaseHold[f] /. j -> 3, {n, 0, 15}, 
    GridLines -> Automatic, PlotRange -> All, ImageSize -> 350, 
    PlotLegends -> "ReIm", 
    ReImLabels -> {"Real", "Imaginary"}, 
    ReImStyle -> {ColorData[97][1], {ColorData[97][2], Dashing[{}]}},
    PlotLabel -> f], 
  {f, {HoldForm@Sum[Sinc[Pi*(n - i*j)], {i, 1, Floor[n]}], 
      HoldForm[(-1 + E^(2*I*Pi*n))/(j*(-1 + E^((2*I*Pi*n)/j)))]}}]