Groupby con somma su Julia Dataframe

Question

Sto cercando di creare un groupby + sum su un Julia Dataframe con valori Int e String

Ad esempio, df:

│ Row │ A      │ B      │ C     │ D      │
│     │ String │ String │ Int64 │ String │
├─────┼────────┼────────┼───────┼────────┤
│ 1   │ x1     │ a      │ 12    │ green  │
│ 2   │ x2     │ a      │ 7     │ blue   │
│ 3   │ x1     │ b      │ 5     │ red    │
│ 4   │ x2     │ a      │ 4     │ blue   │
│ 5   │ x1     │ b      │ 9     │ yellow │

Per fare ciò in Python, il comando potrebbe essere:

df_group = df.groupby(['A', 'B']).sum().reset_index()

Otterrò il seguente risultato di output con le etichette delle colonne iniziali:

    A  B   C
0  x1  a  12
1  x1  b  14
2  x2  a  11

Vorrei fare la stessa cosa a Julia. Ho provato in questo modo, senza successo:

df_group = aggregate(df, ["A", "B"], sum)

MethodError: nessun metodo corrispondente + (:: String, :: String)

Hai idea di un modo per farlo in Julia?

Answer 1

Prova (in realtà invece di colonne non stringa, probabilmente vuoi colonne numeriche):

numcols = names(df, findall(x -> eltype(x) <: Number, eachcol(df)))
combine(groupby(df, ["A", "B"]), numcols .=> sum .=> numcols)

e se vuoi consentire i missingvalori (e saltarli quando fai una somma) allora:

numcols = names(df, findall(x -> eltype(x) <: Union{Missing,Number}, eachcol(df)))
combine(groupby(df, ["A", "B"]), numcols .=> sum∘skipmissing .=> numcols)

Answer 2

Julia DataFrames supporta la logica di divisione-applicazione-combinazione , simile ai panda, quindi l'aggregazione sembra

using DataFrames

df = DataFrame(:A => ["x1", "x2", "x1", "x2", "x1"], 
               :B => ["a", "a", "b", "a", "b"],
               :C => [12, 7, 5, 4, 9],
               :D => ["green", "blue", "red", "blue", "yellow"])

gdf = groupby(df, [:A, :B])
combine(gdf, :C => sum)

con il risultato

julia> combine(gdf, :C => sum)
3×3 DataFrame
│ Row │ A      │ B      │ C_sum │
│     │ String │ String │ Int64 │
├─────┼────────┼────────┼───────┤
│ 1   │ x1     │ a      │ 12    │
│ 2   │ x2     │ a      │ 11    │
│ 3   │ x1     │ b      │ 14    │

Puoi saltare la creazione di gdfcon l'aiuto di Pipe.jl o Underscores.jl

using Underscores

@_ groupby(df, [:A, :B]) |> combine(__, :C => sum)

Puoi dare un nome alla nuova colonna con la seguente sintassi

julia> @_ groupby(df, [:A, :B]) |> combine(__, :C => sum => :C)
3×3 DataFrame
│ Row │ A      │ B      │ C     │
│     │ String │ String │ Int64 │
├─────┼────────┼────────┼───────┤
│ 1   │ x1     │ a      │ 12    │
│ 2   │ x2     │ a      │ 11    │
│ 3   │ x1     │ b      │ 14    │