PlotLegends'a nasıl başlık eklenir?

Question

Kullandığım arsa efsanelerine bir başlık koymak istiyorum. Burada kullanmamı söyleyen bir çözüm buluyorumPlotLegends -> SwatchLegend[{0, 3.3, 6.7, 10, 13, 17, 20}, LegendLabel -> "mu"] . Ama efsaneleri de kullanmak istediğim yere yerleştirmek istiyorum PlotLegends -> Placed[Range[1, 6, 1], {0.2, 0.3}].

İkisini de nasıl yapabilirim?

Düzenleme: Cevap verildiği gibi, sarma çalışıyor, ancak hala bir sorun var, yani arsam şuna benziyor:

Efsanelere "H" adını vermek istediğim yer. Ama Swatchlegend olayını yaptığımda şöyle oluyor:

İşaretleri ve renkleri aynı tutmak istiyorum. Ne yapmalıyım?

Answer 1

Muhtemelen arıyorsunuz PointLegend, ancak başkalarının sonuçlarınızı yeniden üretebilmesi için daha fazla ayrıntı sağlamalısınız.

mu = {0, 3.3, 6.7, 10, 13, 17, 20};
pl = PointLegend[mu, LegendLabel -> "mu", LegendFunction -> "Frame", 
   LegendLayout -> "Row", LegendMarkers -> Automatic];
fns = Table[n^(1/p), {p, 7}, {n, 10}];
ListLinePlot[fns, PlotMarkers -> Automatic, 
 PlotLegends -> Placed[pl, Top]]

Answer 2

Yerleştirilenleri açıklamanın etrafına sarabilirsiniz. SwatchLegend belgelerinden değiştirilmiş bir örnek:

Plot[{Sin[x], Cos[x]}, {x, 0, 5}, 
   PlotLegends -> Placed[SwatchLegend[{"first", "second"}, 
LegendLabel -> "legend title"], {0.2, 0.3}]]

Answer 3

Kullanabilirsiniz PlotLegends - > Placed[labels, Top, Labeled[#, legendlabel, Top] &].

Tim Laska'nın cevabındaki örnek girişi kullanarak:

mu = {0, 3.3, 6.7, 10, 13, 17, 20};
fns = Table[n^(1/p), {p, 7}, {n, 10}];

ListLinePlot[fns, PlotMarkers -> Automatic, 
 PlotLegends -> Placed[mu, Top, Labeled[#, Style["mu", 16], Top] &]]

Üçüncü argümanı kullanarak görünümü daha da güzelleştirebilirsiniz Placed:

ListLinePlot[fns, PlotMarkers -> Automatic, 
 PlotLegends -> Placed[mu, Top, Panel @ Labeled[#, Style["mu", 16], Top] &]]

ListLinePlot[fns, PlotMarkers -> Automatic, 
 PlotLegends ->  Placed[mu, Top, 
   Framed[#, FrameStyle -> Directive[Thin, Gray], 
       RoundingRadius -> 5, ImageMargins -> 5] & @
     Labeled[#, Style[Row[{Spacer[5], "mu"}], 24, "Section"], {{Top, Left}}] &]]