¿Cómo clasificar / extraer poderes positivos y negativos como lista?

Question

Tengo la siguiente expresión

expr = x1^d1 * x2^d2 * x3^d3;

donde d1,d2,d3puede contener valores / expresión negativos, es decir, en general, estos d1,d2,d3pueden no ser valores numéricos. Decir

d1 = 4 d;
d2 = -5 e;
d3 =  -6 d;
with assumption d, e are positive.

Pregunta: ¿Hay alguna forma de hacer dos listas, una que contenga exponente positivo y otra con exponente negativo?

Mi intento actual es usar Exponentpara cada uno de estos términos y probarlos para positivo y negativo.

Answer 1

$Version

(* "12.1.1 for Mac OS X x86 (64-bit) (June 19, 2020)" *)

Clear["Global`*"]

expr = x1^d1*x2^d2*x3^d3;

exponents = 
 Cases[expr, x_^p_. :> p, 1] /. {d1 -> 4 d, d2 -> -5 e, d3 -> -6 d}

(* {4 d, -5 e, -6 d} *)

pos = Assuming[{d > 0, e > 0}, Select[exponents, Simplify[# > 0] &]]

(* {4 d} *)

neg = Assuming[{d > 0, e > 0}, Select[exponents, Simplify[# < 0] &]]

(* {-5 e, -6 d} *)

Answer 2

También se puede utilizar Internal`SyntacticNegativeQcon GeneralUtilities`SelectDiscard, GroupBy, Cases, DeleteCases, Selecto Pickde la siguiente manera:

expr = x1^d1*x2^d2*x3^d3

x1^(4 d) x2^(-5 e) x3^(-6 d)

exponents = Exponent[expr, {x1, x2, x3}]

{4 d, -5 e, -6 d}

{neg, pos} = GeneralUtilities`SelectDiscard[Internal`SyntacticNegativeQ] @ exponents

{neg, pos} = GroupBy[exponents, Internal`SyntacticNegativeQ] /@ {True, False}

{neg, pos} = Cases[#@_?Internal`SyntacticNegativeQ]@exponents & /@ 
   {Identity, Except}

{neg, pos} = DeleteCases[#@_?Internal`SyntacticNegativeQ] @ exponents & /@ 
   {Except, Identity}

{neg, pos} = Select[#@*Internal`SyntacticNegativeQ]@exponents & /@ 
   {Identity, Not}

{neg, pos} = Pick[exponents, 
    Internal`SyntacticNegativeQ /@ exponents, #] & /@ {True, False}

todos dan

 {{-5 e, -6 d}, {4 d}}