Groupby mit Summe auf Julia Dataframe

Question

Ich versuche, eine groupby + Summe auf einem Julia-Datenrahmen mit Int- und String-Werten zu erstellen

Zum Beispiel df:

│ Row │ A      │ B      │ C     │ D      │
│     │ String │ String │ Int64 │ String │
├─────┼────────┼────────┼───────┼────────┤
│ 1   │ x1     │ a      │ 12    │ green  │
│ 2   │ x2     │ a      │ 7     │ blue   │
│ 3   │ x1     │ b      │ 5     │ red    │
│ 4   │ x2     │ a      │ 4     │ blue   │
│ 5   │ x1     │ b      │ 9     │ yellow │

Um dies in Python zu tun, könnte der Befehl sein:

df_group = df.groupby(['A', 'B']).sum().reset_index()

Ich werde das folgende Ausgabeergebnis mit den anfänglichen Spaltenbeschriftungen erhalten:

    A  B   C
0  x1  a  12
1  x1  b  14
2  x2  a  11

Ich würde gerne dasselbe in Julia machen. Ich habe es erfolglos versucht:

df_group = aggregate(df, ["A", "B"], sum)

MethodError: Keine übereinstimmende Methode + (:: String, :: String)

Haben Sie eine Idee, wie Sie dies in Julia tun können?

Answer 1

Versuchen Sie es (tatsächlich möchten Sie anstelle von Spalten ohne Zeichenfolge wahrscheinlich Spalten, die numerisch sind):

numcols = names(df, findall(x -> eltype(x) <: Number, eachcol(df)))
combine(groupby(df, ["A", "B"]), numcols .=> sum .=> numcols)

und wenn Sie missingWerte zulassen möchten (und diese beim Summieren überspringen möchten ), dann:

numcols = names(df, findall(x -> eltype(x) <: Union{Missing,Number}, eachcol(df)))
combine(groupby(df, ["A", "B"]), numcols .=> sum∘skipmissing .=> numcols)

Answer 2

Julia DataFrames unterstützen Split- Apply -Combine- Logik, ähnlich wie Pandas, sodass die Aggregation so aussieht

using DataFrames

df = DataFrame(:A => ["x1", "x2", "x1", "x2", "x1"], 
               :B => ["a", "a", "b", "a", "b"],
               :C => [12, 7, 5, 4, 9],
               :D => ["green", "blue", "red", "blue", "yellow"])

gdf = groupby(df, [:A, :B])
combine(gdf, :C => sum)

mit dem Ergebnis

julia> combine(gdf, :C => sum)
3×3 DataFrame
│ Row │ A      │ B      │ C_sum │
│     │ String │ String │ Int64 │
├─────┼────────┼────────┼───────┤
│ 1   │ x1     │ a      │ 12    │
│ 2   │ x2     │ a      │ 11    │
│ 3   │ x1     │ b      │ 14    │

Sie können die Erstellung gdfmit Hilfe von Pipe.jl oder Underscores.jl überspringen

using Underscores

@_ groupby(df, [:A, :B]) |> combine(__, :C => sum)

Sie können der neuen Spalte mit der folgenden Syntax einen Namen geben

julia> @_ groupby(df, [:A, :B]) |> combine(__, :C => sum => :C)
3×3 DataFrame
│ Row │ A      │ B      │ C     │
│     │ String │ String │ Int64 │
├─────┼────────┼────────┼───────┤
│ 1   │ x1     │ a      │ 12    │
│ 2   │ x2     │ a      │ 11    │
│ 3   │ x1     │ b      │ 14    │