Groupby con suma en Julia Dataframe

Question

Estoy tratando de hacer un groupby + sum en un Julia Dataframe con valores Int y String

Por ejemplo, df:

│ Row │ A      │ B      │ C     │ D      │
│     │ String │ String │ Int64 │ String │
├─────┼────────┼────────┼───────┼────────┤
│ 1   │ x1     │ a      │ 12    │ green  │
│ 2   │ x2     │ a      │ 7     │ blue   │
│ 3   │ x1     │ b      │ 5     │ red    │
│ 4   │ x2     │ a      │ 4     │ blue   │
│ 5   │ x1     │ b      │ 9     │ yellow │

Para hacer esto en Python, el comando podría ser:

df_group = df.groupby(['A', 'B']).sum().reset_index()

Obtendré el siguiente resultado de salida con las etiquetas de columna iniciales:

    A  B   C
0  x1  a  12
1  x1  b  14
2  x2  a  11

Me gustaría hacer lo mismo en Julia. Intenté de esta manera, sin éxito:

df_group = aggregate(df, ["A", "B"], sum)

MethodError: ningún método que coincida + (:: String, :: String)

¿Tienes alguna idea de una forma de hacer esto en Julia?

Answer 1

Pruebe (en realidad, en lugar de columnas que no sean de cadena, probablemente desee columnas que sean numéricas):

numcols = names(df, findall(x -> eltype(x) <: Number, eachcol(df)))
combine(groupby(df, ["A", "B"]), numcols .=> sum .=> numcols)

y si desea permitir missingvalores (y omitirlos al hacer una suma), entonces:

numcols = names(df, findall(x -> eltype(x) <: Union{Missing,Number}, eachcol(df)))
combine(groupby(df, ["A", "B"]), numcols .=> sum∘skipmissing .=> numcols)

Answer 2

Julia DataFrames admite la lógica dividir-aplicar-combinar , similar a los pandas, por lo que la agregación parece

using DataFrames

df = DataFrame(:A => ["x1", "x2", "x1", "x2", "x1"], 
               :B => ["a", "a", "b", "a", "b"],
               :C => [12, 7, 5, 4, 9],
               :D => ["green", "blue", "red", "blue", "yellow"])

gdf = groupby(df, [:A, :B])
combine(gdf, :C => sum)

con el resultado

julia> combine(gdf, :C => sum)
3×3 DataFrame
│ Row │ A      │ B      │ C_sum │
│     │ String │ String │ Int64 │
├─────┼────────┼────────┼───────┤
│ 1   │ x1     │ a      │ 12    │
│ 2   │ x2     │ a      │ 11    │
│ 3   │ x1     │ b      │ 14    │

Puede omitir la creación de gdfcon la ayuda de Pipe.jl o Underscores.jl

using Underscores

@_ groupby(df, [:A, :B]) |> combine(__, :C => sum)

Puede dar nombre a la nueva columna con la siguiente sintaxis

julia> @_ groupby(df, [:A, :B]) |> combine(__, :C => sum => :C)
3×3 DataFrame
│ Row │ A      │ B      │ C     │
│     │ String │ String │ Int64 │
├─────┼────────┼────────┼───────┤
│ 1   │ x1     │ a      │ 12    │
│ 2   │ x2     │ a      │ 11    │
│ 3   │ x1     │ b      │ 14    │