Problema de corte de cubos

Question

Show[Graphics3D[{Cuboid[]}],
ContourPlot3D[{x==1/3,y==1/4,z==1/5},{x,-0.2,1.2},{y,-0.2,1.2},{z,-0.2,1.2}]]

Tres planos dividen la unidad de cubo en 8 cubos pequeños, ¿cuál es la forma más fácil de obtener estos 8 pequeños cuboides? Probé que la operación booleana regional
RegionIntersection[Cuboid[], ImplicitRegion[x < 1/3 && y < 1/4 && z < 1/5, {x, y, z}]]da

BooleanRegion [# 1 && # 2 &, {Cuboid [{0,0,0}], ImplicitRegion [x <1/3 && y <1/4 && z <1/5, {x, y, z}]}]

pero yo quiero

Cuboide [{0, 0, 0}, {1/3, 1/4, 1/5}]

El resultado final esperado es

{Cuboide [{1 / 3,1 / 4,1 / 5}, {1,1,1}], Cuboide [{1 / 3,1 / 4,0}, {1,1,1 / 5}] , Cuboide [{1 / 3,0,1 / 5}, {1,1 / 4,1}], Cuboide [{1 / 3,0,0}, {1,1 / 4,1 / 5}] , Cuboide [{0,1 / 4,1 / 5}, {1 / 3,1,1}], Cuboide [{0,1 / 4,0}, {1 / 3,1,1 / 5}] , Cuboide [{0,0,1 / 5}, {1 / 3,1 / 4,1}], Cuboide [{0,0,0}, {1 / 3,1 / 4,1 / 5}] }

Show[Graphics3D[{Cuboid[]}],
ContourPlot3D[{x==1/3,y==1/4,z==1/5,x==3/4,y==5/6,z==6/7},
{x,-0.2,1.2},{y,-0.2,1.2},{z,-0.2,1.2}]]

Si se puede extender al caso de seis aviones, será mejor.

Answer 1

xmesh = {0, 1/3, 2/3, 1};
ymesh = {0, 1/4, 2/4, 3/4, 1};
zmesh = {0, 1/5, 3/5, 4/5, 1};

cuboids =  Cuboid@@@(Transpose /@ Tuples[Partition[#, 2, 1]& /@ {xmesh, ymesh, zmesh}]);

Graphics3D[{Opacity[.3, RandomColor[]], #} & /@ cuboids, Boxed -> False]

Answer 2

Esto se puede hacer mucho más elegante y conciso usando Outer, pero funciona:

xplanes = {1/3, 2/3};
yplanes = {1/4, 2/4, 3/4};
zplanes = {1/5, 3/5, 4/5};
ends = {0, 1};

myPlanes = Union[ends, #] & /@ {xplanes, yplanes, zplanes};

theCuboidlets=Flatten[Table[
  Cuboid[{myPlanes[[1, i]], 
          myPlanes[[2, j]], 
          myPlanes[[3, k]]}, 
        {myPlanes[[1, i + 1]], 
         myPlanes[[2, j + 1]], 
         myPlanes[[3, k + 1]]}],
  {i, Length[myPlanes[[1]]] - 1},
  {j, Length[myPlanes[[2]]] - 1},
  {k, Length[myPlanes[[3]]] - 1}]];

Graphics3D[theCuboidlets]