Una duda sobre ParametricPlot3D, RevolutionPlot3D, ListPlots y NIntegrate: ¿puedo construir un “RevolutionListPlot3D”?

Question

En primer lugar: esta pregunta se encuentra en el contexto de Superficies e incrustaciones sobre geometría diferencial. Más precisamente en el contexto de las coordenadas de Kruskal y cómo trazar un agujero de gusano Schwarzschild dinámico 3D$[1]$, $[2]$, $[3]$. El contexto principal se da como referencia$[1]$.

PARTE I) Un poco de física y matemáticas

I.1) Un "nada" sobre la gravedad y los agujeros negros

Los agujeros negros son soluciones de las ecuaciones de campo de Einstein. Más precisamente, tenemos entonces la ecuación maestra (tensorial):

$$\textbf{Ric} - \frac{1}{2}R\textbf{g} = \frac{8\pi G}{c^{4}} \textbf{T} \tag{1}$$

Las soluciones de la ecuación $(1)$ están dados por los tensores métricos:

$$\textbf{g} = g_{\mu\nu} \textbf{dx}^{\mu} \otimes \textbf{dx}^{\nu} \tag{2}$$

En un gráfico de coordenadas (también conocido como donde hacemos cálculos), podemos expresar la cantidad escalar llamada elemento de línea que es precisamente el campo escalar cuando el tensor métrico actúa sobre campos vectoriales tangentes en una variedad$\mathcal{M}$:

$$\textbf{g}(d\textbf{r},d\textbf{r}) = g_{\mu\nu}dx^{\mu}dx^{\nu} := ds^2\tag{3}$$

Por lo tanto, dado un tensor métrico en una variedad, caracterizamos la geometría, de manera puntual, de la variedad.

Un hecho importante sobre los tensores es algo llamado covarianza general : la física es independiente de las coordenadas; los fenómenos de la naturaleza no se preocupan por las coordenadas; las ecuaciones de la física deben ser independientes de las coordenadas; los fenómenos de la naturaleza pueden describirse bien mediante el uso del sistema de coordenadas cartesianas, e igualmente bien descritos mediante cualquier sistema de coordenadas curvilíneas. El objeto matemático que captura este hecho son los tensores.

Por lo tanto, el objeto abstracto (tensor métrico) es independiente de las transformaciones de coordenadas:

$$ \textbf{g'} = \textbf{g} \tag{4}$$

Pero en un nivel de gráficos de coordenadas, sus coordenadas cambian en una forma como:

$$ g'_{\mu\nu} = \frac{\partial x^{\alpha}}{\partial x'^{\mu}}\frac{\partial x^{\beta}}{\partial x^{\nu'}}g_{\alpha \beta}\tag{5}$$

Un agujero negro de Schwarzschild tiene el siguiente tensor métrico:

$$ ds^{2} = -\Bigg(1- \frac{2GM}{c^{2}r}\Bigg)c^{2}dt^{2} + \frac{1}{1-\frac{2GM}{c^{2}r}}dr^{2} - r^{2}d\theta^{2} + r^{2}sin^{2}(\theta)d\phi^{2}\tag{6}$$

Podemos ver fácilmente el gráfico de coordenadas aquí: las coordenadas esféricas extendidas a la física del espacio-tiempo;

$$\mathrm{Coordinates} \implies (t,r,\theta,\phi) \tag{7}$$

Por lo tanto, estamos tratando con un espacio-tiempo de cuatro dimensiones. $\mathcal{M}$.

I.2) Procedimiento de incrustación del agujero de gusano de Schwarschild

El contexto básico aquí es: necesitamos representar ese espacio-tiempo de cuatro dimensiones $(6)$en un espacio euclidiano tridimensional. Luego, debemos incrustar una superficie en un espacio 3D.

Luego "suprimimos" dos dimensiones, es decir, fijamos un momento de coordenadas de tiempo $t = T \in \mathbb{R}$ y un ángulo de coordenadas $\theta = \frac{\pi}{2}$(de hecho, este ángulo nos da la geometría del "plano ecuatiorial"). Por lo tanto, los diferenciales son cero:$dt^{2} = dT^{2} = 0 $, $d\theta^{2} = d\frac{\pi}{2}^{2} = 0 $ y luego, la métrica se convierte en:

$$ ds^{2} = \frac{1}{1-\frac{2GM}{c^{2}r}}dr^{2} + r^{2}d\phi^{2}\tag{8}$$

El siguiente paso es "comparar" este $2D$ tensor métrico con el tensor métrico cilíndrico:

$$ ds^{2} = dz^{2} + dr^{2} + r^{2}d\phi^{2} \equiv \Bigg[ 1+\Bigg(\frac{dz}{dr}\Bigg)^{2} \Bigg]dr^{2} + r^{2}d\phi^{2}\tag{9}$$

Entonces decimos que:

$$\Bigg[ 1+\Bigg(\frac{dz}{dr}\Bigg)^{2} \Bigg]dr^{2} = \frac{1}{1-\frac{2GM}{c^{2}r}}dr^{2} \tag{10}$$

Lo que implica, finalmente:

$$ \frac{dz}{dr} = \frac{1}{\sqrt{1-\frac{2GM}{c^{2}r}}} - 1 \tag{11}$$

Podemos integrar esta función y descubrir la función misma de interés aquí:

$$ z(r) = \pm\int^{r}_{r_{0}} \frac{1}{\sqrt{1-\frac{2GM}{c^{2}r}}} - 1 dr \tag{11}$$

Ecuación integradora $(11)$ y usando la función $\mathrm{RevolutionPlot3D}$ trazamos la superficie similar a un agujero de gusano

PARTE II) Mi duda y qué tipo de programa de Mathematica quiero escribir

II.1) Integral de incrustación numérica de Kruskal

Hay mucho que cubrir, pero el hecho físico es: esta garganta de agujero de gusano no es algo "constante en el tiempo", quiero decir, en los agujeros negros de Schwarzshild, el agujero de gusano se cierra muy después de que se forma el agujero negro, luego usando otras coordenadas, el Coordenadas de Kruskal-Szekeres, podemos representar el "agujero de gusano dinámico" en el "paso del tiempo", es decir, para cada valor de "tiempo kruskal" tenemos una superficie diferente!

Las coordenadas cambian entonces para las coordenadas Kruskal-Szekeres:

$$\mathrm{Coordinates'} \implies (v,u,\theta,\phi) \tag{12}$$

Dónde $v$se llaman el "tiempo de Kruskal". Es importante mencionar que esta coordenada no es la hora de nuestros relojes, de hecho, el evento$t$no es la hora de nuestros relojes, sino que llevan una firma temporal .

En este gráfico de coordenadas, la integral de incrustación (como $(11)$ ) se convierte en:

$$ z(u) = \pm\int_{0}^{u} \frac{dz}{du}du = \pm\int_{r(0)}^{r(u)} \frac{dz}{du}\frac{du}{dr}dr = \pm\int_{r(0)}^{r(u)} \sqrt{g_{rr} - 1} dr =$$

$$ = \pm\int_{r(0)}^{r(u)} \sqrt{\frac{2\Big( e^{\frac{r}{2}} -v_{0}^2 \Big)}{re^{\frac{r}{2}} - 2\Big( e^{\frac{r}{2}} -v_{0}^2 \Big)}} dr \tag{12}$$

Entonces, $v_{0}$ son los tiempos constantes de Kruskal, por lo tanto para cada $v_{0}$ podemos tener una integral en $u$! También las funciones$r(u)$ son de hecho:

$$ r(u,v) =: 2m \Biggr[1+\mathrm{LambertW}\Bigg(\frac{u^2-v^2}{e}\Bigg) \Biggr] \tag{13}$$

El uso, en este problema, de la función $(13)$ es más preciso (para $m=1$ ),

$$ r(u) \equiv r(u,v_{0}) =: 2 \Biggr[1+\mathrm{LambertW}\Bigg(\frac{u^2-v_{0}^2}{e}\Bigg) \Biggr] \tag{14}$$

Por tanto, la integral $(12)$ se convierte finalmente:

$$ z(u) = \pm\int_{r(0) = 2 \Biggr[1+\mathrm{LambertW}\Bigg(\frac{-v_{0}^2}{e}\Bigg) \Biggr] }^{r(u)=2 \Biggr[1+\mathrm{LambertW}\Bigg(\frac{u^2-v_{0}^2}{e}\Bigg) \Biggr]} \sqrt{\frac{2\Big( e^{\frac{r}{2}} -v_{0}^2 \Big)}{re^{\frac{r}{2}} - 2\Big( e^{\frac{r}{2}} -v_{0}^2 \Big)}} dr \tag{15}$$

Entonces NECESITAMOS calcular la integral $(15)$, y esta es una tarea numérica. En resumen, calculamos (de alguna manera) la integral$(15)$, y luego trazamos la misma superficie 3D:

$$ \textbf{X} = [r(u)cos(\phi), r(u)sin(\phi), z(u)] \tag{16}$$

II.2) ListPlot de mi cálculo integrado

Así que hice una integración numérica usando NIntegrate pero simplemente no puedo usarlo como $z[u]$¡función! Echar un vistazo:

Manipulate[
 ListPlot[Table[
   NIntegrate[
    Sqrt[((2*(Exp[(r)/(2)] - ((v0)^2))    ))/(r*
         Exp[(r)/(2)] - ((2*(Exp[(r)/(2)] - ((v0)^2))    )))], {r, \
(2*(1)*(1 + ( 
          LambertW[((( 0^2  ) - (v0^2))/(Exp[
               1]))]   ))), (2*(1)*(1 + ( 
          LambertW[((( u^2  ) - (v0^2))/(Exp[1]))]   )))}], {u, 0, k, 
    1}], Joined -> True, InterpolationOrder -> 1, Mesh -> All], {k, 1,
   25}, {v0, -0.99999, 0.99999}]

De hecho, este código calcula la integral numéricamente, pero no puedo usarlo en el $\mathrm{ParametricPlot3D}$.

PARTE III) Algunas incorporaciones y sugerencias ya realizadas

III.1) Mi código anterior basado en referencia $[4]$

De hecho un usuario $[4]$han "resuelto" el problema. Adapté su código un poco:

r[u_, v0_] := 1 + LambertW[(u^2 - v0^2)/E];
z[u_, v0_] := 
  2 Sqrt[(1/
        r[u, v0] Exp[-r[u, v0]] - (u Exp[-r[u, v0]]/(r[u, v0]))^2)];

Z = ParametricNDSolveValue[{z'[u] == z[u, v0], z[0] == 0}, 
  z, {u, -1, 1}, {v0}]

Manipulate[
 ParametricPlot3D[{r[u, v0] Cos[phi], r[u, v0] Sin[phi], 
   Z[v0][u]}, {u, -1, 1}, {phi, 0, 2 Pi}, PlotTheme -> "Classic", 
  PlotRange -> {{-1.5, 1.5}, {-1.5, 1.5}, {-10, 10}}, 
  BoxRatios -> {2, 2, 2}], {v0, -0.99999999999999, 0.99999999999999}]

Pero él está resolviendo una ecuación diferencial, ¡quiero usar el cálculo integral!

III.2) GIF de incorporación dinámica de Hamilton

Este tipo Hamilton ha logrado la trama suprema que quiero hacer, de hecho quiero reproducir su trama dinámica, es decir, esta pregunta mía y todas mis dudas existen solo para reproducir su trama. Puede echar un vistazo a la garganta dinámica del agujero de gusano en lo siguiente:

https://jila.colorado.edu/~ajsh/bh/schww_gif.html

III.3) El consejo de mi profesor

Mi profesor me dijo una posible solución interesante:

Tal vez puedas intentar resolver la integral numérica para varios valores de $u$y obtenga varios puntos del tipo $(u, z)$, y luego puede, por ejemplo, interpolar estos puntos para obtener una función suave de $z = z (u)$y utilice esta función en el $\mathrm{ParametricPlot3D}$. Intente y vea si funciona.

Parece tener razón, pero simplemente no sé cómo traducir obtener varios puntos del tipo$(u, z)$, y luego puede, por ejemplo, interpolar estos puntos para obtener una función suave de $z = z (u)$ en el código de Mathematica.

PARTE IV) Mi duda

Entonces, mi integración numérica en la sección II.2 parece ser correcta, por lo tanto, es solo una cuestión de hecho sobre cómo puedo rotar esta curva. Pero por la forma en que escribí todo, no puedo usar el$\mathrm{RevolutionPlot3D}$, entonces mi duda es:

Como puedo usar $\mathrm{RevolutionPlot3D}$ en mi código II.2 ?

$$ * * * $$

$[1]$ Incrustaciones y evolución temporal del agujero de gusano de Schwarzschild -https://arxiv.org/abs/1107.4871

$[2]$ Gravitación - Misner, Thorne, Wheeler Páginas 612 a 615

$[3]$ Agujeros de gusano en el espacio-tiempo y su uso para viajes interestelares: una herramienta para enseñar la relatividad general -https://aapt.scitation.org/doi/10.1119/1.15620

$[4]$ Diagrama de incrustación de agujeros de gusano

Answer 1

Hay una publicación tan larga, pero la respuesta es muy corta. En el primer paso definimos 3 funciones:

r0[u_?NumericQ, v0_?NumericQ] := 2 (1 + LambertW[(u^2 - v0^2)/E]);
z[u_?NumericQ, v0_?NumericQ] := 
 NIntegrate[
  Sqrt[2 (Exp[r/2] - v0^2)/(r*Exp[r/2] - 2*(Exp[r/2] - v0^2))], {r, 
   r0[0, v0], r0[u, v0]}, AccuracyGoal -> 2, PrecisionGoal -> 2]
wh[v0_?NumericQ] := 
 ParametricPlot3D[{r0[u, v0] Cos[phi], r0[u, v0] Sin[phi], 
   z[u, v0] Sign[u]}, {u, -1, 1}, {phi, 0, 2 Pi}, 
  SphericalRegion -> True, BoxRatios -> 1, FaceGrids -> None, 
  PlotStyle -> {Opacity[0.8]}, Boxed -> False, Axes -> False, 
  ImageSize -> Automatic, ViewPoint -> Front, Mesh -> None, 
  PlotLabel -> Row[{"\!\(\*SubscriptBox[\(v\), \(0\)]\) = ", v0 1.}]]

Y luego visualizamos el agujero de gusano (lleva tiempo):

Table[wh[x], {x, {-1 + 10^-5, -.5, 0., 
    1. - 10^-5 }}] // AbsoluteTiming