मैं जेड-प्लेन से डब्ल्यू-प्लेन तक एक कंफर्टेबल मैपिंग कैसे करूं

Question

मैं गणितज्ञों में कुल आरंभक हूं। एक बात नहीं जानते। मुझे नक्शे के अनुरूप प्रकृति को दिखाने के लिए कुछ चित्र बनाने की आवश्यकता है$w=e^z$।

मुझे कुछ अंतर्विरोधों को आकर्षित करने की आवश्यकता है $z$-विमान; जैसे, क्षैतिज रेखा, ऊर्ध्वाधर रेखा, 45 डिग्री रेखा और इकाई चक्र। फिर मुझे मैप किए गए वक्र प्राप्त करने की आवश्यकता है$w$-जहाँ $u$ तथा $v$ के कार्य हैं $x$ तथा $y$।

मैं यह कैसे करूं पता नहीं है? क्रिप्या मेरि सहायता करे।

Answer 1

कमेंट का जवाब दें।

MeshShadingक्षेत्र को भरने के लिए उपयोग करें ।

expr1 = {x, y};
expr2 = With[{z = x + I*y}, E^z // ReIm // ComplexExpand];
ParametricPlot[#, {x, -4, 4}, {y, -4, 4}, 
    MeshFunctions -> {#3 &, #4 &, #4 - #3 &, Sqrt[#3^2 + #4^2] &}, 
    Mesh -> {{1}, {1}, {0}, {1}}, 
    MeshShading -> {{{{Red, None}, {None, None}}, {{Red, None}, {None,
          None}}}, {{{None, None}, {None, None}}, {{None, 
         None}, {None, None}}}}, 
    MeshStyle -> {{Thick, Red, Opacity[1]}, {Thick, Green, 
       Opacity[1]}, {Thick, Blue, Opacity[1]}, {Thick, Yellow, 
       Opacity[1]}}, Axes -> False, PlotRange -> 4, 
    BoundaryStyle -> None, 
    LabelStyle -> {FontFamily -> "Times", Blue}, PlotPoints -> 80, 
    PlotStyle -> None] & /@ {expr1, expr2} // GraphicsRow

सरल

expr1 = {x, y};
expr2 = With[{z = x + I*y}, E^z // ReIm // ComplexExpand];
ParametricPlot[#, {x, -4, 4}, {y, -4, 4}, 
    MeshFunctions -> {#3 &, #4 &, #4 - #3 &, Sqrt[#3^2 + #4^2] &}, 
    Mesh -> {{1}, {1}, {0}, {1}}, 
    MeshStyle -> {{Thick, Red, Opacity[1]}, {Thick, Green, 
       Opacity[1]}, {Thick, Blue, Opacity[1]}, {Thick, Yellow, 
       Opacity[1]}}, Axes -> False, PlotRange -> 4, 
    BoundaryStyle -> None, 
    LabelStyle -> {FontFamily -> "Times", Blue}, PlotPoints -> 80, 
    PlotStyle -> None] & /@ {expr1, expr2} // GraphicsRow

मूल

expr = With[{z = x + I*y}, E^z // ReIm // ComplexExpand]
xy = ParametricPlot[{x, y}, {x, -2, 2}, {y, -2, 2}, 
   MeshFunctions -> {#1 &, #2 &, #2 - #1 &, Sqrt[#1^2 + #2^2] &}, 
   Mesh -> {{1}, {1}, {0}, {1}}, 
   MeshStyle -> {{Thick, Red, Opacity[1]}, {Thick, Green, 
      Opacity[1]}, {Thick, Blue, Opacity[1]}, {Thick, Yellow, 
      Opacity[1]}}, PlotPoints -> 50, FrameLabel -> {x, y}, 
   PlotStyle -> None];
uv = ParametricPlot[expr, {x, -4, 4}, {y, -4, 4}, 
   MeshFunctions -> {#3 &, #4 &, #4 - #3 &, Sqrt[#3^2 + #4^2] &}, 
   Mesh -> {{1}, {1}, {0}, {1}}, 
   MeshStyle -> {{Thick, Red, Opacity[1]}, {Thick, Green, 
      Opacity[1]}, {Thick, Blue, Opacity[1]}, {Thick, Yellow, 
      Opacity[1]}}, Axes -> False, PlotRange -> 8, 
   BoundaryStyle -> None, FrameLabel -> {u, v}, 
   LabelStyle -> {FontFamily -> "Times", Blue}, PlotPoints -> 80, 
   PlotStyle -> None];
GraphicsRow[{xy, uv}]