Comportement d'évaluation EntityValue

Question

Je suis perplexe devant un comportement de EntityValue, où je trouve qu'il n'est pas évalué. Voici un exemple minimal. Considérez la coutume suivante EntityStore:

store = EntityStore[{
   "Group" -> <|
     "Entities" -> <|
       "GroupA" -> <|
         "name" -> "Group A",
         "size" -> 2,
         "members" -> {
           Entity["Individual", "Claus"],
           Entity["Individual", "Andrea"]
           }
         |>,
       "GroupB" -> <|
         "name" -> "Group B",
         "size" -> 2,
         "members" -> {
           Entity["Individual", "John"],
           Entity["Individual", "Claudia"]
           }
         |>
       |>
     |>,
   "Individual" -> <|
     "Entities" -> <|
       "Claus" -> <|"name" -> "Claus Smith", "age" -> 25|>,
       "Andrea" -> <|"name" -> "Andrea Fisher", "age" -> 35|>,
       "John" -> <|"name" -> "John Allen", "age" -> 45|>,
       "Claudia" -> <|"name" -> "Claudia Wilson", "age" -> 60|>
       |>
     |>
   }
  ]

Enregistrons-le:

EntityRegister[store]

puis interrogez-le:

assoc = EntityValue["Group", "PropertyAssociation"]

ce qui donne comme prévu:

{<|
  EntityProperty["Group", "members"] -> {Entity["Individual", "Claus"], Entity["Individual", "Andrea"]}, 
  EntityProperty["Group", "name"] -> "Group A", 
  EntityProperty["Group", "size"] -> 2
|>, 
<|
  EntityProperty["Group", "members"] -> {Entity["Individual", "John"], Entity["Individual", "Claudia"]}, 
  EntityProperty["Group", "name"] -> "Group B", 
  EntityProperty["Group", "size"] -> 2
|>}

Maintenant, disons que nous aimerions rendre cette association hiérarchique en remplaçant les propriétés individuelles par leurs propres associations de propriétés:

ds = assoc /. {Entity["Individual", n_] :> EntityValue[Entity["Individual", n], "PropertyAssociation"]}

Cela - de manière inattendue pour moi - laisse les expressions EntityValue internes non évaluées:

{<|
  EntityProperty["Group", "members"] -> {EntityValue[Entity["Individual", "Claus"], "PropertyAssociation"], EntityValue[Entity["Individual", "Andrea"], "PropertyAssociation"]}, 
  EntityProperty["Group", "name"] -> "Group A", 
  EntityProperty["Group", "size"] -> 2|>,
 <|EntityProperty["Group", "members"] -> {EntityValue[Entity["Individual", "John"],  "PropertyAssociation"], EntityValue[Entity["Individual", "Claudia"], "PropertyAssociation"]}, 
  EntityProperty["Group", "name"] -> "Group B", 
  EntityProperty["Group", "size"] -> 2
|>
}

Que se passe-t-il? Étrangement, les EntityValueexpressions internes sont évaluées lorsque nous les interrogeons directement:

Lookup[ds, EntityProperty["Group", "members"]]

donne correctement

{{<|EntityProperty["Individual", "age"] -> 25, 
   EntityProperty["Individual", "name"] -> "Claus Smith"|>,
  <|EntityProperty["Individual", "age"] -> 35, 
   EntityProperty["Individual", "name"] -> "Andrea Fisher"|>},
 {<|EntityProperty["Individual", "age"] -> 45, 
   EntityProperty["Individual", "name"] -> "John Allen"|>,
  <|EntityProperty["Individual", "age"] -> 60, 
   EntityProperty["Individual", "name"] -> "Claudia Wilson"
|>}}

Pourquoi cela me dérange-t-il? Je voudrais utiliser ce genre de mécanisme de remplacement pour créer une expression d'association hiérarchique à partir d'un magasin d'entités hiérarchiques. Imaginez une cascade de relations un-à-plusieurs, comme Continent -> Pays -> Région -> Ville -> Voisinage "ou quelque chose de similaire. J'aimerais construire une hiérarchie d'associations en remplaçant itérativement la liste des entités enfants par leurs associations immobilières.

Alors, comment puis-je contrôler l'évaluation de EntityValue?

Merci.

Answer 1

ds = Replace[
  assoc, {Entity["Individual", n_] :> 
    EntityValue[Entity["Individual", n], "PropertyAssociation"]}, 
  Infinity]

ou créez une liste de règles (en utilisant Normal) de l'Association à utiliser ReplaceAll.

ds = Normal[assoc] /. 
 Entity["Individual", n_] :> 
  EntityValue[Entity["Individual", n], "PropertyAssociation"]