Integral kontur numerik

Question

Saya mencoba menghitung integral ganda untuk tetap $m,z>0$:

  (2Pi I)^{-1} Integrate[(Gamma[y/2] Sqrt[Gamma[3 - y]/Gamma[y]])/
  Gamma[(3 - y)/2] z^(3 - y)
   (Exp[-m x] - 1) x^(y - 3)/x, {x, 0, ∞},{y, 
  3/2 - I ∞, 3/2 + I ∞}]

Integral berakhir $x$ dapat dilakukan secara analitis, dan hasilnya tergantung pada produknya $mz$, jadi secara efektif hanya ada satu parameter. Itu$x$ integral perlu dipecah menjadi dua wilayah yang saya duga, dan dalam satu wilayah kontur $y$integral perlu dideformasi agar tetap konvergen. Sejak$y$ integral melibatkan pemotongan cabang yang rumit, saya ingin dapat melakukannya secara numerik untuk berbagai $mz$, untuk mendapatkan ketepatan setidaknya beberapa digit. Saya mengalami kesulitan mendapatkan hasil yang stabil secara numerik.

Answer 1

Saya tidak berpikir integral ini menyatu: hanya dengan melihat $x$-integrasi,

Assuming[m > 0 && z > 0 && Element[q, Reals], 
  Integrate[((E^(-m*x)-1)*x^(y-4)*z^(3-y)*Gamma[y/2]*
            Sqrt[Gamma[3-y]/Gamma[y]])/Gamma[(3-y)/2] /.
            y->3/2+I*q,
            {x, 0, ∞}]]

(*    diverges    *)

Tampaknya hanya menyatu jika $\text{Re}(y)$ dalam interval $[2,3]$:

Assuming[m > 0 && z > 0,
  Integrate[((E^(-m*x)-1)*x^(y-4)*z^(3-y)*Gamma[y/2]*
            Sqrt[Gamma[3-y]/Gamma[y]])/Gamma[(3-y)/2],
            {x, 0, ∞}]]

(*    (m^(3-y)*z^(3-y)*Gamma[y-3]*Gamma[y/2]*Sqrt[Gamma[3-y]/Gamma[y]])/Gamma[(3-y)/2]
      if 2 < Re[y] < 3                                                                  *)

Menggunakan hasil terakhir ini:

f[m_, z_, y_] = 
  Assuming[m > 0 && z > 0 && 2 < Re[y] < 3, 
    Integrate[((E^(-m*x)-1)*x^(y-4)*z^(3-y)*Gamma[y/2]*Sqrt[Gamma[3-y]/Gamma[y]])/Gamma[(3-y)/2],
              {x, 0, ∞}]]

(*    ((m*z)^(3-y)*Gamma[y-3]*Gamma[y/2]*Sqrt[Gamma[3-y]/Gamma[y]])/Gamma[(3-y)/2]    *)

kita dapat mendefinisikan integral yang diinginkan sebagai

F[mz_?NumericQ, Ry_?NumericQ] := 
  2*I*NIntegrate[Re[f[mz, 1, Ry + I t]], {t, 0, ∞}]

memanfaatkan beberapa kesimetrian f: itu hanya tergantung pada produk$m\cdot z$, tidak menyala $m$ dan $z$secara individu; itu simetris$t$ sehingga kami dapat membatasi integral ke $[0,∞)$(tapi ambillah dua kali); dan hasilnya akan murni khayalan jadi kita hanya mengintegrasikan bagian nyata dari integrand tersebut.

Sekarang kita dapat memplot, misalnya, hasil untuk Ry = Re[y] = 5/2: (memplot bagian imajiner)

Plot[F[mz, 5/2]/I, {mz, 0, 10}]

Kita bisa berpetualang dan diatur Ry = Re[y] = 3/2oleh kelanjutan analitik:

Plot[F[mz, 5/2]/I, {mz, 0, 10}]