¿Cómo puedo hacer esos dibujos?

Question

Esta Fig. Representa LQU, donde LQU es una función de $c_1,c_3$y $c_3$, $c_i \in[-1,1]$.

¿Cómo puedo hacer tales dibujos?

Answer 1

tet = Tetrahedron[{{-1, -1, -1}, {1, 1, -1}, {-1, 1, 1}, {1, -1, 1}}];

Graphics3D[{tet}, Axes -> True]

Podemos usar RegionPlot3Dcon las opciones Meshy MeshShadingsubdividir teten 8 tetraedros y estilizar las caras de manera diferente:

SeedRandom[12]

RegionPlot3D[tet,  
 PlotPoints -> 90, BaseStyle -> Opacity[.9], 
 Mesh -> 1, 
 MeshShading -> RandomColor[{2, 2, 2}] , 
 Lighting -> "Neutral", Axes -> True]

También podemos usar la función SymmetricSubdivisionde Tetraedro >> Aplicaciones para subdividir teten 8 tetraedros:

SymmetricSubdivision[Tetrahedron[pl_], k_] /; 0 <= k < 2^Length[pl] := 
  Module[{n = Length[pl] - 1, i0, bl, pos},
   i0 = DigitCount[k, 2, 1]; bl = IntegerDigits[k, 2, n];
   pos = FoldList[If[#2 == 0, #1 + {0, 1}, #1 + {1, 0}] &, {0, i0},  Reverse[bl]];
   Tetrahedron @ Map[Mean, Extract[pl, #] & /@ Map[{#} &, pos + 1, {2}]]]

colors = {Yellow, Yellow, Blue, Yellow, Blue, Blue, Blue, Yellow};

Graphics3D[{colors[[# + 1]], SymmetricSubdivision[tet, #]} & /@ 
  Range[0, 7], BaseStyle -> Opacity[0.5], Axes -> True]