Intégrale de contour numérique

Question

J'essaye de calculer la double intégrale pour fixe $m,z>0$:

  (2Pi I)^{-1} Integrate[(Gamma[y/2] Sqrt[Gamma[3 - y]/Gamma[y]])/
  Gamma[(3 - y)/2] z^(3 - y)
   (Exp[-m x] - 1) x^(y - 3)/x, {x, 0, ∞},{y, 
  3/2 - I ∞, 3/2 + I ∞}]

L'intégrale sur $x$ peut être fait de manière analytique, et le résultat dépend du produit $mz$, il n'y a donc en fait qu'un seul paramètre. le$x$ l'intégrale doit être divisée en deux régions, je soupçonne, et dans une région le contour de la $y$l'intégrale devrait être déformée pour qu'elle reste convergente. Depuis le$y$ l'intégrale implique des coupes de branche compliquées, je voulais pouvoir le faire numériquement pour une plage de $mz$, pour obtenir au moins quelques chiffres de précision. J'ai du mal à obtenir des résultats stables numériquement.

Answer 1

Je ne pense pas que cette intégrale converge: il suffit de regarder $x$-l'intégration,

Assuming[m > 0 && z > 0 && Element[q, Reals], 
  Integrate[((E^(-m*x)-1)*x^(y-4)*z^(3-y)*Gamma[y/2]*
            Sqrt[Gamma[3-y]/Gamma[y]])/Gamma[(3-y)/2] /.
            y->3/2+I*q,
            {x, 0, ∞}]]

(*    diverges    *)

Il ne semble converger que si $\text{Re}(y)$ est dans l'intervalle $[2,3]$:

Assuming[m > 0 && z > 0,
  Integrate[((E^(-m*x)-1)*x^(y-4)*z^(3-y)*Gamma[y/2]*
            Sqrt[Gamma[3-y]/Gamma[y]])/Gamma[(3-y)/2],
            {x, 0, ∞}]]

(*    (m^(3-y)*z^(3-y)*Gamma[y-3]*Gamma[y/2]*Sqrt[Gamma[3-y]/Gamma[y]])/Gamma[(3-y)/2]
      if 2 < Re[y] < 3                                                                  *)

En utilisant ce dernier résultat:

f[m_, z_, y_] = 
  Assuming[m > 0 && z > 0 && 2 < Re[y] < 3, 
    Integrate[((E^(-m*x)-1)*x^(y-4)*z^(3-y)*Gamma[y/2]*Sqrt[Gamma[3-y]/Gamma[y]])/Gamma[(3-y)/2],
              {x, 0, ∞}]]

(*    ((m*z)^(3-y)*Gamma[y-3]*Gamma[y/2]*Sqrt[Gamma[3-y]/Gamma[y]])/Gamma[(3-y)/2]    *)

nous pouvons définir l'intégrale souhaitée comme

F[mz_?NumericQ, Ry_?NumericQ] := 
  2*I*NIntegrate[Re[f[mz, 1, Ry + I t]], {t, 0, ∞}]

en utilisant quelques symétries de f: cela ne dépend que du produit$m\cdot z$, pas sur $m$ et $z$individuellement; il est symétrique en$t$ afin que nous puissions restreindre l'intégrale à $[0,∞)$(mais prenez-le deux fois); et le résultat sera purement imaginaire donc nous n'intégrons que la partie réelle de l'intégrande.

Nous pouvons maintenant tracer, par exemple, le résultat pour Ry = Re[y] = 5/2: (traçage de la partie imaginaire)

Plot[F[mz, 5/2]/I, {mz, 0, 10}]

Nous pouvons être aventureux et déterminés Ry = Re[y] = 3/2par la continuation analytique:

Plot[F[mz, 5/2]/I, {mz, 0, 10}]