कोवेरियन की गणना सही ढंग से करने के लिए फंक्शन `कोवरियनस 'का उपयोग कैसे करें?

Question

नोट: निम्नलिखित प्रश्न 2005 चीनी स्नातक गणित प्रवेश परीक्षा (पहले सेट) के 23 वें प्रश्न से हैं :

मान लीजिए $X_{1}, X_{2}, \cdots, X_{n}(n>2)$ जनसंख्या से एक सरल यादृच्छिक नमूना है $\mathrm{N}(0,1)$, तथा $\bar{X}$ नमूना मतलब है ($\bar{X}=\frac{X_1+X_2+\cdots+X_n}{n}$), $Y_{i}=X_{i}-\bar{X}$, $i=1,2, \cdots, n $।

अब हमें निम्नलिखित समस्याओं को हल करने की आवश्यकता है:

(१) विचरण $D Y_{i}$ का $Y_{i}$,$i=1,2, \cdots, n $।

(२) सहसंयोजक $\operatorname{Cov}\left(Y_{1}, Y_{n}\right)$ का $Y_{1}$ तथा $Y_{n}$।

मैं n = 10इस समस्या को हल करने के लिए एक विशेष मामले के रूप में उपयोग करता हूं :

Y1 = TransformedDistribution[x[1] - Sum[x[i], {i, 1, 10}]/10, 
  Table[x[i] \[Distributed] NormalDistribution[], {i, 1, 10}]]
Variance[Y1]
Y10 = TransformedDistribution[x[10] - Sum[x[i], {i, 1, 10}]/10, 
  Table[x[i] \[Distributed] NormalDistribution[], {i, 1, 10}]]
Variance[Y10]
Covariance[Y1, Y10]
Correlation[Y1, Y10]

लेकिन उपरोक्त कोड को Y1और Y10सही ढंग से (संदर्भ उत्तर है) का सह-प्रसार नहीं मिल सकता है$-\frac{1}{10}$) का है। मैं Covarianceइस समस्या को हल करने के लिए फ़ंक्शन का उपयोग कैसे कर सकता हूं ?

Answer 1

आपको उनके वितरण से यादृच्छिक चर को अलग करने वाले अंकन का उपयोग करना चाहिए। निम्नलिखित कोड आपको वांछित संस्करण और सहसंबंध प्राप्त करना चाहिए:

n = 10; 
distY1Yn = TransformedDistribution[{x[1] - Sum[x[i], {i, 1, n}]/n, x[n] - Sum[x[i], {i, 1, n}]/n}, 
  Table[x[i] \[Distributed] NormalDistribution[], {i, 1, n}]];
Covariance[distY1Yn]
(* {{9/10, -(1/10)}, {-(1/10), 9/10}} *)
Correlation[distY1Yn]
(* {{1, -(1/9)}, {-(1/9), 1}} *)

distY1 = TransformedDistribution[x[1] - Sum[x[i], {i, 1, n}]/n, 
   Table[x[i] \[Distributed] NormalDistribution[], {i, 1, n}]];
Variance[distY1]
(* 9/10 *)

distYn = TransformedDistribution[x[n] - Sum[x[i], {i, 1, n}]/n, 
   Table[x[i] \[Distributed] NormalDistribution[], {i, 1, n}]];
Variance[distYn]
(* 9/10 *)