Cómo contar enésimo primo en prólogo

Question

Soy bastante nuevo en prolog y estoy tratando de escribir un predicado que dé el valor del n-ésimo número primo y se ve así nth_prime(N, Prime) . Ya hice la función que cuenta si el número es primo o no

div(X, Y):- 0 is X mod Y.
div(X, Y):- X>Y+1, Y1 is Y+1, div(X, Y1).

prime(2):- true.
prime(X):- X<2, false.
prime(X):- not(div(X, 2)).

No entiendo cuál es mi próximo paso y cómo debo contar qué número primo pertenece a N.

Answer 1

Su código es un poco inusual para prolog pero (con la excepción de prime(1)) funciona.

Aquí hay una solución para su predicado:

nextprime(N,N):- 
    prime(N),
    !.
nextprime(P, Prime):-
    PP is P+1,
    nextprime(PP,Prime).

nthprime(1, 2).
nthprime(N, Prime):-
    N>1,
    NN is N-1,
    nthprime(NN, PrevPrime),
    PP is PrevPrime+1,
    nextprime(PP, Prime).

?- nthprime(1,P).
P = 2 ;
false.

?- nthprime(2,P).
P = 3 ;
false.

?- nthprime(3,P).
P = 5 ;
false.

Funciona de la siguiente manera: Se sabe que el primer número primo es 2 ( nthprime(1, 2).). Para cualquier otro número Nmayor que 1, obtenga el número primo anterior ( nthprime(NN, PrevPrime)), agregue 1 hasta que llegue a un número primo. La parte de sumar 1 se realiza a través de un predicado de ayuda nextprime/2: para un número dado P, verificará si este número es primo. Si es así, devuelve este número; de lo contrario, se llamará a sí mismo para obtener el siguiente número más alto ( nextprime(PP,Prime)) y reenviará la salida. La explosión !se llama corte que corta las otras ramas elegidas. Entonces, si una vez llega a un mejor, no puede volver atrás e intentar el otro camino.

Para probarlo puedes pedir ?- nthprime(N,P).un dado N. O para verificar varias respuestas a la vez, introduzcamos un predicado auxiliar nthprimeList/2que llame nthprime/2a cada elemento de la primera lista y ponga la "salida" en una lista:

nthprimeList([],[]).
nthprimeList([N|TN],[P|TP]):-
    nthprime(N,P),
    nthprimeList(TN,TP).

?- nthprimeList([1,2,3,4,5,6,7,8,9],[P1,P2,P3,P4,P5,P6,P7,P8,P9]).
P1 = 2,
P2 = 3,
P3 = 5,
P4 = 7,
P5 = 11,
P6 = 13,
P7 = 17,
P8 = 19,
P9 = 23;
false.

Answer 2

Usando sus definiciones, definimos lo siguiente para contar y probar todos los números desde 2 en adelante, uno tras otro:

nth_prime(N, Prime):-
  nth_prime(N, Prime, 1, 2).  % 2 is the candidate for 1st prime

nth_prime(N, P, I, Q):-   % Q is I-th prime candidate
  prime(Q) 
  -> ( I = N, P = Q
     ; I1 is I+1, Q1 is Q+1, nth_prime(N, P, I1, Q1) 
     )
  ;  Q1 is Q+1, nth_prime(N, P, I, Q1).

Pruebas:

30 ?- nth_prime(N,P).
N = 1,
P = 2 ;
N = 2,
P = 3 ;
N = 3,
P = 5 ;
N = 4,
P = 7 ;
N = 5,
P = 11 .

31 ?- nth_prime(N,P), N>24.
N = 25,
P = 97 ;
N = 26,
P = 101 ;
N = 27,
P = 103 .

32 ?- nth_prime(N,P), N>99.
N = 100,
P = 541 ;
N = 101,
P = 547 ;
N = 102,
P = 557 .